Discussion :

[Bib0ucH]

Bonjour à tous,

Le titre n'est pas complètement révélateur de ma recherche, néanmoins, il début bien mon propos.
Je cherche donc à compter le nombre de cellule non-vide avec la condition de les compter "une colonne sur deux".

J'arrive bien à compter le contenu des cellules en utilisant la formule suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((MOD(COLONNE($C2:$H2);2)=0)*1;$C2:$H2)

mais je n'arrive pas à remonter le nombre de cellule.
j'ai tenté ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB((MOD(COLONNE($C2:$H2);2)=0)*1;$C2:$H2)

mais sans résultat.

Merci d'avance

[Raccourcix]

Bonjour

pour compter le nombre de cellule il faut conserver le SOMMEPROD mais modifier l'argument $C2:$H2 pour qu'il renvoie 0 si vide et 1 sinon
donc par exemple $C2:$H2<>"" qui renverra des VRAI et des FAUX à convertir en 1 et 0 par opération -- ou +0 ou *1 ou avec la fonction N

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
=SOMMEPROD((MOD(COLONNE($C2:$H2);2)=0)*1;N($C2:$H2<>""))
=SOMMEPROD((MOD(COLONNE($C2:$H2);2)=0)*1;($C2:$H2<>"")+0)
=SOMMEPROD((MOD(COLONNE($C2:$H2);2)=0)*1;($C2:$H2<>"")*1)
=SOMMEPROD((MOD(COLONNE($C2:$H2);2)=0)*1;--($C2:$H2<>""))

ou même directement en multipliant les deux arguments

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((MOD(COLONNE($C2:$H2);2)=0)*($C2:$H2<>""))

Mais, pour s'affranchir des colonnes paires et impaires, il serait mieux à mon sens d'utiliser la fonction NB.SI.ENS qui est dispo pour 2016 il me semble et qui accepte les jokers "*"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS($C$1:$H$1;"temps >5'*";C2:H2;"<>")

Stéphane

[Bib0ucH]

C'est parfait, le NB.SI.ENS fonctionne parfaitement, comme le SOMMEPROD.
Je vais utiliser le SOMMEPROD car dans mon tableau, je ne peux pas exploiter le nom de la colonne.

Merci pour le coup de main !

[Bib0ucH]

Je pousse le vice un peu plus loin.
Admettons que mes entêtes de colonnes soient désormais des dates. Comment puis-je compléter le code ci-dessous pour "filtrer" les résultats sur "AVRIL" (en utilisant =MOIS je suppose), "MAI" etc... ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((MOD(COLONNE($C2:$H2);2)=0)*($C2:$H2<>""))

[Raccourcix]

si vous supposez, essayez d'abord, puis revenez sur le forum si vous bloquez

le SOMMEPROD attend une liste de valeur (ou de VRAO/FAUX dans votre cas)
donc en considérant que les dates sont en ligne 1, ajoutez dans le SOMMEPROD(... *(MOIS($C$1:$H$1)=4) )
et un critère supplémentaire avec l'année éventuellement pour ne pas avoir du 2020 avec du 2021

Sinon, Power Query me semble bien adapté pour transformer vos données (en les pivotant) afin d'obtenir une base de données "propre" et faire ensuite toutes les analyses avec des TCD, plutôt que de concevoir des formules complexes pour répondre à toutes les questions qu'on vous pose

Stéphane

[Bib0ucH]

Merci c'est parfait.

Je me suis renseigné sur PowerQuery, mais ma feuille étant actualisée quotidiennement, je ne peux pas utiliser de base CSV.

Merci encore

[78chris]

BOnjour

Je me suis renseigné sur PowerQuery, mais ma feuille étant actualisée quotidiennement, je ne peux pas utiliser de base CSV.

Mal renseigné de toute évidence : PowerQuery, heureusement, traite nombre de sources différentes, le csv n'étant qu'un cas parmi tant d'autres...

[Bib0ucH]

Entièrement d'accord, depuis mon précédent post j'ai approfondi le sujet pour essayer d'utiliser cet outils. Merci