Discussion :

[beuzy]

Bonjour à tous,
J'ai un besoin qui vient de tomber pour un client distributeur :
Il veut recevoir ses AR par mail (jusqu'ici tout va bien) mais ce mail doit être envoyé au client final et doit contenir un peu de texte (impérativement texte brut) + le pdf de l'accusé de commande, idem pour la facture
En gros je ne sais pas trop si il est mieux de faire un programme qui detecte les flux de ce client et envoi des mails (mais du coup comment récupérer le pdf de facture) ou si il faut trouver un user exit dans les programmes d'édition des formulaires
Ou une autre solution, j'aimerai votre avis savoir ce qui est le plus judicieux
merci

[Bebel]

Bonjour,

Pour la solution du user exit, ça peut être compliqué à mon avis. Car il faut déjà les trouver, modifier le contenu de la NAST (soit niveau variable,soit avant l'enregistrement) pour remplacer le client par le client final. Plus pouvoir rajouter du texte, car par défaut il colle directement le PDF dans le mail et basta.

Je pencherais plus pour un programme qui gère cela.
Pour récupérer le PDF, tu génères le spool, tu peux aller le récupérer ensuite avec des fonctions.
Regarde du côté de la fonction RSPO_FIND_SPOOL_REQUESTS et ensuite tu envoie ton mail avec ton contenu brut + la pièce jointe.

[beuzy]

Merci de la réponse, oui je suis partie sur le développement spécifique pour l instant j'envoi juste un mail je n'ai pas encore eu le temps de me coller à la PJ.
J'aurais 2 questions du coup :
- comment faire qu'il n y ai pas d'accusé d'envoi/lecture sur la boite mail de l'expéditeur car du coup il est spammé de message je farfouille dans la classe CL_BCS mais en vain
- y a t'il une façon simple de simuler l'edition du smartforms de facture? car de ce que je vois y a pas mal de MF à enchainer (d'apres le programme d edition de facture et il faut des données dans la nast)

Merci

[Bebel]

Pour l'accusé de réception regarde sur cette page d'aide : https://help.sap.com/saphelp_nw70ehp...e/frameset.htm

En gros, c'est une option activée dans la SOST.


Pour le smartforms, généralement pour le tester, je fais un petit programme spécifique qui appelle la FM générée par le smartforms.
Tu trouves le nom dans le menu Environnement > Function module name (ou tu utilises la FM SSF_FUNCTION_MODULE_NAME avec le nom de ton smartforms et tu utilise ce que te renvoie cette fonction en dynamique)

Par contre en fonction de tes données en entrées dans ton smartforms, tu peux avoir besoin de faire quelques sélections avant.

[beuzy]

Bonjour,
oui j'ai trouvé la fonction dans SOST mais malheureusement j'ai du mettre l email en exception car certains ont besoins des accusés en esperant que cela ira car bizarrement quand je teste avec mon email je n'ai rien dans tous les cas ^^ je vais voir pour le MF merci

[beuzy]

Bonjour, Je reviens à la charge sur l'envoi du PDF
Alors j'ai reussi à faire envoyer une facture mais le PDF est vide... je seche un peu voici mon enchainement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
* determine smartform function module for invoice
  CALL FUNCTION 'SSF_FUNCTION_MODULE_NAME'
  EXPORTING
    formname           = lf_formname
  IMPORTING
    fm_name            = lf_fm_name
  EXCEPTIONS
    no_form            = 1
    no_function_module = 2
    OTHERS             = 3.

  ls_control_param-getotf = 'X'.
  ls_control_param-no_dialog = 'X'.

* call smartform invoice
  CALL FUNCTION lf_fm_name
  EXPORTING
    control_parameters = ls_control_param
    output_options     = ls_composer_param
    user_settings      = space
    is_bil_invoice     = ls_bil_invoice
    is_nast            = nast
    is_repeat          = repeat
  IMPORTING
    job_output_info    = ls_job_info
  EXCEPTIONS
    formatting_error   = 1
    internal_error     = 2
    send_error         = 3
    user_canceled      = 4
    OTHERS             = 5.

**  .........................CONVERT TO OTF TO PDF.......................

  CALL FUNCTION 'CONVERT_OTF_2_PDF'
  IMPORTING
    bin_filesize           = v_bin_filesize
  TABLES
    otf                    = ls_job_info-otfdata
    doctab_archive         = it_docs
    LINES                  = it_lines
  EXCEPTIONS
    err_conv_not_possible  = 1
    err_otf_mc_noendmarker = 2
    OTHERS                 = 3.
*
  CALL FUNCTION 'QCE1_CONVERT'
  TABLES
    t_source_tab               = it_lines
    t_target_tab               = it_content
* EXCEPTIONS
*   CONVERT_NOT_POSSIBLE       = 1
*   OTHERS                     = 2
    .
 [.....]
**** Description pièce jointe
      s_attachments-doc_type = 'PDF'.
      MOVE 'Votre facture ' TO s_attachments-subject .
      MOVE 'Votre facture ' TO s_attachments-filename .
      s_attachments-objtp = 'PDF'.

*** Contenu pièce jointe
** Données

      LOOP AT it_content INTO wa_content.
        CONCATENATE w_metastring wa_content-LINE INTO w_metastring.
      ENDLOOP.
      REFRESH : w_soli[], w_solix[], w_attachments[], w_recipients[].

      CALL FUNCTION 'SCMS_STRING_TO_FTEXT'
      EXPORTING
        TEXT      = w_metastring
      TABLES
        ftext_tab = w_soli.

      CALL FUNCTION 'SCMS_STRING_TO_XSTRING'
      EXPORTING
        TEXT   = w_metastring
      IMPORTING
        BUFFER = w_buff.

      CALL FUNCTION 'SCMS_XSTRING_TO_BINARY'
      EXPORTING
        BUFFER     = w_buff
      TABLES
        binary_tab = w_solix.


      DESCRIBE TABLE w_soli[] LINES w_lines.
      s_attachments-docsize = w_lines * 2 * 255.

      s_attachments-cont_text[] = w_soli[].
      s_attachments-cont_hex[] = w_solix[].
      APPEND s_attachments TO w_attachments.

Appel du module d'envoi de mail

Je me demande si le souci vient pas qu'il faille mettre un separateur ou autre dans le "metastring" car je le fais pour creer un fichier csv avec un separateur mais pour le pdf aucune idée

[Bebel]

Salut,
je viens de faire un test, je n'ai pas eu besoin de faire tout cela pour la conversion, regarde

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156

*&---------------------------------------------------------------------*
*& Report ZTEST_MAIL
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ztest_mail.



DATA:fm_name            TYPE rs38l_fnam.
DATA:wa_control_par     TYPE ssfctrlop.
DATA:it_otf_data        TYPE ssfcrescl.
DATA:it_otf_final       TYPE itcoo OCCURS 0 WITH HEADER LINE.
DATA:bin_filesize       TYPE i.
DATA:it_pdfdata         TYPE TABLE OF tline.
DATA:it_pdf             TYPE TABLE OF solisti1.
DATA :g_sent_to_all     TYPE sonv-flag.
DATA :g_tab_lines       TYPE i.

DATA :i_document_data TYPE STANDARD TABLE OF sodocchgi1,
      i_packing_list  TYPE STANDARD TABLE OF sopcklsti1,
      i_attachment    TYPE STANDARD TABLE OF solisti1,
      i_body_msg      TYPE STANDARD TABLE OF solisti1,
      i_receivers     TYPE STANDARD TABLE OF somlreci1,
      i_pdf           TYPE STANDARD TABLE OF tline,
      w_document_data LIKE LINE OF i_document_data,
      w_packing_list  LIKE LINE OF i_packing_list,
      w_attachment    LIKE LINE OF i_attachment,
      w_body_msg      LIKE LINE OF i_body_msg,
      w_receivers     LIKE LINE OF i_receivers,
      w_pdf           LIKE LINE OF i_pdf.

START-OF-SELECTION.
  "Get Function module name for given smartform
  CALL FUNCTION 'SSF_FUNCTION_MODULE_NAME'
    EXPORTING
      formname = 'ZDBEL_TEST'
    IMPORTING
      fm_name  = fm_name.

  wa_control_par-getotf    = 'X'.   "Set this to get OTF data
  wa_control_par-no_dialog = 'X'.   "It supresses the Printer dialog.
  wa_control_par-preview   = space.   "It supresses the Printer dialog.

  CALL FUNCTION fm_name
    EXPORTING
      control_parameters = wa_control_par
    IMPORTING
      job_output_info    = it_otf_data
    EXCEPTIONS
      formatting_error   = 1
      internal_error     = 2
      send_error         = 3
      user_canceled      = 4
      OTHERS             = 5.
  IF sy-subrc <> 0.
    WRITE: 'DIE ', sy-subrc.
    STOP.
  ENDIF.



  APPEND LINES OF it_otf_data-otfdata[] TO it_otf_final[].

  CALL FUNCTION 'CONVERT_OTF'
    EXPORTING
      format       = 'PDF'
    IMPORTING
      bin_filesize = bin_filesize
    TABLES
      otf          = it_otf_final
      lines        = it_pdfdata[].

  CALL FUNCTION 'SX_TABLE_LINE_WIDTH_CHANGE'
    EXPORTING
      line_width_dst = '255'
    TABLES
      content_in     = it_pdfdata[]
      content_out    = it_pdf[].
  IF sy-subrc = 0.
    "Send mail
    PERFORM send_mail.
  ENDIF.

*&---------------------------------------------------------------------*
*&      Form  SEND_MAIL
*&---------------------------------------------------------------------*
FORM send_mail .
  "Subject of the mail.
  w_document_data-obj_name  = 'MAIL_TO_HEAD'.
  w_document_data-obj_descr = 'Regarding Mail Program by SAP ABAP'.
  "Body of the mail
  w_body_msg = 'This is body of mail msg.'.
  APPEND w_body_msg TO i_body_msg.
  CLEAR  w_body_msg.
  "Write Packing List for Body
  DESCRIBE TABLE i_body_msg LINES g_tab_lines.
  w_packing_list-head_start = 1.
  w_packing_list-head_num   = 0.
  w_packing_list-body_start = 1.
  w_packing_list-body_num   = g_tab_lines.
  w_packing_list-doc_type   = 'RAW'.
  APPEND w_packing_list TO i_packing_list.
  CLEAR  w_packing_list.
  "Write Packing List for Attachment
  w_packing_list-transf_bin = 'X'.
  w_packing_list-head_start = 1.
  w_packing_list-head_num   = 1.
  w_packing_list-body_start = 1.
  DESCRIBE TABLE it_pdf LINES w_packing_list-body_num.
  w_packing_list-doc_type   = 'PDF'.
  w_packing_list-obj_descr  = 'PDF Attachment'.
  w_packing_list-obj_name   = 'PDF_ATTACHMENT'.
  w_packing_list-doc_size   = w_packing_list-body_num * 255.
  APPEND w_packing_list TO i_packing_list.
  CLEAR  w_packing_list.
  "Fill the document data and get size of attachment
  w_document_data-obj_langu  = sy-langu.
  READ TABLE it_pdf INTO w_pdf INDEX g_tab_lines.
  w_document_data-doc_size = ( g_tab_lines - 1 ) * 255 + strlen( w_attachment ).
  "Receivers List.
  w_receivers-rec_type   = 'U'."Internet address
  w_receivers-receiver   = 'test@test.com'.
  w_receivers-com_type   = 'INT'.
  w_receivers-notif_del  = 'X'.
  w_receivers-notif_ndel = 'X'.
  APPEND w_receivers TO i_receivers .
  CLEAR:w_receivers.
  "Function module to send mail to Recipients
  CALL FUNCTION 'SO_NEW_DOCUMENT_ATT_SEND_API1'
    EXPORTING
      document_data              = w_document_data
      put_in_outbox              = 'X'
      commit_work                = 'X'
    IMPORTING
      sent_to_all                = g_sent_to_all
    TABLES
      packing_list               = i_packing_list
      contents_bin               = it_pdf
      contents_txt               = i_body_msg
      receivers                  = i_receivers
    EXCEPTIONS
      too_many_receivers         = 1
      document_not_sent          = 2
      document_type_not_exist    = 3
      operation_no_authorization = 4
      parameter_error            = 5
      x_error                    = 6
      enqueue_error              = 7
      OTHERS                     = 8.
  IF sy-subrc = 0 .
    MESSAGE i303(me) WITH 'Mail has been Successfully Sent.'.
  ENDIF.
ENDFORM.                    " SEND_MAIL

[beuzy]

Bonjour, oui c'est parce que je n'utilise pas ce MF

[Bebel]

Bon du coup, je présume que tu as utilisé la classe ?

le code est encore plus simple.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
*&---------------------------------------------------------------------*
*& Report ZTEST_MAIL
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ztest_mail.



DATA:fm_name            TYPE rs38l_fnam.
DATA:wa_control_par     TYPE ssfctrlop.
DATA:it_otf_data        TYPE ssfcrescl.
DATA:it_otf_final       TYPE itcoo OCCURS 0 WITH HEADER LINE.
DATA:it_pdfdata         TYPE TABLE OF tline.
DATA:w_bin_file         TYPE xstring.

START-OF-SELECTION.
  "Get Function module name for given smartform
  CALL FUNCTION 'SSF_FUNCTION_MODULE_NAME'
    EXPORTING
      formname = 'ZDBEL_TEST'
    IMPORTING
      fm_name  = fm_name.

  wa_control_par-getotf    = 'X'.   "Set this to get OTF data
  wa_control_par-no_dialog = 'X'.   "It supresses the Printer dialog.
  wa_control_par-preview   = space.   "It supresses the Printer dialog.

  CALL FUNCTION fm_name
    EXPORTING
      control_parameters = wa_control_par
    IMPORTING
      job_output_info    = it_otf_data
    EXCEPTIONS
      formatting_error   = 1
      internal_error     = 2
      send_error         = 3
      user_canceled      = 4
      OTHERS             = 5.
  IF sy-subrc <> 0.
    WRITE: 'DIE ', sy-subrc.
    STOP.
  ENDIF.



  APPEND LINES OF it_otf_data-otfdata[] TO it_otf_final[].

  CALL FUNCTION 'CONVERT_OTF'
    EXPORTING
      format       = 'PDF'
    IMPORTING
      bin_file     = w_bin_file
    TABLES
      otf          = it_otf_final
      lines        = it_pdfdata[].

  PERFORM send_mail_object.


FORM send_mail_object.

  DATA: lo_send_request  TYPE REF TO cl_bcs,
        lt_text          TYPE bcsy_text,
        lo_sender        TYPE REF TO cl_sapuser_bcs,
        lt_pdf_data      TYPE solix_tab,
        lo_recipient     TYPE REF TO if_recipient_bcs,
        lo_document      TYPE REF TO cl_document_bcs.


* définition de l'expéditeur
  lo_sender = cl_sapuser_bcs=>create( sy-uname ).
  lo_send_request = cl_bcs=>create_persistent( ).
  lo_send_request->set_sender( i_sender = lo_sender ).


* ajout de destinataire
  CLEAR lo_recipient.
  lo_recipient = cl_cam_address_bcs=>create_internet_address( 'test@test.com' ).
  CALL METHOD lo_send_request->add_recipient
    EXPORTING
      i_recipient = lo_recipient
      i_express   = 'X'.

* gestion du texte
  REFRESH lt_text.
  APPEND 'Ceci est un test d envoi de mail' TO lt_text.

* gestion du corps du mail
  lo_document = cl_document_bcs=>create_document( i_type    = 'HTM'
                                                  i_text    = lt_text
                                                  i_subject = 'Pièce jointe' ).


* ajout du document
  CALL METHOD cl_document_bcs=>xstring_to_solix
    EXPORTING
      ip_xstring = w_bin_file
    RECEIVING
      rt_solix   = lt_pdf_data.


  lo_document->add_attachment( i_attachment_type    = 'PDF'
                               i_attachment_subject = 'facture.PDF'
                               i_att_content_hex    =  lt_pdf_data ).

  lo_send_request->set_document( lo_document ).

  lo_send_request->send( i_with_error_screen = 'X' ).



  COMMIT WORK.

ENDFORM.