Discussion :

[paul1004]

Bonjour
Je suis débutant en VBA
Grâce à l'enregistreur j'ai obtenu cette macro qui me permet de créer un graphique d'une série de données.
Je désire maintenant déplacer ce graphique créer et le disposer en haut de la feuille mais je n'y arrive pas. De plus je voudrais connaitre des commandes pour le renommer et renommer les titres des séries si possible.

Mon but final étant que la macro me demande de saisir les numéros de lignes et me trace les graphiques (on verra plus tard)

merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Sub Macro4()
'
' Macro4 Macro
'
 
'
    Range("C1180:E1340").Select
 
    ActiveSheet.Shapes.AddChart2(227, xlLineMarkers).Select
 
    ActiveChart.SetSourceData Source:=Range( _
        "'100Hz_marche_arrêt'!$C$1180:$E$1340")
    ActiveChart2.Name = "graphique 5"
    ActiveSheet.Shapes("graphique 5").IncrementLeft -120
    ActiveSheet.Shapes("graphique 5").IncrementTop 133
 
    ActiveChart.Legend.Select
    ActiveChart.Legend.LegendEntries(1).Select
    Application.CommandBars("Format Object").Visible = False
    ActiveWindow.ScrollColumn = 2
    ActiveWindow.ScrollColumn = 3
    ActiveWindow.ScrollColumn = 4
    ActiveChart.ChartArea.Select
    ActiveChart.Axes(xlValue).MajorGridlines.Select
    ActiveChart.FullSeriesCollection(3).Select
End Sub

[riaolle]

Bonjour,
Tu peux t'intéresser aux propriétés top et left de Shape.

De plus je voudrais connaitre des commandes pour le renommer et renommer les titres des séries si possible.

Tu obtiendras tout cela avec l'enregistreur de macro aussi.

Une fois que tu as tout ceci, essaie de nettoyer un peu ton code. L'enregistreur de macro ne donne pas souvent des codes bien "propres". Par ex. :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
  ActiveWindow.ScrollColumn = 2
    ActiveWindow.ScrollColumn = 3
    ActiveWindow.ScrollColumn = 4

Sont des operations que tu as faites pendant l'enregistrement, mais qui ne servent à rien (déplacement de la fenêtre Excel).
D'autre part, il n'est pas très bon d'utiliser Select/Activate/ActiveSheet...Il vaut mieux travailler directement sur les objets.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sheets("ma feuille").Activate
Range("A1").Select
Selection.Value = "toto"

Mais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("ma feuille").Range("A1").Value = "toto"

N'oublie pas d'utiliser Set pour les objets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim graphique As Shape
Set graphique = ActiveSheet.Shapes.AddChart2(227, xlLineMarkers)

[mercatog]

Une autre manière structurée à l'aide de l'objet Chartobject

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub Test()
Dim Gauche As Integer, Haut As Integer, Largeur As Integer, Hauteur As Integer
Dim Ch As Chart
 
'Définition des dimensions et coordonnées du graphique
Gauche = 360
Haut = 0
Largeur = 460
Hauteur = 300
 
'Ajout du graphique avec les dimensions et coordonnées définies précédement
Set Ch = Worksheets("Feuil1").ChartObjects.Add(Gauche, Haut, Largeur, Hauteur).Chart    'Adapte le nom de la feuille
With Ch
    'Parmetrer les graphique
    .ChartType = xlLineMarkers
    .HasLegend = True
    .HasTitle = True
    .ChartTitle.Text = "Le titre du ton graphique"
 
    'Ajout de la première série
    With .SeriesCollection.NewSeries
        .Name = "Nom de Ta série 1"
        .XValues = Worksheets("Feuil1").Range("A2:A10")
        .Values = Worksheets("Feuil1").Range("B2:B10")
    End With
 
    'Ajout de la seconde série
    With .SeriesCollection.NewSeries
        .Name = "Nom de Ta série 2"
        .Values = Worksheets("Feuil1").Range("C2:C10")
    End With
 
End With
Set Ch = Nothing
End Sub

[paul1004]

Merci beaucoup je vais m'en inspirer et travailler dessus pour l'améliorer