sap gui scripting inserer un fichier text dans sap via la selection mutiple

**Sophie.1** · 18/01/2017, 16h54

Bonjour,

J'ai établi un petit programme en utilisant l'outil SAP GUI SCRIPTING qui me permet d'extraire la table marc (transaction SE16N=> MARC).
Il fonctionne un fichier se génère et s'enregistre sur mon bureau.
Je souhaiterais maintenant extraire uniquement une liste d'articles afin de limiter le nombre de lignes de mon extraction.
Pour ce faire je clique sur l'icone import fichier, une fenêtre s'ouvre qui me demande d'entrer l'adresse du fichier, (je tape manuellement l'adresse)et lance la transaction . Le rapport apparait bien je demande l'enregistrement sur mon fichier sur c:\ et arrête l'enregistrement.
Lorsque je regarde le code il n'a pas pris en compte le nom du fichier quel bout de code dois- je rajouter pour que cela fonctionne?

ci dessous le bout de code
session.findById("wnd[0]").maximize
session.findById("wnd[0]/tbar[0]/okcd").Text = "SE16N"
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]/usr/ctxtGD-TAB").Text = "MARC"
session.findById("wnd[0]/usr/ctxtGD-TAB").caretPosition = 4
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]/usr/txtGD-MAX_LINES").Text = ""
session.findById("wnd[0]/usr/txtGD-MAX_LINES").SetFocus
session.findById("wnd[0]/usr/txtGD-MAX_LINES").caretPosition = 0
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]/usr/tblSAPLSE16NSELFIELDS_TC/ctxtGS_SELFIELDS-LOW[2,2]").Text = ""
session.findById("wnd[0]/usr/tblSAPLSE16NSELFIELDS_TC/ctxtGS_SELFIELDS-LOW[2,2]").SetFocus
session.findById("wnd[0]/usr/tblSAPLSE16NSELFIELDS_TC/ctxtGS_SELFIELDS-LOW[2,2]").caretPosition = 4
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]/usr/tblSAPLSE16NSELFIELDS_TC/btnPUSH[4,1]").SetFocus
session.findById("wnd[0]/usr/tblSAPLSE16NSELFIELDS_TC/btnPUSH[4,1]").press
session.findById("wnd[1]/tbar[0]/btn[21]").press
'LE programme s'arrete la j'ai une fenetre qui me demande le chemin du fichier,
'je selectionne le fichier text et clique sur ouvrir et le programme continue
session.findById("wnd[1]").sendVKey 8
session.findById("wnd[0]").sendVKey 8

**sandraros** · 19/01/2017, 14h09

Je crois que le souci, c'est que la fenêtre qui demande de choisir un fichier n'est pas une fenêtre SAP GUI, mais une fenêtre Windows. Du coup, le SAP GUI Scripting ne peut pas être utilisé dans ce cas là. Je n'ai pas de solution hélas.

**parmi** · 19/01/2017, 15h01

Bonjour,

Une autre façon (je pense) serait d'ouvrir ton fichier qui contient les codes, copier la plage de ces codes et utiliser le bouton Charger du presse-papier.

**Sophie.1** · 19/01/2017, 22h30

Envoyé par parmi

Bonjour,

Une autre façon (je pense) serait d'ouvrir ton fichier qui contient les codes, copier la plage de ces codes et utiliser le bouton Charger du presse-papier.

Merci pour vos réponses,
j'ai tenté cette solution (copier et coller dans le press papier) mais rien ne se passe non plus.

Sophie

**parmi** · 20/01/2017, 14h51

Essaie comme ceci.
Le code qui suit est à mettre dans Excel
Ma transaction, ici, se nomme ZSE16N, mais j'ai inscrit SE16N

Ça prend un fichier avec des codes en colonnes A qui se nomme C:\Codes.xlsx
Le résultat sera sauvegardé dans C:\Resultat.xls

Change les chemins et noms au besoin.

J'ai mis une référence à la librairie Sap Gui Scripting API qui se trouve dans c:\program files (x86)\sap\frontend\sapgui\sapfewse.ocx

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
Sub ZSE16N()
    Dim SapGuiAuto As Object
    Dim AppliSAP As SAPFEWSELib.GuiApplication
    Dim Connection As SAPFEWSELib.GuiConnection
    Dim Session As SAPFEWSELib.GuiSession
    Dim Chemin As String, Fichier As String
    Dim nbLignes As Long
    
    Set SapGuiAuto = GetObject("SAPGUI")
    If Not IsObject(SapGuiAuto) Then
        Exit Sub
    End If
    
    Set AppliSAP = SapGuiAuto.GetScriptingEngine()
    If Not IsObject(AppliSAP) Then
        Exit Sub
    End If
    
    Set Connection = AppliSAP.Connections(0)
    If Not IsObject(Connection) Then
        Exit Sub
    End If
    
    Set Session = Connection.Sessions(0)
    If Not IsObject(Session) Then
        Exit Sub
    End If
    
    Chemin = "C:\"
    Fichier = "Resultat.xls"
    
    Session.FindById("wnd[0]").Maximize
    Session.FindById("wnd[0]/tbar[0]/okcd").Text = "/nSE16N"       '"/nZSE16N"
    Session.FindById("wnd[0]").SendVKey 0
    Session.FindById("wnd[0]/usr/ctxtGD-TAB").Text = "MARC"
    Session.FindById("wnd[0]").SendVKey 0
    
    'Sélection de codes
    Session.FindById("wnd[0]/usr/tblSAPLSE16NSELFIELDS_TC/btnPUSH[4,1]").SetFocus
    Session.FindById("wnd[0]/usr/tblSAPLSE16NSELFIELDS_TC/btnPUSH[4,1]").Press
    
    'Ouverture du fichier qui contient les codes nécessaires
    Workbooks.Open "C:\Codes.xlsx"
    nbLignes = ActiveSheet.Cells(Rows.Count, "A").End(xlUp).Row
    ActiveSheet.Range("A2:A" & nbLignes).Copy
    
    Session.FindById("wnd[1]/tbar[0]/btn[24]").Press    'Copie les codes dans SAP
    Session.FindById("wnd[1]/tbar[0]/btn[8]").Press     'Ferme la fenêtres des codes
    Session.FindById("wnd[0]/tbar[1]/btn[8]").Press     'Démarre la transaction
    ActiveWorkbook.Close False                          'Ferme le fichier
    
    'Sauvegarde du fichier
    Session.FindById("wnd[0]/usr/cntlRESULT_LIST/shellcont/shell").PressToolbarContextButton "&MB_EXPORT"
    Session.FindById("wnd[0]/usr/cntlRESULT_LIST/shellcont/shell").SelectContextMenuItem "&PC"
    Session.FindById("wnd[1]/usr/subSUBSCREEN_STEPLOOP:SAPLSPO5:0150/sub:SAPLSPO5:0150/radSPOPLI-SELFLAG[1,0]").Select
    Session.FindById("wnd[1]/usr/subSUBSCREEN_STEPLOOP:SAPLSPO5:0150/sub:SAPLSPO5:0150/radSPOPLI-SELFLAG[1,0]").SetFocus
    Session.FindById("wnd[1]/tbar[0]/btn[0]").Press
    
    Session.FindById("wnd[1]/usr/ctxtDY_PATH").Text = Chemin        'Inscrit le chemin
    Session.FindById("wnd[1]/usr/ctxtDY_FILENAME").Text = Fichier   'inscrit le nom du fichier
    If Dir(Chemin & Fichier) <> "" Then Kill Chemin & Fichier       'supprime le fichier s'il existe déjà
    Session.FindById("wnd[1]/tbar[0]/btn[0]").Press                 'sauvegarde
    
    
    mgbox "Fichier sauvegardé"
    
    Exit Sub
Erreur:
    If Err.Number = -2147221020 Or Err.Number = 614 Then
        MsgBox "Démarrer une session SAP", vbExclamation, "Erreur SAP"
        Application.WindowState = xlMaximized
    Else
        MsgBox Err.Number & vbCrLf & Err.Description
    End If

End Sub

**sandraros** · 22/01/2017, 18h05

Au fait, si ton code est dans un fichier .VBS alors l'ouverture de fichier ne marchera pas, il faut le faire en macro VBA dans une application MS Office (Word, Excel...) et lancer la macro depuis ce logiciel. Du coup on peut aussi facilement mettre un texte dans le presse-papier avec DataObject défini dans C:\windows\system32\FM20.dll (dans l'éditeur VBA, l'ajouter via menu outils -> références) : Dim text As String Dim DO As New DataObject text = "test presse-papier" Call DO.SetText(text) Call DO.PutInClipboard

**parmi** · 22/01/2017, 19h06

À partir d'Excel, seule une copie de plage suffit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.Range("A2:A" & nbLignes).Copy

**sandraros** · 22/01/2017, 22h49

ah ben oui c'est vrai, pardon!

**Sophie.1** · 23/01/2017, 15h16

Envoyé par parmi

À partir d'Excel, seule une copie de plage suffit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.Range("A2:A" & nbLignes).Copy

Merci à tous cela fonctionne très bien!

Sophie

sap gui scripting inserer un fichier text dans sap via la selection mutiple

SAP

Discussions similaires

Partager

Partager