Discussion :

[Claude40]

Bonjour à tous,
J'utilise VBA Access 2007.
Je ne parviens pas à créer des PDF de taille « raisonnable ».
Tous les PDF que je crée, via la commande « DoCmd.OutputTo acOutputReport…» font entre 600Ko et 1,5 Mo pour une seule page !
Comment faire pour créer des PDF de quelques dizaines de Ko comme ceux que nous recevons de la sécurité sociale ou de la banque ?
La valeur donnée au paramètre « acExportQuality » (Print ou Screen) ne modifie rien quant au poids du document.
Merci d'avance pour vos avis éclairés.

[chrtophe]

Qu'imprimes tu dans le PDF ?

[Claude40]

Qu'imprimes tu dans le PDF ?

Il s’agit de devis ou de factures de modèle classique avec un logo (image png intégrée de 2.5 par 1.7 cm), en haut à gauche un en-tête descriptif des coordonnées d’un artisan, en haut à droite, un en-tête descriptif du document (Type de document, N°, Date, code client). En dessous un pavé avec l’adresse du client. Au centre, le détail du devis ou de la facture avec en-têtes de colonnes et tout en bas, un texte relatif à l’assurance souscrite par l’artisan.
J’ai essayé de supprimer le logo : Pas de changement au niveau du poids du PDF.

[chrtophe]

Je crois que tout ce qui est image est stocké en bmp dans Access (pas sûr à 100%).

600Ko encore ça va, mais 1,5 Mo ça fait effectivement un peu lourd.

Si tu essayes de faire une impression vers un moteur PDF (exemple PDF Creator), tu as le même résultat ?

[loufab]

Bonjour,

Tout dépend de la source de l'image et du réglage des options dans Options / BAse active.



Si tu enlèves le logo et que le problème est identique c'est que le pdf est peut-être créé comme une image.

Cordialement,

[kiki29]

Salut, je précise que je n'ai pas Access, est-ce que cela t'aidera ( il faut Acrobat pas le Reader ). Voir Smallest File Size.joboptions

[Claude40]

Bonjour,
Je réponds à plusieurs intervenant que je remercie.
Le paramétrage d'Access base active est sur "Conserver le format d'image source (taille réduite)"
Depuis Office 2007, on pouvait se passer de PDFCreator, la fonction « enregistrer sous PDF » étant incluse.
J’ai à nouveau essayé PDFCreator, en mode manuel tout d’abord et j’ai obtenu via « Imprimer » avec PDFCreator un PDF de 96 Ko pour un état issu d’Access qui pesait précédemment 1.28 Mo. Réel progrès donc.
Mais lorsque j’ai essayé de passer par du code VBA (pour personnaliser le nom du document en sortie et un répertoire), j’ai à nouveau un PDF qui pèse 1.28 Mo !
Le résultat est le même si je pratique par « Enregistrer sous » au format PDF, en mode manuel donc.
Ce « grossissement » exagéré du poids se constate aussi avec Word : un fichier docx de 24 Ko, passe à 800 Ko, lorsque il est enregistré sous PDF, alors qu’il passe seulement à 48 Ko via « Imprimer » avec PDFCreator.
Je m’oriente plutôt vers une solution qui consistera à « épurer » les PDF passés un certain délai, sachant que mon application demande moins d’une minute pour recréer un PDF et l'imprimer si besoin est et le besoin est peu fréquent de revenir sur une impression.
Merci à tous.
Problème clos si non résolu.

[tee_grandbois]

Bonsoir Claude40,
si tu utilises PdfCreator, il a une possibilité d'obtenir des PDF beaucoup moins gros. En cherchant un peu partout à partir du lien de kiki29 (merci de son aide) j'ai trouvé un code qui permettait d'imprimer depuis Excel et que j'ai adapté pour Access : en substituant temporairement l'imprimante par défaut par PdfCreator (si ce dernier ne l'est pas déjà) et ensuite en faisant un PrintOut de l'état avec l'option Brouillon (peut-être pas obligatoire, il faut faire le test avec les autre options).

Il faut au préalable ajouter dans les références PdfCreator :

Pièce jointe 244208

et créer ce code dans un nouveau module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
Option Compare Database
 
Option Explicit
Private Declare Sub Sleep Lib "kernel32.dll" (ByVal dwMilliseconds As Long)
   Public Sub ImprimePDF(ReportName As String, PDFName As String, PDFLocation As String)
      Dim PDFCreator1 As PDFCreator.clsPDFCreator               ' Objet PDF
      Dim DefaultPrinter As String                              ' Imprimante par Défaut (mémorisation)
      Dim c As Long                                             ' Compteur Temporisation
      Dim OutputFilename As String                              ' Nom du Fichier Généré
 
      Set PDFCreator1 = New clsPDFCreator
      With PDFCreator1
         .cStart "/NoProcessingAtStartup"
         .cOption("UseAutosave") = 1
         .cOption("UseAutosaveDirectory") = 1
         .cOption("AutosaveDirectory") = PDFLocation            ' Répertoire de stockage du Fichier PDF généré
         .cOption("AutosaveFilename") = PDFName                 ' Nom du Fichier PDF à produire (Remplace
                                                                ' par des _ les caractères interdits
         .cOption("AutosaveFormat") = 0                         ' 0 = PDF
         DefaultPrinter = .cDefaultPrinter                      ' Mémorise l'Imprimante pas défaut
         .cDefaultPrinter = "PDFCreator"                        ' écrasé par PDFCreator
         .cClearCache
      End With
 
        DoCmd.OpenReport ReportName, acViewPreview              ' Ouvre l'état en mode Aperçu
        DoCmd.PrintOut acPrintAll, , , acDraft                  ' Imprime l'état avec l'option brouillon acDraft
        DoCmd.Close acReport, ReportName                        ' (à changer selon les résultats attendus)
 
      Do Until PDFCreator1.cCountOfPrintjobs = 1                ' Attend la Fin du travail pour quitter
         DoEvents
         Sleep 1000
      Loop
      Sleep 1000
      PDFCreator1.cPrinterStop = False
 
 
      c = 0                                                    ' Attend la Fin d'Ecriture
      Do While (PDFCreator1.cOutputFilename = "") And (c < 50) ' au besoin 50x200ms (1 sec)
         c = c + 1
         Sleep 200
      Loop
      OutputFilename = PDFCreator1.cOutputFilename             ' Récupère le nom du Fichier Généré
      With PDFCreator1
         .cDefaultPrinter = DefaultPrinter                     ' Réattribue l'Imprimante initiale
         Sleep 200                                             ' Tempo de prise en compte avant fermeture
         .cClose
      End With
      Sleep 2000                                               ' Tempo 2 sec permettant d'assurer la libération de PDFCreator de la Mémoire
 
      If OutputFilename = "" Then
         MsgBox "Création Fichier pdf." & vbCrLf & vbCrLf & _
            "Une Erreur s'est produite: Délai dépassé!", vbExclamation + vbSystemModal
      End If
 
' Suppression des objets et des tâches créées     
    Set PDFCreator1 = Nothing
    Shell "taskkill /f /im PDFCreator.exe", vbHide
 
End Sub

Ensuite tu l'utilises en passant les 3 paramètres à ImprimePDF : (Nom de l'état, nom du PDF, Chemin destination du PDF)

[Claude40]

Bonsoir,
j'avais déjà essayé un code très semblable à celui-ci, mais sans succès car je dois avoir un problème de bibliothèque.
La référence que j'ai cochée est PDFCREATOR_COM
Son chemin est :C :\Program Files\PdfCreator\PdfCreator_com.tlb
J'ai une erreur de compilation "Type défini par l’utilisateur non défini" sur la ligne "Dim PDFCreator1 As PDFCreator.clsPDFCreator "

[tee_grandbois]

Ta version est-elle bien de pdfforge, 1.7 ou supérieur ?



En référence il devrait y avoir PDFCreator.exe :

[Claude40]

Bonsoir,
J'avais la version 2.4.1, mais impossible de sélectionner la référence en question. J'ai désinstallé et forcé l'installation de la 1.7.3.
Cela fonctionne à présent. Un premier PDF d'essai pèse 48 Ko.
Résolu donc. Mais il faudra que je me méfie et que je surveille les velléités d'incrémentation de version.
Malgré tout, je garde mes routines d'épuration de fichiers PDF anciens.
Merci beaucoup.

[tee_grandbois]

J'avais la version 2.4.1, mais impossible de sélectionner la référence en question.

bizarre qu'une version plus récente ne propose plus cette fonctionnalité bien pratique
Mais apparemment ce n'est pas nouveau au vu de ce post : https://www.developpez.net/forums/d1...e/#post8237847

[Claude40]

Vérification faite de façon plus approfondie, l'impression avec PDFCREATOR et VBA ne donne pas satisfaction sauf au niveau du poids du fichier.
Le logo (une petite image Jpg intégrée) ne s'affiche plu et l'utilisation de "LinecanGrow" de fonctionne plus correctement.

[tee_grandbois]

as-tu essayé avec l'option acMedium ou acHigh au niveau du paramètre acPrintQuality ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DoCmd.PrintOut acPrintAll, , , acMedium

[Claude40]

as-tu essayé avec l'option acMedium ou acHigh au niveau du paramètre acPrintQuality ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DoCmd.PrintOut acPrintAll, , , acMedium

Bonjour,
Effectivement, je n'avais pas examiné à fond le module "ImprimePdf". Avec acMedium ou acHigh, tout fonctionne normalement avec un poids du PDF de 96 ko pour l'exemple que j'ai pris et qui faisait 1.28 Mo avec la méthode "classique".
Merci encore. Cette fois-ci mon problème est entièrement résolu.

[kiki29]

Salut,@tee_grandbois : concernant PDFCreator il te faut la 1.7.3 car ensuite l'interface COM a été complètement remaniée. Les classes d'objet ne sont plus les mêmes ni les propriétés et méthodes.
voir remarque de GrandZebu ainsi que celle-ci

Concernant les propriétés de PDFCreator 1.7.3 voir ici et en téléchargement ici.

[tee_grandbois]

bonsoir kiki29,
Merci pour les liens, je vais étudier çà.