[VBA-E]Lancement macro ouverture Feuille

**zoumzoum59** · 07/06/2006, 21h15

Bonjour à tous

Je voudrais savoir qu'est ce qui cloche dans le code suivant, devant normalement lancer la macro a l'ouverture de la feuille nommé "chant".

Car quand je click sur l'onglet rien ne se passe.
Voila le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Sub Worksheet_Activate(ByVal chant As Object)

Ca doit etre simple mais je seche.

Merci d'avance

**SilkyRoad** · 07/06/2006, 21h50

bonsoir

tu peux tester cette synthaxe :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Worksheet_Activate()
laMacro
End Sub

La procedure doit etre collée dans la feuille "Chant"

bonne soiree
michel

**zoumzoum59** · 07/06/2006, 22h14

merci SilkyRoad le truc est que je ne l'avait pas mis dans la feuille mais dans un module.

Par contre du coup j'ai un message d'erreur à l'execution de la macro qui est:

Erreur d'execution 1004
La methode select de la classe range a echoué

l'erreur ce situe sur la ligne en rouge, bizarre la macro fonctionnait avant que j'essaie de la faire demarrer a l'ouverture de la feuille.

La macro sert a additionner independemment trois cellule de chaque feuille de la troisieme à l'avant derniere et a coller ces trois adddition dans trois cellules de la derniere feuille.

Voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Private Sub Worksheet_Activate()
 Dim NbFeuille, i As Integer
Dim PFeuille, Chant_a, Chant_b, Chant_c, Chant1, Chant2, Chant3 As Integer
 Dim firstcell, lastcell, zone As Range
 
 'PQR
 
 NbFeuille = Worksheets.Count
 
  PFeuille = 2
     
    
    Chant_a = 0
    Chant_b = 0
    Chant_c = 0
     
    For i = 3 To (NbFeuille - 1) Step 1
        Sheets(i).Select
        Set firstcell = Range("P5")
Set lastcell = Range("p65536").End(xlUp)
Set zone = Range(firstcell, lastcell)

Range(firstcell, lastcell).Select
ActiveCell.Offset(-1, 0).Select
Chant1 = ActiveCell.Value
Chant_a = Chant_a + Chant1

 Set firstcell = Range("Q5")
Set lastcell = Range("Q65536").End(xlUp)
Set zone = Range(firstcell, lastcell)


Range(firstcell, lastcell).Select
ActiveCell.Offset(-1, 0).Select
Chant2 = ActiveCell.Value
Chant_b = Chant_b + Chant2

Set firstcell = Range("R5")
Set lastcell = Range("R65536").End(xlUp)
Set zone = Range(firstcell, lastcell)


Range(firstcell, lastcell).Select
ActiveCell.Offset(-1, 0).Select
Chant3 = ActiveCell.Value
Chant_c = Chant_c + Chant3
        
        
        Debug.Print Chant_a
    Next i
Worksheets(Worksheets.Count).Select
Range("b8").Value = Chant_a
Range("c8").Value = Chant_b
Range("d8").Value = Chant_c
 
 End Sub

**zazaraignée** · 07/06/2006, 22h28

Salut

Je crois que tu n'as pas initialisé ta variable lastcell.

**SfJ5Rpw8** · 07/06/2006, 22h36

essai de modifier le code de cette ainsi..:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
  For i = 3 To (NbFeuille - 1) Step 1
  With Sheets(i)
                  .Select 
        Set firstcell = .Range("P5")
         Set lastcell = .Range("p65536").End(xlUp)
       Set zone = .Range(firstcell, lastcell)
 
.Range(firstcell, lastcell).Select
...
end with
 next i

en indiquant explicitement la feuille concerné.. sinon les range portent sur la contenant le code...

**SfJ5Rpw8** · 07/06/2006, 22h47

Envoyé par SilkyRoad

bonsoir

en complément de la réponse de Bbil ci joint une adaptation sans Select
...

et oublie le "replatrage" que dont je t'ai montré le chemin.. (avec le with... ) l'utilisation des .select c'est pas terrible dans VBA excel..mais en plus dans un code événementiel .. sur l'activation d'une feuille...

utilise plutôt le code à Michel..

**zoumzoum59** · 07/06/2006, 22h52

bbil j'ai essayé de modifier selon ton code mais j'ai une erreur qui me dit Next sans For est ce du au with ? que tuas rajouter pourtant le next y est encore.

J'ai essayer de rajouter un end with mais j'ai pas de resultat.

**zoumzoum59** · 07/06/2006, 22h57

SilkyRoad J'ai une erreur de compilation avec ton code qui me dit "objet requis " sur le premier firstcell de la boucle For

**zoumzoum59** · 07/06/2006, 23h12

SilkyRoad ce problème est resolu par contre j'ai une incompatibilité de type apparemment entre chant1(integer l'objet Range) sur la ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Chant1 = Sheets(i).Range(firstCell, lastCell).Offset(-1, 0)

**SilkyRoad** · 07/06/2006, 23h18

rebonsoir

peux tu reexpliquer ce que doit faire ta macro car je suis un peu perdu dans ta procedure ...

bonne soiree
michel

**zoumzoum59** · 07/06/2006, 23h31

La macro sert a additionner l'avant derniere cellule de la colonne p de la troisieme feuille à l'avant derniere contenant toute le meme tableau mais pas forcement le meme nombre de ligne.

La meme chose pous la colonne q et r de la feuille 3 à l'avant derniere et de coller ces trois adddition dans trois cellules de la derniere feuille.

J'espere que ce coup ci j'ai ete plus claire SilkyRoad

**SilkyRoad** · 08/06/2006, 00h16

rebonsoir

L'utilisation de Range n'etait pas du tout adaptée dans ta procedure d'origine
Utilise Range si tu connais l'adresse
Uilise Cells si tu connais les numeros de lignes et de colonne

une nouvelle version à tester

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Dim NbFeuille As Integer, i As Integer
Dim PFeuille As Integer
Dim Chant_a As Integer, Chant_b As Integer, Chant_c As Integer, _
Chant1 As Integer, Chant2 As Integer, Chant3 As Integer
Dim ligneCible As Integer, j As Integer
 
NbFeuille = Worksheets.Count
PFeuille = 2
 
Chant_a = 0
Chant_b = 0
Chant_c = 0
 
For i = 3 To (NbFeuille - 1) Step 1
    j = j + 1
    ligneCible = Sheets(i).Range("P65536").End(xlUp).Row - 1
    Chant1 = Sheets(i).Cells(ligneCible, 15 + j).Value
    Chant_a = Chant_a + Chant1
 
    ligneCible = Sheets(i).Range("Q65536").End(xlUp).Row - 1
    Chant2 = Sheets(i).Cells(ligneCible, 15 + j).Value
    Chant_b = Chant_b + Chant2
 
    ligneCible = Sheets(i).Range("R65536").End(xlUp).Row - 1
    Chant3 = Sheets(i).Cells(ligneCible, 15 + j).Value
    Chant_c = Chant_c + Chant3
 
Next i
 
With Worksheets(Worksheets.Count)
    .Range("B8").Value = Chant_a
    .Range("C8").Value = Chant_b
    .Range("D8").Value = Chant_c
End With

bonne soiree
michel

**zoumzoum59** · 08/06/2006, 00h33

Desolé SilkyRoad

J'ai toujours une "erreur d'execution 13 incompatibilité de type" sur la ligne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ligneCible = Sheets(i).Range("Q65536").End(xlUp) - 1

**SilkyRoad** · 08/06/2006, 06h21

bonjour

tu peux retester la procedure dans mon precedent message . j'avais oublié le .Row - 1 en fin de ligne ...

bonne journée
michel

**AlainTech** · 08/06/2006, 11h07

Attention à cette syntaxe:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim NbFeuille, i As Integer
Dim PFeuille, Chant_a, Chant_b, Chant_c, Chant1, Chant2, Chant3 As Integer
Dim firstcell, lastcell, zone As Range

Première ligne, seul i est déclaré Integer
2e, seul Chant3...
3e, seul zone est déclaré Range

Tous les autres sont Variant car pas de typage.

Voir le code de SilkyRoad pour la syntaxe correcte.

**zoumzoum59** · 08/06/2006, 21h31

Merci SilkyRoad pour ton dernier message Car ton code fonctionne au poil.

J'ai fai quelque modif car tu avais pas tout a fait saisi ce que je voulais , j'ai du mal exprimé ma pensé.

Je n'avais pas besoins d'un decalage d'une colonne en passant de feuille en feuille, mais ton code est tres interressant et peu me donner d'autres idées.

Merci également à Alain Tech pour ton info sur mon ecriture de variable.

Le code finale est celui-ci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Private Sub worksheet_activate()
Dim NbFeuille As Integer, i As Integer
Dim Chant_a As Integer, Chant_b As Integer, Chant_c As Integer, _
Chant1 As Integer, Chant2 As Integer, Chant3 As Integer
Dim ligneCible As Integer
 
NbFeuille = Worksheets.Count
 
Chant_a = 0
Chant_b = 0
Chant_c = 0
 
For i = 3 To (NbFeuille - 1) Step 1
 
    ligneCible = Sheets(i).Range("P65536").End(xlUp).Row - 1
    Chant1 = Sheets(i).Cells(ligneCible, 16).Value
    Chant_a = Chant_a + Chant1
 
    ligneCible = Sheets(i).Range("Q65536").End(xlUp).Row - 1
    Chant2 = Sheets(i).Cells(ligneCible, 17).Value
    Chant_b = Chant_b + Chant2
 
    ligneCible = Sheets(i).Range("R65536").End(xlUp).Row - 1
    Chant3 = Sheets(i).Cells(ligneCible, 18).Value
    Chant_c = Chant_c + Chant3
 
Next i
 
With Worksheets(Worksheets.Count)
    .Range("B8").Value = Chant_a
    .Range("C8").Value = Chant_b
    .Range("D8").Value = Chant_c
End With
End Sub

[VBA-E]Lancement macro ouverture Feuille

Macros et VBA Excel

Discussions similaires

Partager

Partager