Discussion :

[benoitbrisefer]

Bonjour,
Soit la table SAS suivante :

Departement	Nom
0001	Nom1
0001	Nom2
0001	Nom3
0002	Nom4
0002	Nom5
0003	Nom6

Je voudrais créer autant de fichier Excel (3 dans l'exemple ici) qu'il n'y a de départements différents dans la table.
Comment puis-je procéder ?

[Rageo]

Bonjour,

Le code ci dessous devrait vous aider :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
 
 
DATA extrait;
INFILE CARDS;
INPUT Departement $ Nom $;
CARDS;
0001 Nom1
0001 Nom2
0001 Nom3
0002 Nom4
0002 Nom5
0003 Nom6
;
RUN;
 
%MACRO export();
 
/* On extrait les départements en supprimant les doublons */
PROC SORT DATA=extrait (KEEP=Departement) OUT=extrait_tri NODUPKEY;
	BY Departement;
RUN;
 
/* On stocke le nom des départements dans des macro-variables et on récupère le nombre total de départements */
DATA _null_;
	SET extrait_tri;
	CALL SYMPUT("Dpt"||LEFT(_N_),compress(Departement));
	CALL SYMPUT("Total",_N_);
RUN;
 
%DO i=1 %TO &Total;
 
        /* On crée une table pour chaque département */
	DATA Dpt&i;
		SET extrait;
		WHERE "&&Dpt&i" = Departement;
	RUN;
 
	%PUT Dpt&i="&&Dpt&i";
 
        /* On crée un fichier Excel pour chaque département à l'aide des macros variables ou l'on a stocké le nom des départements */
	PROC EXPORT DATA=Dpt&i
		OUTFILE="C:\chemin du répertoire\&&DPT&i"
		DBMS=xlsx
		REPLACE;
	RUN;
 
%END;
 
%MEND export;
 
%export;

Bon courage !

[benoitbrisefer]

Bonjour,

Merci pour ce code qui fonctionne parfaitement !
Juste une dernière demande :
Comment procéder pour que le fichier Excel créé soit sous la forme suivante :
DEP_0001_Done.Xlsx (où 0001 est le departement bien sûr).
Merci d'avance.