Discussion :

[serpiccio]

Bonsoir à tous,
des heures que je cherche et personne n'a visiblement eu besoin de cela.
J'ai écris un code dans thisworkbook qui empêche de supprimer une ligne. Ca je l'ai fait, ça marche en mettant count>10, car je n'ai pas réussi à trouver comment dire que c'est une ligne dont je veux empêcher la suppression. Là déjà, si quelqu'un peut m'aider, c'est bien.
Ensuite je voudrais que cela soit quand même possible si c'est une macro qui demande la suppression de ligne. Un code qui dit : si "demandé par macro" then exit sub else "empêche le suppression" etc...
Je veux donc forcer l'utilisateur à utiliser mes procédures dans mes userform, plutôt que supprimer n'importe quoi sans les vérifications que j'ai incluses dans mes userform.
Le code ci-dessous fonctionne, sauf si une procédure du userform est lancée et qui bug. Ensuite, le code dans thisworkbook ne fonctionne plus, dans tous les cas, il faut ré-ouvrir le classeur pour que ça re-fonctionne. Là aussi j'aimerai en savoir plus.

Merci à tous.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal target As Range)
 
 
   If target.Count > 10 Then
        With Application
            .EnableEvents = False
            .Undo
            .EnableEvents = True
        End With
    MsgBox "Ne jamais supprimer de ligne sans les formulaires !"
    End If
End Sub

A votre bon coeur.

[EricDgn]

est de passer par une variable globale et une fonction.
Exemple: avoir ce code dans un module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Option Explicit
 
Dim ViaMacro As Boolean
 
Sub DeleteRow10()    '--- exemple de macro
    ViaMacro = True
    Rows(10).Delete
    ViaMacro = False
End Sub
 
Public Function DepuisMacro() As Boolean
    DepuisMacro = ViaMacro
End Function

et avoir ce code dans ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal target As Range)
    Debug.Print target.Address, DepuisMacro
    If DepuisMacro Then
        '--- continuer
    Else
        If target.Count > 10 Then
            With Application
                .EnableEvents = False
                .Undo
                .EnableEvents = True
            End With
        MsgBox "Ne jamais supprimer de ligne sans les formulaires !"
        End If
    End If
End Sub

En testant j'ai eu des problèmes en voulant utiliser directement la variable globale ViaMacro dans ThisWorkbook. Cela plante.
Dans ThisWorkbook, il faut passer par la fonction pour ramener la valeur de cette variable globale.
Elle n'est donc "globale" que pour les modules, pas pour ThisWorkbook.

Bonne continuation.

[serpiccio]

Merci pour la réponse.

[Philippe Tulliez]

Bonjour EricDgn,
Belle astuce mais

est de passer par une variable globale et une fonction.

et

En testant j'ai eu des problèmes en voulant utiliser directement la variable globale ViaMacro dans ThisWorkbook. Cela plante.

La déclaration de la variable en tête de module (Dim ViaMacro As Boolean), n'est pas pour une variable globale pour le projet mais une variable Module.

Si tu fais précéder le nom de la variable par le mot clé Public, celle-ci sera bien entendu reconnue dans le module de classe ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Public ViaMacro As Boolean

Lire ce chapitre V. Les niveaux de variables

[patricktoulon]

bonjour
sinon je ferais comme ceci
dans le module de la feuille concerné
ca te permet de la modifier mais pas la supprimer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Dim oldvalue_11 As string
Private Sub Worksheet_Activate()
    oldvalue_11 = Cells(11, 1)
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Row <> 10 Then oldvalue_11 = Cells(11, 1) ' au cas ou on modifie entre temps la cellule en dessous car c'est notre repère et comme ca notre oldvalue_11 est toujours a jour
    ' parce que quand tu supprime la ligne la ligne 11 devient la ligne 10
    If Target.Row = 10 Then
        If Cells(11, 1) <> oldvalue_11 Then
            With Application
                .EnableEvents = False
                .Undo
                .EnableEvents = True
            End With
        End If
    End If
End Sub

[Pierre Fauconnier]

Salut.

Une façon de réaliser cela à peu de frais... à tester en fonction de la version utilisée...

• Déprotéger toutes les cellules de la feuille;
• protéger la feuille en cochant toutes les permissions sauf la suppression de lignes (avec ou sans mot de passe).

Pour pouvoir supprimer la ligne par VBA, il suffit simplement d'utiliser le code feuilXXX.Protect userinterfaceonly:=true en utilisant un mdp si souhaité. Cela ne place la protection qu'au niveau d'Excel, laissant toutes les possibilités d'action au VBA. Il est intéressant de noter que déprotection puis la reprotection par Excel n'altère pas la propriété UserInterfaceOnly.

Toute l'opération du paramétrage de la protection et de la protection elle-même peut être réalisée en VBA, notamment si cela doit être réalisé sur plusieurs feuilles.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Function ProtectSheet(sh As Worksheet)
  sh.Cells.Locked = False
  sh.Protect "123", True, True, True, True, True, True, True, True, True, True, True, False, True, True, True
End Function

[serpiccio]

Oui Pierre,
l'idée de la protection était ma première idée. Malheureusement, la fonction userinterfaceonly ne fonctionne pas comme on le souhaite. Je précise que la feuille et les cellules étaient paramétrée correctement. Mais rien n'y fait.
Alors je me suis orienté sur l'interdiction de suppression.
Merci.

[Pierre Fauconnier]

Ok. Pour ma culture personnelle, j'apprécierais que tu définisses ne fonctionne pas comme on le souhaite

[serpiccio]

Houlala !
Depuis tout ce temps je ne me suis pas aperçu que tu avais répondu. J'avais mis résolu, car problème abandonné.
Désolé.
Du coup, mes meilleurs voeux.

Alors je précise ce que veut dire ne fonctionne pas comme on le souhaite :
la fonction userinterfaceonly était censée n'autoriser la suppression que si cela était demandé dans mon userform. Échec total, la surpression était possible quelque soit le moyen. Manuelle ou macro.

Voilà.
Le projet a été abandonné.

Bon courage.

[Phil'oche]

Alors je précise ce que veut dire ne fonctionne pas comme on le souhaite :
la fonction userinterfaceonly était censée n'autoriser la suppression que si cela était demandé dans mon userform. Échec total, la surpression était possible quelque soit le moyen. Manuelle ou macro.

Même si la discussion est close, ton problème m'intéresse, car à chaque fois que j'ai fait un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("Feuil1").Protect "pass", , , , True

, ma feuille était bien protégée contre toute modification MANUELLE, seules les actions sur la feuille VIA LE CODE VBA étaient exécutées (donc y compris celles inclues dans une UF)

Pourrais-tu STP nous en dire plus ?

[Pierre Fauconnier]

Salut.

La protection de la feuille, c'est uniquement la protection de la feuille. Ca n'a rien à voir avec un userform qui n'est nullement impacté par la protection.

Donc, UserInterfaceOnly ou non, on pourra toujours modifier les données dans un userform. C'est au développeur du userform de mettre en place la protection de celui-ci.

[Phil'oche]

je suis bien d'accord avec toi, Pierre, mais comme le message initial faisait référence à un évènement "Workbook_SheetChange", il était clair qu'il ne parlait pas d'UF mais bien de feuille... pour lesquelles la protection marche (à ma connaissance) correctement...