Discussion :

[pasbonte38]

Bonjour

Je sèche sur l'imbrication de SI.

J'ai ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(I4<5;"Groupe 1";SI(5<=I4<10;"Groupe 2");SI(10<=I4<15;"Groupe 3");SI(15<=I4<20;"Groupe 4"))

Il n'en veut pas et me dit TROP D'ARGUMENTS...pourtant c'est simple non ?

merci pour le coup de main.

[joe.levrai]

Bonjour,

tes SI() ne sont pas imbriqués ici (sauf le premier SI()), ils sont accolés

voici une imbrication, à adapter si besoin

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(I4<5;"Groupe 1";SI(5<=I4<10;"Groupe 2";SI(10<=I4<15;"Groupe 3";SI(15<=I4<20;"Groupe 4"))))

[pasbonte38]

Grand merci mais EXCEL me donne FAUX alors que la cellule I4 a une valeur de 11.

Mon calcul:
Si note comprise entre 0 et 5 alors Groupe 1
Entre 5 et 10 (5 compris) alors groupe 2
Entre 10 et et 15 alors groupe 3.
Entre 15 et 20 alors groupe 4

J'essaye d'automatiser car j'ai plus de 200 élèves..

[riaolle]

Bonjour,
Pour vérifier une double inégalité, il faut utiliser la fonction ET :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(I4<5;"Groupe 1";SI(ET(5<=I4;I4<10);"Groupe 2";SI(ET(10<=I4;I4<15);"Groupe 3";"Groupe 4")))

J'ai enlevé le dernier SI, j'imagine que si les 3 premières conditions ne sont pas vérifiées, alors on a bien un note entre 15 et 20.

[Menhir]

Mon calcul:
Si note comprise entre 0 et 5 alors Groupe 1
Entre 5 et 10 (5 compris) alors groupe 2
Entre 10 et et 15 alors groupe 3.
Entre 15 et 20 alors groupe 4

Il faudrait que tu précises à quel groupe appartiennent les valeurs 5, 10 et 15.

En supposant qu'ils appartiennent respectivement aux groupes 1, 2 et 3, il y a une formule plus simple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MAX(0;ENT((A4-1)/5))+1

Autre solution : mettre dans un coin de ta feuille (ou une autre feuille) un petit tableau :

0	1
5	2
10	3
15	4

Et l'utiliser avec un RECHERCHEV.

[papouclo]

Bonjour,
Autre possibilité de formule sans SI et proche dans l'esprit de la dernière proposition de Menhir :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="Groupe "& EQUIV (I4 ;{0;5;10;15})

Cordialement
Claude

[Menhir]

C'est vrai que pour ne résultat 1 2 3 4, EQUIV est plus simple que RECHERCHEV.

[Rapidkiller]

Bien que résolu et un peu tard, avec des SI mais dans le sens inverse, car la logique d'un SI est que s'il rentre dans une condition VRAIE c'est terminé ... Du coup on part du max, et on redescend

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(B3>15;"Groupe 4";SI(B3>10;"Groupe 3";SI(B3>5;"Groupe 2";"Groupe 1")))

Avec la note en B3 forcément