Discussion :

[Nulll]

Bonjour à tous,

Je fais arriver des flux provenant de Google finances dans différents dossiers de flux (PostItem).

Est-ce à cause de ma source? Je me retrouve régulièrement avec des multiples de la même info.

J'ai adapté du code trouvé pour les éliminer relativement rapidement. Avec le code original, je dois exécuter ma macro. Elle ouvre une fenêtre qui me permet de sélectionner le dossier à traiter. Ensuite, une autre fenêtre s'ouvre pour que je puisse choisir le dossier destination.

Ça fonctionne mais c'est long. J'ai entrepris de rendre cela bien plus rapide.

J'ai d'abord éliminé le choix destination. Je pointe vers la poubelle. Ça marche sans problème.

Maintenant cela se corse!

Pourquoi lancer une macro alors qu'un événement pourrait se déclencher dans certaines conditions?

Le seul événement exploitable (sauf erreur) est Application_ItemLoad

Voici comment j'appelle ma fonction de nettoyage:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub Application_ItemLoad(ByVal Item As Object)
 
If TypeOf Item Is PostItem Then
 
  TrierLesDoublonsV4 ' ma fonction de nettoyage. J'ai juste introduit avant un msgbox pour me laisser le choix de finalement nettoyer ou non
 
End If
 
End Sub

C'est vraiment super! Ça fonctionne à un détail prêt. Je suis incapable de différencier un dossier de flux d'un élément RSS. C'est embêtant car ce que je veux c'est que le msgbox que j'ai intercalé, apparaisse pour me proposer le nettoyage, seulement quand je clique sur le dossier et NON quand je clique sur une info!

Merci par avance

[Oliv-]

Bjr,
je ne pense pas que l’événement se déclenche "quand" tu cliques sur un dossier, il se déclenche parce qu'il affiche le premier élément de ce dossier un post rss

[Nulll]

Oui effectivement, bien réveillé ce matin, cela me parait évident ...

... mais malheureusement ne m'apporte pas l'ombre d'un début de nouvelle piste à explorer

Aucune difficulté de trouver le dossier actif mais rien vu pour identifier un post RSS actif. Je pense qu'il en aurait été autrement si j'avais été du côté courriel.

C'est fou, j'ai pas mal l'habitude de coder dans Access et évidemment aussi dans Excel. Mais dès que je m'aventure dans d'autres produits d'office ... bonjour la galère.

[Oliv-]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Set selectionné = ActiveExplorer.Selection(1)
Set ouvert = ActiveInspector.CurrentItem

et après tu vérifies la propriété .class

[Nulll]

Vraiment merci pour le suivi!

J'ai donc exploré l'idée ainsi en espérant que j'ai bien compris ce qui m'était proposé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Public Sub TrierLesDoublonsV4()
 
Dim objApp As Outlook.Application
    Set objApp = Application
On Error Resume Next
Select Case TypeName(objApp.ActiveWindow)
    Case "Explorer"
        Set CurrentItem = objApp.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
        Set CurrentItem = objApp.ActiveInspector.CurrentItem
End Select
 
Dim PostItem As Outlook.PostItem
Set PostItem = CurrentItem
 
x = CurrentItem.Class
 
'suit le msgbox et le code de nettoyage

Après plusieurs tests il s'avère que c'est toujours au travers d'Explorer que CurrentItem est défini.

Que je clique sur un post ou sur un dossier j'ai toujours 45 pour la classe. Est-ce à cause de l'événement que j'ai choisi? Je n'arrive donc pas à différencier le type d'objet que j'ai cliqué.

Il y a très peu de types d'événements proposés dans Outlook. J'aurais préféré faire un double clique ou clique droit avec menu contextuel modifié mais cela m'a paru bien plus compliqué voire infaisable. Maintenant je commence à me demander si je n'aurais pas dû en baver un peu dès le départ

[Oliv-]

Tu n as pas compris ! Tu as toujours 45 parce que quand tu cliques sur un dossier il y a un clic implicit sur l item sélectionné !

En fait dans ton evenement load tu dois instancier une variable qui va designer ton post et dont tu utiliseras les événements.

Regarde ce sujet c est pareil sauf que c est pas un mailitem mais un postitem
https://www.developpez.net/forums/bl...mails-outlook/

[Nulll]

Vraiment merci Oliv-

Vu l'exemple donné, effectivement j'étais complètement dans les patates

Je vais faire mieux que simplement remplacer mailItem par postItem:Je vais sérieusement réviser mes connaissances sur les modules de classe (je ne suis même pas sûr qu'elles aient été un jour assez solide pour travailler avec). Jusqu'à présent je m'en suis toujours très bien sorti sans, dans le ronron vba qui m'était utile. Cette fois je n'ai pas le choix il semble. Alors autant le faire intelligemment en comprenant bien ce que je fais.

Promis, je reviens dans qq jours donner des nouvelles sur cette question

[Oliv-]

Tu peux faire sans la partie moduke de classe, la seule chose c est que le clic sur un post va remplacer dans la variable l objet par celui qye tu viens de cliquer

[Nulll]

Là je suis complètement perdu avec la dernière réponse. Alors il ne me reste plus qu'à rajouter bien des l et ! à mon pseudo

[Oliv-]

Mon exemple sera plus clair ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
  Public WithEvents AP As PostItem
 
Private Sub Application_ItemLoad(ByVal Item As Object)
 
    If Item.Class = 45 Then
             Set AP = Item
    End If
 
End Sub
 
Private Sub AP_Open(Cancel As Boolean)
 
MSGBOX AP
End Sub

DANS les 2 menus déroulants au dessus de ton code tu auras
"AP " à Gauche et dans celui de droite les événements de AP QUE TU PEUX UTILISER

[Nulll]

Merci, ce code était très clair. J'ai essayé ensuite de créer quelques variantes dont certaines avec d'autres événements de AP . Mais je ne vois le début de l'ombre d'une piste de solution.

Probablement que la suite de la solution se trouve dans le premier exemple de code qui m'a été donné. Je vais donc y replonger à la lumière de la dernière réponse.

Au cas ou, le rappel de mon besoin: Je clique sur le dossier contenant les flux: J'ai un msgbx qui me propose de nettoyer. Sinon, si je clique sur le flux lui même (ou me déplace), il ne se passe rien de particulier: je ne veux pas voir apparaître le message!

Heureusement qu'Oliv- est patient!

[Oliv-]

SAlut,

Tu veux que ton traitement se déclenche en cliquant uniquement sur le dossier ?


dans ce cas là c'est plutôt un événement lié à explorer qu'il faut gérer sur BeforeFolderSwitch

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Public WithEvents myOlExp As Outlook.Explorer
 
Public Sub Initialize_handler()
    Set myOlExp = Application.ActiveExplorer
End Sub
 
Private Sub myOlExp_BeforeFolderSwitch(ByVal NewFolder As Object, Cancel As Boolean)
    If NewFolder.Name = "Off Limits" Then
        MsgBox "You do not have permission to access this folder."
        Cancel = True
    End If
End Sub

[Nulll]

Exactement!

Ce matin (je suis au Canada) je suis en train d'explorer une solution plan B en utilisant GetAsyncKeyState parce que, bien entendu , la boite à outil d'Outlook semble bien vide à côté d'Access ou Excel.

Mais je suis toujours preneur de mon plan A!

[Nulll]

Bon, mon plan b ... finalement ne fonctionne pas dans tous les cas de figures (notamment changer de dossier alors que "n" n'a pas été appuyé dans la séquence précédente. L'attente de l'appui sur la touche empêche l'affichage des nouveaux flux)

L'idée: On a vu qu'il était facile de détecter quand on était dans les flux RSS. La difficultée (pour moi) détecter si je cliquais sur un dossier ou un post lui-même. Donc si on essaye de contourner cela:
Initialement, l'étape d'après était d'afficher un msgbox demandant s'il fallait procéder au nettoyage ou non. Je remplace cela par la détection d'une touche particulière (en l’occurrence N pour nettoyage). L'attente de l'enfoncement de cette touche est initiée par la détection que je suis du côté RSS d'Outlook. J'ai donc repris le début du code proposé. Ce qui donne:

Dans un module:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public Declare PtrSafe Function GetAsyncKeyState Lib "user32.dll" (ByVal vKey As Long) As Integer 'retirer PtrSafe pour PC 32 bits. C'est la fonction qui renvoie l'information de touche enfoncée
 
Private Const VK_N = &H4E 'Constante pour la lettre n
 
'Une fois cette fonstion appelée, elle va boucler tant que la lettre attendue n'est pas enfoncée (ici n)
Sub WaitUntil_N_Key()
Do Until GetAsyncKeyState(VK_N)
    DoEvents
Loop
'Ma macro de nettoyage
End Sub

Source d'inspiration: https://vb.developpez.com/faq/?page=...tAsyncKeyState

Dans ThisOutlookSession:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub Application_ItemLoad(ByVal Item As Object)
 
    If Item.Class = 45 Then
 
             WaitUntil_N_Key
    End If
 
End Sub

Ça fonctionne bien, peut être c'Est améliorable. J'espère que cela pourra aider. Mais tout de même, par curiosité j'aimerais vraiment savoir si on aurait pu différencier le clic sur un dossier d'un clic sur un post!

[Oliv-]

il faudrait que tu essayes avec cela j'ai adapté l'exemple de mon post précédent à ton cas

dans thisOutlookSession

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Public WithEvents myOlExp As Outlook.Explorer
 
 
Private Sub Application_Startup()
 
Initialize_handler
 
End sub
 
 
Public Sub Initialize_handler()
    Set myOlExp = Application.ActiveExplorer
End Sub
 
Private Sub myOlExp_BeforeFolderSwitch(ByVal NewFolder As Object, Cancel As Boolean)
 
    If StrComp(NewFolder.Name, "Abonnements RSS", vbTextCompare) <> 0 And InStr(1, NewFolder.FullFolderPath, "\Abonnements RSS\") > 0 Then
        MsgBox "Vous êtes dans un dossier RSS : " & vbCr & NewFolder.Name
'ici tu lances ton traitement
        'call doublons
    End If
End Sub

[Oliv-]

Pour ne pas perdre l'événement en cas de réinitialisation des variables tu peux ajouter à l’événement Application_NewMail

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Application_NewMail()
    If myOlExp Is Nothing Then Set  Set myOlExp = Application.ActiveExplorer
End sub

où dans Private Sub Application_ItemLoad(ByVal Item As Object)

[Nulll]

Amusant!

Je ne comprenais pas pourquoi l'événement BeforeFolderSwitch ne se déclenchait pas. Et bien tout simplement parce que dans ThisOutlookSession j'avais laissé Application_ItemLoad (même avec le code désactivé dedans).

Donc une fois cela réglé, BeforeFolderSwitch a été appelé à chaque changement de dossier. Cependant, à ce stade, il vous manque une information capitale: J'ai plusieurs dossiers RSS et donc évidemment avec des noms personnalisés (celui du titre financier surveillé). Le code de validation proposé ne peut fonctionner dans mon cas.

Au cas où: Dès le départ (avant de soumettre mon problème) j'ai éliminé la possibilité de mettre une chaine de caractères particulière (par exemple "RSS_" & nom de la valeur ) comme nom de dossier. C'est sûr que là, s'aurait été simplissime surtout avec BeforeFolderSwitch
__-
Cette fois donc je ne peux distinguer un dossier courriel (par exemple) d'un dossier RSS.

En plus je peux avoir 2 ou 3 niveaux de sous dossiers. Cela m'enlève la possibilité d'utiliser NewFolder.Parent. J'ai bien espéré en faisant NewFolder.Class mais cela ne donne rien.

J'ai espéré avec NewFolder.DefaultItemType, sans résultat. Je me suis dit finalement qu'il était typé après avoir été ouvert mais pour l'instant (je n'ai pas fini), sans résultat probant.

Voilà!

[Oliv-]

Salut,
Est ce que dans ces dossiers il n'y a que des flux ? si oui tu peux tester le premier ou le dernier item de ce dossier et vérifier son type (45)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Private Sub myOlExp_BeforeFolderSwitch(ByVal NewFolder As Object, Cancel As Boolean)
 
    If NewFolder.Items(1).Class = 45 Then
        MsgBox "Vous êtes dans un dossier RSS : " & vbCr & NewFolder.Name
'ici tu lances ton traitement
        'call doublons
    End If
 
End Sub

[Nulll]

Chapeau bas Oliv- !

C'est simple et ça fonctionne, merci

Merci pour la patience

[Oliv-]

Sion pour occupé ton Week end

Avec REDEMPTION tu peux avoir la liste des RSS et leur emplacement
http://www.dimastr.com/redemption/Redemption.zip

à comparer avec le FullFolderPath du dossier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub rss()
Set RDOSession = CreateObject("Redemption.RDOSession")
RDOSession.MAPIOBJECT = Application.Session.MAPIOBJECT
For Each RssFeed In RDOSession.RssFeeds
    Debug.Print RssFeed.Localfolder.FolderPath & vbTab & "|" & RssFeed.localName & " - " & RssFeed.RemotePath
Next
End Sub