Discussion :

[magali13]

Bonjour à tous,

J'ai besoin d'aide pour poser une routine d'erreur sur mon code.
J'ai un fichier en lecture seule utilisé simultanément par plusieurs personnes.
Lorsque ces personnes cliquent sur un bouton elles transfèrent des données vers un autres fichier = doc(1).
Mon problème est que lorsque le doc1 est déjà "ouvert" par un autre utilisateur (le temps que celui-ci transfère ses données) cela génère une erreur.
Je voudrais pouvoir recommencer la demande d'ouverture du doc1 tant qu'il ne s'ouvre pas en lecture-écriture
Auriez-vous une proposition ?

Merci d'avance pour votre aide
Bon week-end

Mag

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
    Sub transferer()
    'masque l'execution des macros
    Application.ScreenUpdating = False
 
 
    'ouvre le fichier
    Workbooks.Open Filename:="N:\Serveur1\GESTION SUIVI CAF.xlsx"
 
    'récupère le nom dans une variable
    doc1 = ActiveWorkbook.Name
 
 
    Windows("RECEVABILITE_AUTO DP.xlsm").Activate
 
    'récupère le nom dans une variable
    doc2 = ActiveWorkbook.Name
 
    Windows(doc2).Activate
 
    Sheets("nir caf").Visible = True
    Sheets("nir caf").Select
 
 
    ' copie les données
       Columns("A:n").Select
        Selection.Copy
        Windows(doc1).Activate
        Columns("A:n").Select
        ActiveSheet.Paste
        Range("a1").Select
 
    ' vide le presse papier
    Call presse
 
    'enregistre et ferme le doc1 après copie
    Windows(doc1).Activate
    ActiveWorkbook.Save
    ActiveWorkbook.Close
 
    End Sub

[joe.levrai]

Bonjour,

j'ai été amené à répondre à cette problématique, que je déconseille personnellement
en partant du principe que le fichier excel n'est pas ouvert trop longtemps pour l'écriture et l'utilisation du fichier cible (quelques secondes), voici comment j'ai procédé, ce n'est pas la panacée

une fonction d'ouverture un peu brute

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Option Explicit
 
' ESSAYE D'OUVRIR LA BDD EN ECRITURE
Function Ouverture_BDD() As Variant
Dim LectureSeule As Boolean, Cpt As Long
Application.ScreenUpdating = False
    Do
        ' ON TENTE 5 FOIS DE SUITE D'OUVRIR LA BDD EN ECRITURE
        With Workbooks.Open(CheminBDD & NOM_BDD, , False, , PASSWORD)
            LectureSeule = .ReadOnly
            Cpt = Cpt + 1
            If LectureSeule Then
                .Close False
                ' AU BOUT DE 5 ECHECS, L'UTILISATEUR CHOISIS DE REESSAYER OU PAS
                If Cpt = 5 Then
                    If MsgBox("La BDD est fermée en écriture, voulez-vous refaire une tentative ?", vbYesNo) = vbYes Then
                        Cpt = 0
                    Else
                        ' SI ECHEC ET ARRETE DE L'UTILISATEUR
                        ' ON RENVOIE UN FALSE
                        Ouverture_BDD = False
                        Exit Do
                    End If
                End If
            End If
        End With
    Loop While LectureSeule = True
 
' SI OUVERTURE REUSSIE
' ON RENVOIE UN OBJET WORKBOOK REPRESENTANT LA BDD
Set Ouverture_BDD = Workbooks(NOM_BDD)
Application.ScreenUpdating = True
End Function

Voici comment je l'appelle dans mes procédures :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Option Explicit
 
Sub Export_Saisie()
Dim Wb_BDD As Workbook
    Application.ScreenUpdating = False
        On Error Resume Next: Set Wb_BDD = Ouverture_BDD: On Error GoTo 0
        If Wb_BDD Is Nothing Then Exit Sub
 
        ' TRAITEMENT
 
        Wb_BDD.Close True
    Set Wb_BDD = Nothing
    Application.ScreenUpdating = True
End Sub

Avec trois constantes publiques :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Public Const CheminBDD As String = "CheminDuFichier"
Public Const NOM_BDD As String = "NomDuFichier"
Public Const PASSWORD As String = "MdpEventuelDuFichier"

Pour le moment, ça tient avec 6 ou 7 utilisateurs de l'outil déporté, mais je maintiens que c'est pas conseillé

[kiki29]

Salut, peut-être via Code de macro pour vérifier si un fichier est déjà ouvert ou allégé dans la FAQ.