Discussion :

[madhouse2891]

bonsoir à tous,
j'ai mis en place un export spécifique qui se lance à partir d'une action à partir de la fenêtre OSOH. jusqu'à ce jour cela fonctionnait très bien.

cet export contient une ligne d'entête qui contient les informations de la commande le numéro de la contremaque et pleins d'autres informations et il contient en dessous une ligne ou plus qui les détails: le code article, la référence constructeur, et d'autres informations.

pour ce faire au début j'ai créé une vue afin de ne récupérer que les articles éligibles à cet export, et un filtre supplémentaire qui dit je ne rempli le fichier que si la livraison est créée. et pour un fournisseur bien défini. et une fois l'export est bien terminé je lance une mise à jour des lignes en question par un flag afin de ne plus les réexporter et par la suite griser le bouton dans la barre de menu de l'écran.

Aujourd'hui dans une commande j'ai plusieurs fournisseurs qui peuvent être dans une même commande, et je suis obligé de générer un fichier par fournisseur qui contient une ligne d'entête et une/plusieurs lignes de détails. sauf que je n'y arrive pas.
à la base je ne suis pas développeur mais par la force des choses je réussi à faire des choses en language L4G et qui fonctionne bien. sauf que cette fois je bloque.

j'ai commencé à tout modifié dans tous les sens et là je me suis perdu.

je vous mets à disposition le bout de code développé et qui a fonctionné jusque à ce jour. et même aujourd'hui il fonctionne mais il me mets la ligne d'entêtes sans faire la distinction dans les lignes à quel fournisseur appartient elle.

##########################################################
#Version 1.00 MDA export vers Plateforme
#Version 1.01 MDA Ajout Flag export [SDH]
#Version 1.02 MDA
##########################################################
Local Char VALEUR(10), PARAM(10)(1..2)
Call TRAITE_CHAR(VALEUR,PARAM,"","","YCTP",3,"YCTP") From GTRAITE
End
##########################################################

$ACTION
Case ACTION
When "INIT" : Gosub INIT
When "EXEC" : Gosub EXP_HARMO
When "SORTIE" : Gosub SORTIE
When "FIN" : Gosub FIN
Endcase
Return
###########################################################

$INIT
Call ECR_TRACE("Export CTP",0) From GESECRAN
Return
###########################################################

$EXP_HARMO
Local Char FICH(250)
Local Char HARMODIR(150) , DOSS(10)
[L]HARMODIR="\\répertoirededestination\"
#nom du fichier à générer
[L]FICH=[L]HARMODIR+"CTP.writing"
[L]DOSS=nomap

###################################################
## Bon CTR plateforme a exporte ##
###################################################

Subprog EXP11(DOSS,HARMODIR)
Value Char DOSS, HARMODIR
Local File = DOSS+".XCTP" [CTP]
Local Char FICH(250), DEL(1)
[L]FICH=[L]HARMODIR+"CTP.writing"
Openo [L]FICH
Iomode adxifs ";"
Iomode adxirs chr$(13)+chr$(10)
Iomode adxium 50

Gosub EXPORT11

$EXPORT11
Local Integer IND
Local Char LIG(254)(1..15)
Local Char ZLIG(254)(1..2)
If !clalev ([F:CTP]) : Local File XCTP [CTP] : Endif
If [F:SOH]LASDLVNUM<>"" & adxseek(1)=0

#boucle pour l'export entête selon la matrice définit dans le traitement YXCTP
For IND=1 To 2

Read[CTP]IDREF=[F:SOH]LASDLVNUM
Filter [CTP] Where IDBL=[M:SOH2]LASDLVNUM
Gosub IMEF From YXCTP
Wrseq ZLIG(IND);

Next IND
Endif

If [F:CTP]IDBL=[M:SOH2]LASDLVNUM & [F:CTP]REFSAGE>""
For[CTP]IDREF Where IDBL=[M:SOH2]LASDLVNUM & [F:CTP]REFSAGE>""
For IND=1 To 15

Gosub IMEF2 From YXCTP
Wrseq LIG(IND);
Next IND
Next
Endif

#Return


$SORTIE
Local Char ZFICHIER2(250)
Local Char FICH(250)
Local Integer STAT
Local Char HORO(14) , TIM(8)
Local Char PATH(250)
[L]HORO=datesyst
[L]TIM=time$
[L]HORO += left$(TIM,2)+mid$(TIM,4,2)+mid$(TIM,7,2)
[L]PATH="\\chemin du répertoire\"
Openo [L]FICH
#répertoire pour déposer le fichier

[L]ZFICHIER2=[L]PATH+[L]HORO+"_"+GUSER+"_CTP_SPX.csv"
[L]FICH="répertoire de destination\CTP.writing"

#ici je renomme le fichier selon la syntaxe du Zfichier2
Call MOVE(FICH,ZFICHIER2,STAT) From ORDSYS
If fstat=0
Gosub FIN
Endif

$FIN
#######################################
##MAJ Flag export dans la table SDH
## afin de n'exporter que les bl en-cours
#######################################
Local Integer CHANGE
Local Integer EXPT
If clalev([F:SDH]) = 0 Local File SDELIVERY [SDH] : Endif
[L]EXPT=2
Trbegin [SDH] : GOK=1

For [CTP]IDREF Where IDBL=IDBL & REFSAGE>""
If [CTP]ZCTP<>2
Update [F:SDH] Where [F:SDH]SDHNUM=[F:CTP]IDBL & [F:SDH]SDHNUM=[F:SOH]LASDLVNUM With [F:SDH]ZCTP=[L]EXPT
Endif
Rewrite [F:SDH]
CHANGE +=1
Next
If GOK=1 : Commit
Else : Rollback
Endif
End

est ce que quelqu'un a eu à faire ceci auparavant et pourrais t'il m'aider à réussir à faire cet export conditionnel vers 2 fichiers séparée si existence de deux fournisseurs différents sinon un seul fichier si mono-fournisseur.
merci par avance à tout ceux qui me porterons leur aide

[bimiman]

Bonjour,

Je ne sais pas si j'ai bien compris le problème, mais :

openo .... using [FIC1] pour le premier fichier
openo .... using [FIC2] pour le deuxième fichier
et toujours utiliser le "using" avec le wrseq

[madhouse2891]

Merci bimiman de ton retour,

certes qu'il faut que j’utilise deux ouvertures mais c'est la boucle conditionnelle que je n'arrive pas faire pour lui dire si dans la ligne N°2, le fournisseur diffère de celui qui est sur la ligne N°1 alors tu m’éclates en deux fichiers.

j’espère que je me suis fait comprendre

encore un merci en plus

[bimiman]

Non je ne comprends pas bien...

Il n'y a pas de fichier à éclater puisque les deux sont écrits simultanément.

[madhouse2891]

En effet mes enregistrements sont dans une vue, de cette vue je dois reconnaitre si l'enregistrement N°1 et N°2 ont le même fournisseur donc j'exporte un seul fichier, sinon s'il s'avère que les deux enregistrements n'ont pas le même fournisseur je dois exporter chacun dans un fichier séparé.

j’espère que je me suis fais comprendre

et merci encore une fois de votre retour

[castorameur]

Bonjour,
Justement c'est ce que vous indique Bimiman :

lors de la lecture votre requete vous fabriquez 2 fichiers en meme temps la ligne 1 allant dans le fichier 1 si frn=x et la ligne 2 allant dans le fichier 2 sir frn = y

[madhouse2891]

bonjour castorameur,
merci de votre retour, le problème c'est je n'arrive pas à mettre en place cette boucle qui me permet de distinguer ou comparer le code fournisseur dans les deux lignes

auriez vous la syntaxe svp de début de la boucle, par la suite j'essaierais de me débrouiller tout seul

[castorameur]

Sans connaître la requête c'est difficile mais avez vous essayez de ne pas filtrer par frn, de rajouter une colonne frn et d'utiliser cette colonne dans votre exp.
Et sinon question subsidiaire : pourquoi ne pas avoir choisi un modèle d'export ?
cdt

[madhouse2891]

En effet c'est un peu compliqué , l'export je le déclenche à partir d'un bouton spé rajouté au niveau de la fenêtre OSOH, car dans le processus de traitement des commandes les utilisateurs génèrent la contremarque et par la suite génère le Bon de livraison et par la suite exporte les informations qui seront exploités par un logiciel tiers qui nous a imposé une matrice bien définie. (une ligne d'entête et une ligne de détails ou plus à condition que ce soit le même frn)

donc j'ai été obligé de faire un TRT spé qui lance l'export de cette matrice qui est défini dans les étiquettes IMEF et IMEF2 du TRT YXCTP. afin de pouvoir générer une ligne d'entête et une ligne de détail dans le fichier final qui sont issus d'une vue qui contient tous les produits en Contremarque.

sauf que tout ceci fonctionnait parfaitement quand j'avais un seul fournisseur! Sauf que depuis peu ils ont décidé de mettre des fournisseurs supplémentaires,ce qui me ramène à avoir une commande qui contient plusieurs fournisseurs donc il me faut produire un fichier par fournisseur en sortie

[castorameur]

Sans tout casser (même si je n'aurais pas fait de la même manière) vous pouvez peut être faire une boucle dans l'appel du bouton à votre vue et pg d export

exemple 1er appel vous filtrez pour frn 1 votre vue , vous flaguez les lignes exportées (1, 3 et 5 par ex)
2eme appel vous filtrez pour frn 2 votre vue , vous flaguez les lignes exportées (2 et 4 par ex)
...
jusqu a ce que toutes les lignes soient flaguées

ce n'est pas optimisé mais cela doit marcher

[madhouse2891]

merci castorameur pour votre retour, le problème est que cela soit fluide pour l'user qui traite la commande sans beaucoup de manipulation.

pouvez vous me donner un aperçu de votre manière à vous peut être que cela me donnerais des idées à améliorer celui que j'ai fait ou bien à changer de cap.

en effet j'ai une commande avec deux articles en contremarque , l'opérateur génère sa contremarque par la suite la livraison car le numéro de livraison est primordial pour le service logistique(quin'est pas le même qui traite la commande initial), qui lui doit matcher par la suite une fois la commande passée par le logiciel tiers, la livraison se fait chez nous et par la suite le tout dans un même carton.

donc je dois boucler en construisant deux fichiers issu du même numéro de BL(qui sera le numéro auquel l'opérateur logistique doit se référer pour ranger tout ça une fois livré chez nous afin d'être livré par la suite à notre client final) mais le même fournisseur.
le tout doit être fait en amont par le service commercial qui traite les commandes. je vous donne un exemple du fichier de sortie souhaité final:

fichier 1:
ENT224441385/POH1705-0001920170522TEST2 TEST TEST SOS SAS 10-12 RUE VERTE BL1705-000041 94310 ORLY FR EUR
LIG 320005 TURBO ES 1PCE 20170522

Fichier 2:
ENT224441385/POH1705-002020170522TEST2 TEST TEST SOS SAS 10-12 RUE VERTE BL1705-000041 94310 ORLY FR EUR
LIG 3000 951 917 4013872722723 1PCE 20170522SACHS


aujourd'hui:
dans le même fichier j'ai les deux lignes avec une entête de la dernière ligne d'entête exporté, car je n'arrive pas à faire la condition initiale de savoir distinguer si Frn1 seul et si deux frn(s) je décide d'ouvrir deux fichiers séparés afin d'exporter chaque ligne avec sa propre entête.

j'espère que je te prends pas la tête avec ceci

[castorameur]

Bonjour,
je ne vois pas de manipulation supplémentaire pour l'utilisateur : dans le spé lié a votre bouton
-vous faites comptez le nbre de frn pour savoir combien ouvrir de fichier
-vous faites une boucle d'appel à votre export avec en paramètre le frn et le fichier

ou comme vous l'a dit bimiman et moi même vous avez votre code frn dans la vue avec un tri et vous faites vos fichiers au fur et a mesure

[madhouse2891]

Bonjour,
je suis désolé de mon retour assez tardif sur le sujet, voici le bloc de lignes de code utilisé afin de créer deux fichiers à partir d'un seul appel de mon action d'export:
pour rappel mon but était de pouvoir exporter des données sur un même fichier si même fournisseur, sur deux fichiers séparés si fournisseur différent dans les lignes.
je poste la solution au cas où des gens auront un besoin
##########################################################################################
$EXPORT11

[L]NBFIC = 0
[L]NBENRTOT = 0

For [CTP]BPSNUM(2)

[L]BPSID=[F:CTP]BPSNAM

[L]NBFIC += 1
[L]FICH = [L]HARMODIR + [L]HORO + "_" + GUSER + "_" + num$(NBFIC) + "_" + [L]BPSID +".csv"
Call ECR_TRACE("Fichier en sortie |" - [L]FICH, 0) From GESECRAN

Openo [L]FICH, 0 Using [FIC]
Iomode adxifs "" Using [FIC]
Iomode adxirs chr$(13)+chr$(10) Using [FIC]
Iomode adxium 50 Using [FIC]

Gosub HEAD_FIC
[L]NBENR = 1

For [CTP]BPSNUM

Gosub DETAIL_FIC
[L]NBENR += 1

Next

# Fermeture du fichier (avec un openo !)
Openo Using [FIC]

Call ECR_TRACE("Enregistrements écrits :" - num$([L]NBENR), 0) From GESECRAN
[L]NBENRTOT += [L]NBENR

Next

Call ECR_TRACE("Nombre total d'enregistrements écrits :" - num$([L]NBENRTOT), 0) From GESECRAN

Return

$HEAD_FIC

RAZ ZLIG, ZLIG1
ZLIG += format$("K:3X", [F:CTP]IDENT) # type d'enregistrement /obligatoire (O)
ZLIG += format$("K:3X", [F:CTP]DLPIO) # type de commande /conditionnel (C)
ZLIG += format$("K:20X", [F:CTP]IDCDE) # Numéro de commande / O
ZLIG += format$("D:YYYYMMDD", [F:CTP]DLVDAT) # Date livraison souhaitée / C
ZLIG += format$("K:14X", [F:CTP]BPCNUMBPS) # SIRET FRS / O
ZLIG += format$("K:13X", [F:CTP]EAN_FRS) # EAN FRS / C
ZLIG += format$("K:14X", [F:CTP]CODE_ACH) # Code distributeur / O
ZLIG += format$("K:13X", [F:CTP]EAN_ACH) # EAN distributeur / C
ZLIG += format$("K:14X", [F:CTP]CODE_LIV) # Code pt livraison / C
ZLIG += format$("K:13X", [F:CTP]EAN_LIV) # EAN pt livraison / C
ZLIG += format$("K:35X", [F:CTP]RAISON) # Raison sociale / C
ZLIG += format$("K:35X", [F:CTP]ADRESSE1) # adresse livraison1 / C
ZLIG += format$("K:35X", [F:CTP]ADRESSE2) # adresse livraison2 /utilise pour le N° BL / Client
ZLIG += format$("K:9X", [F:CTP]POSTALCOD) # Code postal / C
ZLIG1 += format$("K:35X", [F:CTP]COMMUNE) # Commune / C
ZLIG1 += format$("K:3X", [F:CTP]CPY) # Code pays / C
ZLIG1 += format$("K:35X", [F:CTP]NUMOP) # operation promo / C
ZLIG1 += format$("K:3X", [F:CTP]DEVISE) # devise / C
ZLIG1 += format$("K:3X", [F:CTP]COND_LIV) # condition livraison / C
ZLIG1 += chr$(13)+chr$(10)
Wrseq [L]ZLIG, [L]ZLIG1, Using [FIC]

Return


$DETAIL_FIC
RAZ LIG
LIG += format$("K:3X", [F:CTP]IDENT2)
LIG += format$("K:4X", [F:CTP]NUMLIG)
LIG += format$("K:35X", [F:CTP]ITMREFBPS)
LIG += format$("K:13X", [F:CTP]ITMDESBPS)
LIG += format$("K:35X", [F:CTP]DESIGNATION)
LIG += format$("N:9X", [F:CTP]QTE)
LIG += format$("K:3X", [F:CTP]UNITE)
LIG += format$("K:11X", [F:CTP]PRIX)
LIG += format$("K:3X", [F:CTP]TYPRIX)
LIG += format$("D:YYYYMMDD", [F:CTP]DLVDAT2)
LIG += format$("K:35X", [F:CTP]CODE_FAB)
LIG += chr$(13)+chr$(10)
Wrseq LIG, Using [FIC]

Return
#####################################################################
je remercie tous ceux qui m'ont répondu lors de l'ouverture de mon post, et vous souhaite une agréable journée.

[hado34]

en placant le code fournisseur dans votre index, vous pourrez trier votre table sur ce champs et faire une boucle avec un break voir la doc du For Next
Cela permet de sortir de la premiere boucle a chaque changement de fournisseur dans les enregistrements

[madhouse2891]

Merci hado34,
le développement actuel fonctionne très bien et fais l'affaire, il m’éclate autant de fichiers que de fournisseurs présents dans mon export.
j'ai juste posté le dev final avec lequel j'ai réussi à résoudre mon problème de départ.
bonne journée à vous