Discussion :

[Sergio33600]

Bonjour le forum,

J'ai un classeur Excel composé de plusieurs onglets portant les noms suivants : Notice, Sortie, Partenaires, Arcachon, Gujan, Lacanau, Médoc, Pessac, ...

Le nom des onglets Arcachon, Gujan, Lacanau, Médoc, Pessac, ... correspond au contenu de la cellule (i, 2) de l'onglet Sortie. Le contenu de ces onglets est différent, je ne peux donc pas avoir un seul onglet que je renommerai en fonction du contenu de la cellule (i, 2) de l'onglet Sortie.

Je souhaiterai créer une macro pour masquer les onglets dont le nom ne correspond pas au contenu de la cellule (i, 2) de l'onglet Sortie, sauf les onglets Notice, Sortie, Partenaires.

Par exemple, si le contenu de la cellule (i, 2) de l'onglet Sortie est Gujan, les onglets visibles dans mon classeur seraient : Notice, Sortie, Partenaires, Gujan. Les autres onglets (Arcachon, Lacanau, Médoc, Pessac, ...) seraient masqués.

Si quelqu'un peut m'aider.

Merci d'avance.

[rossemma]

Bonjour,

Tu peux essayer avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
If Sheets("Sortie").Range("I2") = "Gujan" Then
    Sheets("Notice").Visible = True
   '... ==> ajouter toutes les feuilles visibles ici
   Else
 
    End If

A adapter..

[Sergio33600]

Bonjour rossemma,

Merci pour ta réponse, mais je me demandais, n'étant pas très calé en VBA, si on ne pouvait pas avoir un code plus générique en affectant une variable, à la cellule (i, 2) de l'onglet Sortie et si le nom de cette variable est différent du nom des onglets, je masque ces onglets (sauf les onglets Notice, Sortie, Partenaires).

Est-ce possible ou faut-il que je récrive la ligne 1 de ton code pour tous les onglets que je veux masquer.

Merci encore pour ton aide.

[Philippe Tulliez]

Bonjour,
J'ai relu trois fois ton explication mais je ne suis pas certain d'avoir bien compris.
Un classeur contient une feuille nommée [Sortie] qui dans les cellules de la colonne 2, de la 1ère ou 2ème ligne (ce n'est pas précisé) jusqu'à la Xème contient des valeurs qui correspondent aux noms d'autre feuilles du même classeur.
Le but est de rendre visible ces feuilles ainsi que les les feuilles nommées Notice, Sortie et Partenaires
Si c'est cela que tu souhaites, voici un exemple (Les données contenant le nom des feuilles commencent en B2). Il y a plus court code mais pas le temps de peaufiner.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub t()
 Dim Cel As Range, sht As Worksheet, rng As Range
 With ThisWorkbook.Worksheets("Sortie")
  Set rng = .Range("B2:B" & .Range("B2").End(xlDown).Row)
 End With
 ' Masque toutes les feuilles et affiche les feuilles principales
 For Each sht In ThisWorkbook.Sheets
  Select Case sht.Name ' Liste des feuilles à afficher d'office
   Case "Sortie", "Notice"
    sht.Visible = True
   Case Else
    sht.Visible = False
  End Select
 Next sht
 ' Affiche les feuilles de la colonne B
 For Each Cel In rng
  ThisWorkbook.Sheets(Cel.Value).Visible = True
 Next
End Sub

[Sergio33600]

Bonjour Philippe Tulliez,

Merci pour ta réponse.
Par rapport à tes interrogations :
Le classeur contient une feuille Sortie. Dans la cellule (I,2) de cette feuille, on saisi le nom de la feuille qu'on veut garder (Lacanau, par exemple) et dans ce cas les feuilles visibles seront Notice, Sortie, Partenaires et Lacanau. Les autres feuilles (Arcachon, Gujan, Médoc, Pessac, ) seraient masquées.

Dans le code que tu m'a donné j'ai un message d'erreur (erreur d'exécution '9' : L'indice n'appartient pas à la sélection), pour la ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
ThisWorkbook.Sheets(Cel.Value).Visible = True

Merci encore pour ton aide

[Philippe Tulliez]

Bonjour,

Dans le code que tu m'a donné j'ai un message d'erreur (erreur d'exécution '9' : L'indice n'appartient pas à la sélection), pour la ligne

C'est logique puisque je n'avais pas compris ton problème et le code que j'ai publié parcourt plusieurs cellules et ce qui m'a induit en erreur c'est cellule (i, 2) où j'ai pris le i comme la variable d'une boucle.
Code à placer dans le module de la feuille nommée [Sortie].
Le code sera enclenché dès que l'on écrit une nouvelle valeur en cellule I2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub Worksheet_Change(ByVal Target As Range)
 Dim sht As Worksheet
 If Target.Address = "$I$2" Then
  ' Masque toutes les feuilles et affiche les feuilles proincipales
  For Each sht In ThisWorkbook.Sheets
   Select Case Trim(LCase(sht.Name))
    ' Liste des feuilles à afficher toujours (écrire en minuscule)
    Case Trim(LCase(Me.Range("I2").Value)), "sortie", "notice"
     sht.Visible = True
    Case Else
     sht.Visible = False
   End Select
  Next sht
 End If
 Set sht = Nothing
End Sub

[Sergio33600]

Re-bonjour Philippe Tulliez,

Merci beaucoup pour ta réponse, c'est très bien.

Petite question : comme je ne suis pas très calé en VBA, j'ai essayé de modifier ton code pour le faire fonctionner dans un module, mais je n'y suis pas arrivé. Aurais-tu la gentillesse de m'aider.
Si tu ne peux pas ce n'est pas très grave, car ton code fonctionne parfaitement ainsi.
Merci

[Philippe Tulliez]

Bonjour,

Petite question : comme je ne suis pas très calé en VBA, j'ai essayé de modifier ton code pour le faire fonctionner dans un module

Dans un module standard, on ne pourra pas déclencher la procédure automatiquement lors de la modification de la cellule I2 de la feuille nommée Sortie mais cependant, il suffit de donner un nom quelconque à une procédure et ensuite copier/coller (ou couper/coller) les lignes 2 à 15

Code de la procédure dans le module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub SheetsHideUnhide(mySheet As Worksheet)
 Dim sht As Worksheet
  ' Masque toutes les feuilles et affiche les feuilles principales
 For Each sht In ThisWorkbook.Sheets
  Select Case Trim(LCase(sht.Name))
   ' Liste des feuilles à afficher toujours
   Case "sortie", "notice", Trim(LCase(mySheet.Range("I2").Value))
    sht.Visible = True
   Case Else
    sht.Visible = False
  End Select
 Next sht
End Sub

Transformation éventuelle dans la procédure événementielle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Worksheet_Change(ByVal Target As Range)
 SheetsHideUnhide Me
End Sub

[Sergio33600]

Bonjour Philippe Tulliez,

Merci beaucoup pour ta réponse.
En fait je voulais déclencher la macro, par un bouton, mais la première solution que tu m'a donnée me semble bien meilleure.
Merci encore pour ton aide.

Très bonne journée.