Discussion :

[Invité]

Bonjour à tous,

Je dois migrer les tables locales Access sur sql server, seulement voilà, j'ai des soucis sur une table en particulier, la table IMMATRICULATION, elle a un champ IMMAT déclaré comme étant une clé primaire.

Quand je veux exécuter le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Dim mydb As Database
Dim myrs As Recordset
Dim req As String
Set mydb = CurrentDb()
 
DoCmd.Hourglass True
 
req = "SELECT * FROM IMMATRICULATION WHERE IMMAT ='" & Me.Liste_CANum & "'"
Set myrs = mydb.OpenRecordset(req, dbOpenDynaset, dbDenyWrite)
 
If myrs.RecordCount > 0 Then
    IMMAT = myrs![IMMAT]
    MARQUE = myrs![MARQUE]
    MODELE = myrs![MODELE]
    PRIX = myrs![PRIX]
    DATE = myrs![DATE]
    AMO_DUREE = myrs![AMO_DUREE]
    AMO_MONTANT = myrs![AMO_MONTANT]
    AMO_DEBUT = myrs![AMO_DEBUT]
    AMO_FIN = myrs![AMO_FIN]
    ASS_MONTANT = myrs![ASS_MONTANT]
    SOM = myrs![SOMMEIL]
Else
    myrs.AddNew
    myrs![IMMAT] = Me.Liste_CANum
    myrs.Update
    IMMAT = Me.Liste_CANum
    MARQUE = ""
    MODELE = ""
    PRIX = ""
    DATE = ""
    AMO_DUREE = ""
    AMO_MONTANT = ""
    AMO_DEBUT = ""
    AMO_FIN = ""
    ASS_MONTANT = ""
    SOM = "Non"
End If
myrs.Close
mydb.Close
DoCmd.Hourglass False

La ligne de code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set myrs = mydb.OpenRecordset(req, dbOpenDynaset, dbDenyWrite)

est en erreur, j'obtiens comme message d'erreur

ODBC - ne peut pas verrouiller tous les enregistrements

Auriez-vous des idées de comment résoudre le problème?

Merci

[argyronet]

Bonjour,

Sans doute que tu utilises dbDenyWrite conjointement avec un dbOpenDynaset dont le but est effectivement d'empêcher d'autres utilisateurs de modifier les enregistrements dans ce laps de temps.
Utilise un dbOpentable plutôt...

Par ailleurs, j'avoue ne pas comprendre comment sont initialisés les champs qui précèdent les signes = (IMMAT, MARQUE, MODELE, PRIX, DATE, AMO_DUREE, AMO_MONTANT, AMO_DEBUT, AMO_FIN, ASS_MONTANT, SOM)...

Argy

[Invité]

Bonjour,

Le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set myrs = mydb.OpenRecordset(req, dbOpentable)

Ne fonctionne pas, j'ai un message d'erreur qui est :

Le moteur de base de données Microsoft Office Access n'a pas pu trouver l'objet "SSELECT * FROM IMMATRICULATION WHERE IMMAT = '018RV40'". Assurez-vous que l'objet existe et que vous avez correctement saisi son nom et son chemin d'accès.

Même message d'erreur avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set myrs = mydb.OpenRecordset(req, dbOpentable, dbDenyWrite)

Question : en ouvrant le formulaire où je rencontre cet erreur, j'ai un champ combo qui est rempli en exécutant une requête depuis la feuille des propriétés, dans l'onglet "Données", puis dans "Contenu" : serait-il d’exécuter cette requête dans du code VBA Access, lors du chargement du formulaire? Ainsi, je pourrais fermer (proprement?) la connexion à l'odbc une fois le champ entièrement remplie.

[argyronet]

Attention, un dbOpenTable ne doit pas pointer vers une requête (SELECT * FROM...) mais une table.

Si tu nous disais explicitement le cheminement de ce que tu veux faire, je pourrais t'aider mais là, c'est encore floue...
[EDIT]
au niveau du code j'entends...
[/EDIT]

Argy

[Invité]

Auparavant, ma table IMMATRICULATION se trouvait sur un fichier access externe, là, j'ai migré cette table sur sql server, depuis, je rencontre l'erreur dont je fais mention.

Comme je n'arrive pas à me familiariser avec cette façon de programmer, j'ai tout refais, j'ai mis à la place le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Dim l_conn As ADODB.Connection
Dim l_cmd As ADODB.Command
Dim l_rst As ADODB.Recordset
Dim l_query As String
Set l_conn = New ADODB.Connection
l_conn.ConnectionString = MyConnectionString()
l_conn.Open
 
l_query = "SELECT IMMAT, MARQUE, MODELE, PRIX, DATE, AMO_DUREE, AMO_MONTANT, AMO_DEBUT, AMO_FIN, ASS_MONTANT, SOMMEIL "
l_query = l_query & "FROM IMMATRICULATION WHERE IMMAT ='" & Me.Liste_CANum & "'"
Set l_cmd = New ADODB.Command
With l_cmd
    .ActiveConnection = l_conn
    .CommandText = l_query
End With
 
Set l_rst = l_cmd.Execute
If l_rst.EOF = False Then
    'j'ai un enregistrement
    IMMAT = l_rst.Fields(0).Value
    MARQUE = l_rst.Fields(1).Value
    MODELE = l_rst.Fields(2).Value
    PRIX = l_rst.Fields(3).Value
    DATE = l_rst.Fields(4).Value
    AMO_DUREE = l_rst.Fields(5).Value
    AMO_MONTANT = l_rst.Fields(6).Value
    AMO_DEBUT = l_rst.Fields(7).Value
    AMO_FIN = l_rst.Fields(8).Value
    ASS_MONTANT = l_rst.Fields(9).Value
    SOM = l_rst.Fields(10).Value
    l_query = ""
Else
    l_query = "INSERT INTO IMMATRICULATION (IMMAT, SOMMEIL) VALUES ('" & Me.Liste_CANum & "', 0)"
    IMMAT = Me.Liste_CANum
    MARQUE = ""
    MODELE = ""
    PRIX = ""
    DATE = ""
    AMO_DUREE = ""
    AMO_MONTANT = ""
    AMO_DEBUT = ""
    AMO_FIN = ""
    ASS_MONTANT = ""
    SOM = "Non"
End If
l_rst.Close
 
If l_query <> "" Then
    l_cmd.CommandText = l_query
    Set l_rst = l_cmd.Execute
End If
 
Set l_rst = Nothing
l_conn.Close

et là, tout fonctionne désormais!!!

[argyronet]

Chat alors!

Je te conseille toutefois de greffer une gestion d'erreurs et en //, de tester la propriété State de ton objet l_conn avant de le fermer pour éviter une erreur.

Argy