Discussion :

[camzo]

Bonsoir,

Je tente d'appliquer la macro Supprime les lignes si cellule vide en colonne A sur plusieurs feuilles d'un classeur.

Pour cela, j'ai trouvé de quoi prendre en compte toutes les feuilles d'un classeur:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim fl As Worksheet
For Each fl In ThisWorkbook.Worksheets
...
Next fl

Et j'ai testé avec succès la suppression des lignes dont la cellule en colonne A est vide:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim i As Integer
Dim LastRow As Integer
LastRow = Range("A65536").End(xlUp).Row
 
    For i = LastRow To 2 Step -1
        If Cells(i, 1) = "" Then Rows(i).Delete
    Next i

Du coup, j'ai voulu mixer l'ensemble comme suit dans une macro:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Test()
 
Dim i As Integer
 
Dim LastRow As Integer
LastRow = Range("A65536").End(xlUp).Row
 
Dim fl As Worksheet
 
For Each fl In ThisWorkbook.Worksheets
 
    For i = LastRow To 2 Step -1
        If Cells(i, 1) = "" Then Rows(i).Delete
    Next i
 
Next fl
 
End Sub

J'imagine que cela vous saute aux yeux...
Merci par avance pour vos lumières

Camzo

[camzo]

Pardon, j'ai oublié d'expliquer le résultat: cela fonctionne bien sur la feuille active mais pas d'action sur les autres feuilles du classeur.
C'est comme si mon for each n'était pas pris en compte à compter du moment où j'ai ajouté l'étape de la suppression de ligne...

Cordialement,
Camzo

[RyuAutodidacte]

Bonsoir,

tu persistes avec les boucles , mais bon faut bien apprendre

pose toi ces questions :
que représente ton fl ?
comment pointes tu sur une plage précise sur une feuille déterminée ?
manque t-il pas qq ch dans ta boucle ?

[camzo]

Zut, je commence à me faire une réputation... et pas des meilleures !!!
J'ai effectivement comme qui dirait du mal à lâcher les boucles. Un collègue insiste aussi là-dessus, je vais finir par lâcher...

Je pense néanmoins me rapprocher du but!

Déjà je suis passé en ActiveWorkbook et ActiveSheet (au lieu de nommer notamment ma sheet "feuille1" directement). Je pense que cela aide, mais un peu tard pour contre-vérifier... ce sera pour demain si j'ai le temps!

Et ensuite j'ai intégré un With / End With. Cela semble coller. Mais je n'y mettrai pas ma main à couper.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Dim fl As Worksheet
Sheets("Sheet1").Select
 
For Each fl In ActiveWorkbook.Worksheets
 
fl.Activate
 
With ActiveSheet.Range("A:A")
    For i = .Cells(.Rows.Count, 1).End(xlUp).Row To 2 Step -1
        With .Cells(i, 1)
            If IsEmpty(.Value) = True Then ...
        End With
    Next i
End With
Next fl
End Sub

Je regarde demain matin plus en détail afin de décortiquer le tout avec (je l'espère) un collègue qui s'y connait bien mieux que moi.

Cordialement,
Camille

[RyuAutodidacte]

haaa erfff quel horreur un activate

le pointage schématiquement se fait comme ceci :
Classeur.feuille.plage

même t as dernière ligne n'est pas inclus dans la boucle - correction rapide :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Test()
 
Dim i As long, LastRow As Long, fl As Worksheet
 
For Each fl In ThisWorkbook.Worksheets
    LastRow = fl.Range("A65536").End(xlUp).Row 
    For i = LastRow To 2 Step -1
        If fl.Cells(i, 1) = "" Then fl.Rows(i).Delete
    Next
Next
End Sub

j'ai pas vérifié je l'ai fait vite fait à la volée, si il y a une erreur, précise là

Voilà un démo quasi automatique rien qu'avec des formules

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub Demo()
Dim ws As Worksheet
'Demo fait sur 4 feuilles tout automatiser
    For Each ws In Worksheets
        With ws
            With .UsedRange
                DL& = Split(.Address, "$")(4): Col& = .Columns.Count + 1
            End With
 
            entete = Array(3, 1, 2, 5)(.Index - 1) ' on démare de la ligne 4 puis 1, 3 et 5 (dans l'odre des feuilles)
            'Cela permet de définir différents en-têtes afin que ceci ne soit pas toucher => ex : en feuil1 l'en-tête vaut 4 -1 = 3
            If entete - 1 > 0 Then .Cells(Col).Resize(entete - 1).Value = 0
        'Application.ScreenUpdating = False
            With .Range(.Cells(entete, Col), .Cells(DL, Col))
                .Formula = "= A" & entete & "=""""" 'Ici on change la formule selon ce que l'on veut (là on a : Ax = "") x représentant la ligne par "entete"
                .Value = .Value
            End With
 
            .UsedRange.Sort .Cells(Col), xlAscending, Header:=xlNo
            V = Evaluate("=MATCH(TRUE," & ws.Name & "!" & .Columns(Col).Address & ",0)")
            If Not IsError(V) Then
                .Rows(V & ":" & DL).EntireRow.Clear
            End If
            .Columns(Col).Clear
        'Application.ScreenUpdating = True
        End With
    Next
End Sub

Edit : j'ai apporté une correction à mon code, je l'ai fait afin que tu puisses l'analyser

Pour Analyser le code il faut :
- Ouvrir la fenêtre des variables locales pour vérifier ce qu'il s'y passe lorsque l'on fait du pas à pas dans le code
- pour faire du pas à pas dans dans le code, utiliser la touche F8
- on peut vérifier certaines parties du code (ce que l'on souhaite) avec un Debug.Print (soit dans le code soit via des tests avec la fenêtre d'exécution) - pour Debug.Print cf l'aide vba

PS : Dans la boucle for Each fl prends la valeur de chaque feuille l'une après l'autre à chaque passage dans la boucle
si tu as 3 feuilles : Feuil1, Feuil2 et Feuil3, alors fl sera égal à Feuil1 puis Feuil2 puis Feuil3
on aura alors fl.Cells(i, 1) ou en clair Feuil1.Cells(i, 1), etc …

Edit : Petites corrections de texte

[halaster08]

Bonjour,

Si jamais tu veux le faire sans boucle (ce qui est plus rapide) je te conseille d'aller voir ici: https://www.developpez.net/forums/d1...on-lignes-vba/