1. #1
    Débutant
    Avatar de koKoTis
    Profil pro
    Inscrit en
    août 2006
    Messages
    3 432
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : août 2006
    Messages : 3 432
    Points : 2 413
    Points
    2 413

    Par défaut Un script pour faire sonner le carte mère toutes les minutes

    Bonjour ... je voudrais créer un script VBS qui ouvre une fenêtre ... et dans cette fenêtre j'entre un nombre ... qui sera le nombre de minute durant le quel le script devra faire bipper ma carte mère toutes les une minute ... auriez vous des piste ?

  2. #2
    Membre chevronné

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, AMP)
    Inscrit en
    juillet 2014
    Messages
    1 031
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 38
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, AMP)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 1 031
    Points : 1 904
    Points
    1 904

    Par défaut

    VBS : oShell.Run "%comspec% /c echo " & Chr(7), 0, False
    https://community.spiceworks.com/scripts/show/103-beep

    Un beep Windows : rundll32 user32.dll,MessageBeep -1
    Un outil beep : http://www.rlvision.com/script/downl...&file=Beep.zip
    En batch : echo •
    En batch : echo (ctrl + G)
    echo ^G

  3. #3
    Rédacteur/Modérateur
    Avatar de ProgElecT
    Homme Profil pro
    Retraité
    Inscrit en
    décembre 2004
    Messages
    4 072
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 61
    Localisation : France, Haute Savoie (Rhône Alpes)

    Informations professionnelles :
    Activité : Retraité
    Secteur : Communication - Médias

    Informations forums :
    Inscription : décembre 2004
    Messages : 4 072
    Points : 8 080
    Points
    8 080

    Par défaut

    Salut

    Dans un HTA cela pourrait être ce
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    <HTML>
     
    	<HEAD>
    	<TITLE> Alarme </TITLE>
    		<HTA:APPLICATION
    			APPLICATIONNAME="alarme"
    			ID="alarme"
    			SCROLL="no"
    			INNERBORDER="no"
    			MAXIMIZEBUTTON="no"
    			MINIMIZEBUTTON="no"
    	</HEAD>
    <SCRIPT language="VBScript">
    	Option Explicit 
    	'Déclarations utilisables dans toute la partie VBScript
    	Dim chrono
    	chrono = 0
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub Window_Onload()
    	ResizeTo 150, 100
    	End Sub
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub Window_OnUnload()
    	If chrono <> 0 then window.clearInterval(chrono)
    	End Sub
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub entSc_onkeyUp()
    		If window.event.keyCode = 13 then BtApp_onClick()
    	End Sub
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub BtApp_onClick()
    	dim Sc, tempo
    	Sc = entSc.Value
    	If chrono = 0 then
    		If IsNumeric(Sc) Then
    			If Cint(Sc) < 1 Or cint(Sc) >= 61 Then
    				msgbox "Minimum 1, maximum 60"
    				Exit Sub
    			End If
    			Else
    			msgbox "Entrez un chiffre, minimum 1, maximum 60"
    			Exit Sub
    		End If
    		BtApp.value = "Arreter"
    		entSc.disabled = True
    		tempo = Cint(Sc)*1000
    		chrono = window.setInterval("sonner", tempo)
    		'sonner() ' éventuellement pour sonner au moment de l'enclenchement
    		Else
    		window.clearInterval(chrono)
    		BtApp.value = "Appliquer"
    		entSc.disabled = False
    	End If
    	End Sub
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub sonner()
    	dim oShell
    	Set oShell = CreateObject("WSCript.shell")
    	oShell.Run "%comspec% /c echo " & Chr(7), 0, False
    	Set oShell = NotHing
    	End Sub
    </SCRIPT>
     
    	<Body>
    		<Input Type="text" id="entSc" style="position:absolute; left:15px; top:5px; width:71px">
    		<p style="position:absolute; left:90px; top:5px"> Sc </p>	
    		<Input Type="button" id="BtApp" Value="Appliquer"
    			style="position:absolute; left:15px; top:30px; height:22px; width:100px;
    			background-color:powderblue; Color:#000000">
    	</Body> 
    </HTML>

  4. #4
    Rédacteur/Modérateur
    Avatar de ProgElecT
    Homme Profil pro
    Retraité
    Inscrit en
    décembre 2004
    Messages
    4 072
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 61
    Localisation : France, Haute Savoie (Rhône Alpes)

    Informations professionnelles :
    Activité : Retraité
    Secteur : Communication - Médias

    Informations forums :
    Inscription : décembre 2004
    Messages : 4 072
    Points : 8 080
    Points
    8 080

    Par défaut

    Re

    Un code plus complet
    choix de l'intervalle de chaque sonnerie par minute
    choix de la plage durant laquelle doivent avoir lieux ces sonneries
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    72
    73
    74
    75
    76
    77
    78
    79
    80
    81
    82
    83
    84
    85
    86
    87
    88
    89
    90
    91
    92
    93
    94
    95
    96
    97
    98
    99
    100
    101
    102
    103
    104
    <HTML>
     
    	<HEAD>
    	<TITLE> Alarme </TITLE>
    		<HTA:APPLICATION
    			APPLICATIONNAME="alarme"
    			ID="alarme"
    			SCROLL="no"
    			INNERBORDER="no"
    			MAXIMIZEBUTTON="no"
    			MINIMIZEBUTTON="no"
    	</HEAD>
    <SCRIPT language="VBScript">
    	Option Explicit 
    	'Déclarations utilisables dans toute la partie VBScript
    	Dim chrono, NbrSon, NumPass
    	chrono = 0
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub Window_Onload()
    	ResizeTo 225, 120
    	End Sub
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub Window_OnUnload()
    	If chrono <> 0 then window.clearInterval(chrono)
    	End Sub
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub NbrSon_onkeyUp()
    		If window.event.keyCode = 13 then BtApp_onClick()
    	End Sub
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub entSc_onkeyUp()
    		If window.event.keyCode = 13 then BtApp_onClick()
    	End Sub
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub BtApp_onClick()
    	dim tSc, tMn, tempo
    	tSc = entSc.Value
    	tMn = entMn.Value
    	If chrono = 0 then
    		If IsNumeric(tSc) Then
    			If Cint(tSc) < 5 Or cint(tSc) >= 61 Then ' temps entre chaque sonnerie
    				msgbox "Minimum 5, maximum 60"
    				Exit Sub
    			End If
    			Else
    			msgbox "Entrez un chiffre, minimum 5, maximum 60"
    			Exit Sub
    		End If
    		If IsNumeric(tMn) Then ' plage de temps de la sonnerie
    			If Cint(tMn) < 1 Or cint(tMn) >= 61 Then
    				msgbox "Minimum 1, maximum 60"
    				Exit Sub
    			End If
    			Else
    			msgbox "Entrez un chiffre, minimum 1, maximum 60"
    			Exit Sub
    		End If
    		BtApp.value = "Arreter"
    		entSc.disabled = True ' empêcher la possibilité d'entrer un chiffre dans le Input Type="text"
    		entMn.disabled = True ' idem
    		NbrSon = Cint((tMn*60) / tSc) 'nombre de sonnerie durant la plage de temps
    		NumPass = 0 'comptage de passage dans la Sub "sonner()"
    		tempo = tSc*1000 'temps entre chaque sonnerie en millisecondes
    		chrono = window.setInterval("sonner", tempo) ' appelle la fonction de manière répétée, avec un certain délai fixé entre chaque appel 
    		'sonner() ' éventuellement pour sonner au moment de l'enclenchement, dans ce cas mettre NumPass = -1
    		Else
    		window.clearInterval(chrono)
    		chrono = 0
    		BtApp.value = "Appliquer"
    		entSc.disabled = False
    		entMn.disabled = False
    	End If
    	End Sub
    	'----------------------------------------------------------------------------------------------------------------------
    	Sub sonner()
    	dim oShell
    	Set oShell = CreateObject("WSCript.shell")
    	oShell.Run "%comspec% /c echo " & Chr(7), 0, False
    	Set oShell = NotHing
    	NumPass = NumPass + 1
    	If NumPass = NbrSon Then
    		window.clearInterval(chrono)
    		BtApp.value = "Appliquer"
    		entSc.disabled = False
    		entMn.disabled = False
    	End If
     
    	End Sub
    </SCRIPT>
     
    	<Body>
    		<p style="position:absolute; left:15px; top:5px"> Sonnerie toutes les </p>	
    		<Input Type="text" id="entSc" value="60" style="position:absolute; left:135px; top:5px; width:30px">
    		<p style="position:absolute; left:180px; top:5px"> Sc </p>	
     
    		<p style="position:absolute; left:15px; top:30px"> Durant ..............</p>	
    		<Input Type="text" id="entMn" value="15" style="position:absolute; left:135px; top:30px; width:30px">
    		<p style="position:absolute; left:180px; top:30px"> Mn </p>	
     
    		<Input Type="button" id="BtApp" Value="Appliquer"
    			style="position:absolute; left:15px; top:55px; height:22px; width:180px;
    			background-color:powderblue; Color:#000000">
    	</Body> 
    </HTML>

Discussions similaires

  1. Faire sonner la carte mére
    Par koKoTis dans le forum VBScript
    Réponses: 2
    Dernier message: 12/04/2007, 09h10
  2. Réponses: 1
    Dernier message: 30/12/2006, 00h26
  3. Script pour faire plusieurs page…
    Par sam01 dans le forum Fichiers
    Réponses: 7
    Dernier message: 14/04/2006, 21h51
  4. Script pour faire défiler des infos
    Par waddle dans le forum JavaScript
    Réponses: 2
    Dernier message: 19/01/2006, 14h54
  5. [MS-DOS] Faire sonner la carte mère
    Par Furius dans le forum Scripts/Batch
    Réponses: 14
    Dernier message: 20/09/2005, 17h48

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo