Discussion :

[sebastien david]

Bonjour,

je suis novice en VBA.
j'ai appris avec l'aide de ces forum et là, ca fait un jour que je sèche... voici mon probleme :

j'ai écris la rechercheV suivante, jusque la ca fonctionne :

Bonjour,

je suis novice en VBA.
j'ai appris avec l'aide de ces forum et là, ca fait un jour que je sèche... voici mon probleme :

j'ai écris la rechercheV suivante, jusque la ca fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub test11()
With Sheets("Ligne1")
.Range("$K$7:$K$750").Value = WorksheetFunction.VLookup(.Range("$B$7:$B$750").Value, Sheets("data").Range("A1:U100"), 6, False)
 
End With
End Sub

Mais à partir de cette recherchev, je souhaiterai remplacer les valeurs #n/a par " 0 "
Je pensais utiliser la fonction IFERROR mais impossible....

est ce réalisable ? si oui pouvez vous m'aider ?

Merci d'avance

Mais à partir de cette recherchev, je souhaiterai remplacer les valeurs #n/a par " 0 "
Je pensais utiliser la fonction IFERROR mais impossible....

est ce réalisable ? si oui pouvez vous m'aider ?

Merci d'avance

[Pierre Fauconnier]

Salut.

Tu as plusieurs solutions:

• Test1 qui imbrique application.vlookup dans application.iferror;
• Test2 qui travaille avec Evaluate(...);
• Test3 qui teste le retour de VLookup. Attention, la variable qui reçoit la valeur de VLookUp doit être un variant pour permettre la récupération de l'erreur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub test1()
  Dim Resp As Variant
 
  Resp = Application.IfError(Application.VLookup("Perre", Range("tableau1"), 2, False), "Erreur")
  MsgBox Resp
End Sub
 
Sub test2()
  Dim Resp
 
  Resp = Evaluate("iferror(vlookup(""Pierre"",tableau1,2,0),""Erreur"")")
  MsgBox Resp
End Sub
 
Sub Test3()
  Dim Resp As Variant
 
  Resp = Application.VLookup("Pierre", Range("tableau1"), 2, False)
  If Not IsError(Resp) Then
    MsgBox Resp
  Else
    MsgBox "Erreur"
  End If
End Sub

Tu remarqueras que je travaille systématiquement avec des tables de données (Insertion/Tableaux/Tableau) qui permettent d'éviter de mettre en dur dans le code l'adresse de la plage. En utilisant un tableau, ta table peut être modifiée en taille sans que tu doives adapter ton code ou en tester la taille. Les tables de données existent depuis XL2007 (en fait, cette notion a pointé le bout de son nez en 2003, mais de façon très discrète), il devient temps d'intégrer cet outil dans les classeurs et dans le code VBA

[sebastien david]

Merci beaucoup pour la rapidité de la réponse et l'efficacité ! ca fonctionne !!