Discussion :

[clairou56]

Bonjour à tous,

j'ai besoin de votre aide sur Access.
Je cherche à créer une copie d'un fichier fichier 1 à l'emplacement Source dans l'emplacement Destination.
Je sais le faire en VBA avec un filecopy mais impossible d'y parvenir en Access.
J'ai du mal avec l'importation des objets Excel sur Access je pense..

Pourriez - vous m'aider ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub fonctioncopie()
 
Dim oAppExcel As Excel.Application
Dim oWbk As Excel.Workbook
 
        ' Lance Excel
        Set oAppExcel = New Excel.Application
 
        'Ouvre le classeur
        Set oWbk = oAppExcel.Workbooks.Open(Chemin)
        oAppExcel.Visible = True
 
Const Sep = " \ "
 
Dim BasePath As String
BasePath = CurrentProject.Path
 
Dim Source
Dim Destination
 
Source = BasePath & Sep & "Fichier 1.xlsm"
Destination = BasePath & Sep & "Dossier1" & Sep & "Dossier 2"
 
Dim Fso As Object
Set Fso = CreateObject("Scripting.FileSystemObject")
 
Fso.FileCopy Source, Destination
 
End Sub

je voudrais aussi rajouter dans ce même fichier, à la cellule Cells(1,9), une valeur textuelle mais j'ai un message d'erreur qui buge ma macro..

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Dim oAppExcel As Excel.Application
Dim oWbk As Excel.Workbook
Dim oSht As Excel.Worksheet
 
oSht.Cells(1, 9) = "test"

[tee_grandbois]

Bonsoir,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set oWbk = oAppExcel.Workbooks.Open(Chemin)

Ta variable chemin est vide, donc tu n'ouvriras jamais ton fichier.
Je suppose que c'est le fichier Source qu'il faut ouvrir et copier c'est donc cette variable qu'il faut utiliser.
Il faut aussi enlever les espaces de la variable sep.
Si les dossiers ne sont pas créés, il y aura un message d'erreur, il faut donc utiliser Fso.FolderExists pour tester l'existence et MkDir pour les créer si besoin (j'ai mis un exemple pour Dossier1, mais il faudrait le faire aussi pour Dossier 2)
Pour l'insertion du texte dans la cellule, il manquait l'affectation des variables oWbk et oSht, car il ne suffit pas de les déclarer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub fonctioncopie()
Dim oAppExcel As Excel.Application
Dim oWbk As Excel.Workbook
Dim chemin As String
Dim BasePath As String
Dim Source As String
Dim Destination As String
Dim Fso As Object
Dim oSht As Excel.Worksheet
 
' Affectations des constantes et variables
Const Sep = "\"
BasePath = CurrentProject.Path
Source = BasePath & Sep & "Fichier 1.xlsm"
Destination = BasePath & Sep & "Dossier1" & Sep & "Dossier 2" & Sep & "Fichier 2.xlsm"
 
' Vérifie l'existence du Dossier
Set Fso = CreateObject("Scripting.FileSystemObject")
If Not Fso.folderexists(BasePath & Sep & "Dossier1") Then
    MkDir (BasePath & Sep & "Dossier1")
End If
 
' Lance Excel
Set oAppExcel = New Excel.Application
'Ouvre le classeur
Set oWbk = oAppExcel.Workbooks.Open(Source)
oAppExcel.Visible = True
 
Fso.CopyFile Source, Destination   ' c'est Copyfile et pas FileCopy
 
oWbk.Close
 
' Ajout du texte dans une cellule
Set oWbk = oAppExcel.Workbooks.Open(Destination)
Set oSht = oWbk.Worksheets("Feuil1")    ' mettre le nom correct de la feuille si besoin
oSht.Cells(1, 9) = "test"
oWbk.Close True
 
oAppExcel.Quit
 
End Sub

[clairou56]

Mille merci tee_grandbois !! Mon erreur venait en réalité de ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
const Sep = "\"      'je n'avais pas l'espace sur ma macro donc ce n'était pas ça le soucis par contre :
 
DestinationModele = BasePath & Sep & "Dossier Application" & Sep & "Fichiers ST Vide" & Sep
'Mon erreur venait  du dernier & Sep.. c'est un dossier donc il faut rajouter un "\" ! J'avais fait la même erreur en VBA en plus.. !

Pour la valeur de la cellule c'est cela merci ! :-)

J'étais bloqué dessus depuis quelques semaines alors ça me fait bien avancer !
Je pense utiliser le forum plus souvent pour le coup :-D !

Bon dimanche