Discussion :

[Pauliakov]

Bonjour,

En fait si j'ai bien compris, car lu, que chaque sht était une de mes feuilles.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each sht In ThisWorkbook.Worksheets

Donc en gros je comprends bien qu'à chaque changement de feuille du classeur, la macro ouvre un message box. Je l'ai même testé pour m'en rendre compte


C'est en fait le rapport entre For Each Next et la macro que riaolle m'aide à faire que je ne comprends pas.

C'est pour que la macro soit adapté à chaque feuille où j'éprouve une difficulté à comprendre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub boucle()
Dim sht As Worksheet
 For Each sht In ThisWorkbook.Worksheets
    If sht.Name <> "Suivi AR" Then Call suivi(sht)
 Next sht
End Sub

Jusque là pas de soucis de mon côté. Donc la macro va prendre la première feuille A et exécuter la macro suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub suivi(feuille As Worksheet)
 
Dim DernLigneClnnC As Long
Dim DernLigneClnnA As Long
DernLigneClnnC = ActiveSheet.Range("C1048576").End(xlUp).Row
DernLigneClnnA = ActiveSheet.Range("A1048576").End(xlUp).Row + 1
 
ActiveSheet.Range("C4:S" & DernLigneClnnC).Copy destination:=Sheets("Suivi AR").Range("A" & DernLigneClnnA)
End Sub

Mais là je me perds car comme j'ai Activesheets.Range je dois trouver comment faire pour qu'elle fonctionne dans toutes les feuilles. Et je ne trouve pas de variable.

Pour moi je devais partir vers un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim Wb As Worksheet

pour que la macro sélectionne bien les cellules de la sht en cours. Mais il semble que non.

[Philippe Tulliez]

Bonjour,

ActiveSheet est l'objet qui représente la feuille active donc pour qu'elle soit active, il faut l'activer. De même que pour avoir une porte ouverte il faut l'ouvrir

Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Main()
 Dim sht As Worksheet
 For Each sht In ThisWorkbook.Worksheets
  EcritDansFeuille sht
 Next
End Sub

Donc si on utilise maFeuille comme argument, avant d'utiliser ActiveSheet il faut alors utiliser la méthode Select soit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub EcritDansFeuille(maFeuille As Worksheet)
 With maFeuille
  .Select
   ActiveSheet.Range("A1").Value = "Ici la feuille " & .Name
 End With
End Sub

Comme on le répète régulièrement ixi, les méthodes Select, Activate, etc. sont à proscrire car elles sont inutiles et ralentissent l'exécution du programme donc le code ci-dessous est meilleur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub EcritDansFeuille(maFeuille As Worksheet)
 With maFeuille
 .Range("A1").Value = "Ici la feuille " & .Name
 End With
End Sub

Est-ce plus clair ?

[Pauliakov]

Bonjour,

A vous lire c'est clair mais quand je veux l'adapter ça l'est moins

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub suivi(feuille As Worksheet)
 
 
Dim DernLigneClnnC As Long
Dim DernLigneClnnA As Long
DernLigneClnnC = feuille.Range("C1048576").End(xlUp).Row
DernLigneClnnA = feuille.Range("A1048576").End(xlUp).Row + 1
 
feuille.Range("C4:S" & DernLigneClnnC).Copy Destination:=Sheets("Suivi AR").Range("A" & DernLigneClnnA)

Voici comment je l'ai adapté, mais pourtant cela ne fonctionne pas (très long et surtout ne copie rien du tout dans Suivi AR)

C'est là que je vous perds

Car pourtant je dis bien à ma macro de prendre les infos dans feuille qui est la feuille sht dans la boucle

[Philippe Tulliez]

Bonjour,
Si tu veux copier d'une feuille Source vers une feuille Cible, il faut connaître la taille de la source mais il faut également connaître la dernière ligne remplie de la cible.
Or d'après ce que je lis tu calcules à tout les coups depuis la feuille source représentée par la variable objet Feuille

[Pauliakov]

En j'exécute cette macro

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Dim sht As Worksheet
 For Each sht In ThisWorkbook.Worksheets
 
    If sht.Name <> "Suivi AR" Then Call suivi(sht)
 Next sht

Qui normalement fonctionne. Et pour moi la variable feuille dans l'autre macro change avec la boucle non ?

Je souhaite juste que ça copie colle les cellules de A, B, C etc dans Suivi AR mais rien à faire je ne comprends pas mon erreur

[Philippe Tulliez]

Bonjour,
Voici une exemple de la copie des cellules de toutes les feuilles du classeur où se trouve le code VBA la feuille qui se nomme Target. Celle ci étant la feuille de destination.
Toutes les données des feuilles à copier commencent à A1 et la première ligne contient les titres
La propriété CurrentRegion utilisée ici est celle que j'emploie toujours pour connaître la taille d'une liste de données (C'est l'équivalent de Ctrl + *

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Main()
 Const TargetSheetName$ = "Target"
 Dim sht As Worksheet
 With ThisWorkbook
  For Each sht In .Worksheets
   If sht.Name <> TargetSheetName Then
    Export sht.Range("A1").CurrentRegion, .Worksheets(TargetSheetName)
   End If
  Next
 End With
End Sub

La procédure d'exportation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Export(rngSource As Range, shtTarget)
 ' rngSource est la plage source
 ' shtTarget  est la feuille cible
 Dim NextRow As Long
 Dim rngTarget As Range
 Set rngTarget = shtTarget.Range("A1").CurrentRegion
 With rngTarget
  If .Count = 1 Then NextRow = 1 Else NextRow = .Rows.Count + 1
  rngSource.Copy rngTarget.Range("A" & NextRow)
  If NextRow > 1 Then .Worksheet.Rows(NextRow).Delete  ' Efface la ligne des titres exportées sauf la première ligne
 End With
End Sub

[Pauliakov]

Vous avez un niveau beaucoup trop supérieur au mien, je me perds dans vos codes car ils me semblent beaucoup trop complexes pour mon niveau.

Je comprends certaines parties comme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Main()
 Const TargetSheetName$ = "Target"
 Dim sht As Worksheet
 With ThisWorkbook
  For Each sht In .Worksheets
   If sht.Name <> TargetSheetName Then
    Export sht.Range("A1").CurrentRegion, .Worksheets(TargetSheetName)
   End If
  Next
 End With

Mais pour l'autre code c'est autre chose, je n'arrive pas à visualiser la manipulation exacte.
Je ne trouve pas les informations qui peuvent me permettre de trouver une solution à mon problème de la variable feuille

[riaolle]

Bonjour,
Je reviens sur ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub suivi(feuille As Worksheet)
Dim DernLigneClnnC As Long
Dim DernLigneClnnA As Long
DernLigneClnnC = feuille.Range("C1048576").End(xlUp).Row
DernLigneClnnA = feuille.Range("A1048576").End(xlUp).Row + 1
feuille.Range("C4:S" & DernLigneClnnC).Copy Destination:=Sheets("Suivi AR").Range("A" & DernLigneClnnA)
End Sub

J'imagine que c'est une faute de copie, mais attention à ne pas oublier le End Sub.

Si tu veux copier d'une feuille Source vers une feuille Cible, il faut connaître la taille de la source mais il faut également connaître la dernière ligne remplie de la cible.
Or d'après ce que je lis tu calcules à tout les coups depuis la feuille source représentée par la variable objet Feuille

Ce que Philippe Tulliez t'explique ici, c'est :

• Tu veux copier les données de la feuille feuille. Il faut donc trouver la dernière ligne non vide de la feuille feuille pour copier de la première jusqu'à cette dernière ligne. C'est ce que tu fais avec

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  DernLigneClnnC = feuille.Range("C1048576").End(xlUp).Row

• Tu veux coller sur la feuille Suivi AR. Il faut donc trouver la première ligne non vide de la feuille Suivi AR pour coller à partir de cette ligne. OR, ici

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  DernLigneClnnA = feuille.Range("A1048576").End(xlUp).Row + 1

  tu cherches la premire ligne non vide de la feuille feuille. Il faut écrire

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  DernLigneClnnA = Sheets("Suivi AR").Range("A1048576").End(xlUp).Row + 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub suivi(feuille As Worksheet)
Dim DernLigneClnnC As Long
Dim DernLigneClnnA As Long
DernLigneClnnC = feuille.Range("C1048576").End(xlUp).Row
DernLigneClnnA = Sheets("Suivi AR").Range("A1048576").End(xlUp).Row + 1
feuille.Range("C4:S" & DernLigneClnnC).Copy Destination:=Sheets("Suivi AR").Range("A" & DernLigneClnnA)
End Sub
 
Sub boucle()
Dim sht As Worksheet
 For Each sht In ThisWorkbook.Worksheets
    If sht.Name <> "Suivi AR" Then Call suivi(sht)
 Next sht
End Sub

[Pauliakov]

Bonjour,

Désolé, j'étais en train de chercher une solution au problème mais rien à faire le code ne fonctionne pas et là je ne comprends pas pourquoi.
Le code modifié ne fonctionne pas, j'ai intégrer tout ce que vous m'avez dit mais rien ne se copie ni se colle...

[riaolle]

Peux-tu nous donner ton code actuel, stp?
EDIT : et que se passe-t-il quand tu le lances en mode pas à pas ?

[Pauliakov]

Bonjour,

Merci pour la reprise de contact rapide.

Le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub boucle()
Dim sht As Worksheet
 For Each sht In ThisWorkbook.Worksheets
    If sht.Name <> "Suivi AR" Then Call suivi(sht)
 Next sht
End Sub
 
 
Sub suivi(feuille As Worksheet)
 
Dim DernLigneClnnC As Long
Dim DernLigneClnnA As Long
DernLigneClnnC = feuille.Range("C1048576").End(xlUp).Row
DernLigneClnnA = Sheets("Suivi AR").Range("A1048576").End(xlUp).Row + 1
feuille.Range("C4:S" & DernLigneClnnC).Copy Destination:=Sheets("Suivi AR").Range("A" & DernLigneClnnA)
 
End Sub

Je ne comprends pas car DernLigneClnnA doit fonctionner et DernLigneClnnC aussi car on a inclus feuille As Worksheet.
Pour le pas à pas, ça ne fonctionne pas au début

Merci par avance

[riaolle]

En fait, on aurait besoin de savoir sur quelle erreur tu butes ? Est-ce qu'il y a un message d'erreur? Lequel et sur quelle ligne ?
Quand tu fais en mode pas à pas que se passe-t-il exactement ? Que veut dire "ça ne fonctionne pas au début" ? Soit plus précise, que se passe-t-il ? Ca fonctionne à un moment ? Si oui à partir de quand ça fonctionne ?
Est-ce que tu arrives à voir combien valent DernLigneClnnC et DernLigneClnnA ?

[RyuAutodidacte]

Bonjour,

il n y as point besoin de faire plusieurs macro pour faire ce code !
Par contre quand on apprend, il est utile de faire une macro par action afin de se rendre compte du résultat (et le débugguer quand une erreur se présente)
afin de bien comprendre le mécanisme.

- Action 1 = boucler sur les feuiles

- Action 2 = copie des données de la feuilles A à B
(le pointage dans un même classeur se fait : Feuille.Plage =>

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("Feuil1").Range("A1:D5")

Donc ici on aura 2 pointages, 1 sur la feuille A et l'autre sur la feuille B ainsi que 2 dernière ligne en rapport avec le pointage (qu'on appellera DLC et DLA)

une fois que les 2 actions marchent correctement indépendamment l'une de l'autre, on va les réunir en se souciant du pointage,
car sur la 1ère action on boucle sur un ensemble de feuilles

ce qui donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Synthese()
Dim sh As Worksheet, DLC&, DLA&
 For Each sh In Worksheets
    If sh.Name <> "Suivi AR" Then
        DLC = sh.Cells(Rows.Count, 3).End(xlUp).Row
        With Sheets("Suivi AR")
            DLA = .Cells(.Rows.Count, 1).End(xlUp)(2).Row
            sh.Range("C4:S" & DLC).Copy Destination:=.Range("A" & DLA)
        End With
    End If
 Next
End Sub

note bien comment le pointage est fait et regarde dans l'aide VBA With … End With

[Pauliakov]

Bonjour,

Rien à faire. J'essaye absolument tout ce que je trouve, je modifie mais c'est toujours pareil.

Quand je veux dire que rien ne se passe c'est que ça mouline, marque "ne réponds pas" pendant 20 minutes puis ça revient sur la feuille "Suivi_AR".
La fonction Pas à Pas fait fonctionner toutes les lignes jusqu'au bout sans problème.

Je cloture le sujet. Je suis parti sur un copier/coller de chaque macro de départ. Ça alourdit la macro mais tant pis.

Par contre merci pour le cours sur les boucles car j'ai pu alléger une autre macro qui avec la boucle fonctionne correctement alors merci à vous !

Je vais penser à demander une formation avec le travail plus approfondie d'Excel.

En tout cas je vous remercie pour votre aide.

[RyuAutodidacte]

bonjour,

étrange car j'ai testé la macro que j'ai fait avant de poster. je n'ai pas rencontrer de souci.
tu devrais essayer sur un nouveau fichier avec de fausses données en prenant soins de mettre correctement le nom des onglets
si ça tourne c'est que ton problème se situe ailleurs …

[Pauliakov]

Je vais essayer ça merci