Discussion :

[Feupy]

Bonjour,

j'ai un tableau comme celui là :

A1 B1 C1 D1 E1 F1
A2 B2 C2 D2 E2 F2
A3 B3 C3 D3 E3 F3

je souhaiterai créer un automatisme pour un présentation comme ci-dessous (la colonne D a été volontairement sautée) :

A2 B1 B2
A2 C1 C2
A2 E1 E2
A2 F1 F2
A3 B1 B3
A3 C1 C3
A3 E1 E3
A3 F1 F3

Pouvez vous m'aider ? Merci !!

[papouclo]

Bonjour,
Il est difficile de dégager sur un seul exemple un automatisme susceptible d'être généralisé à d'autres dimensions du tableau source.
Avec ce deuxième exemple de source,
A1 B1 C1 D1 E1 F1 G1 H1
A2 B2 C2 D2 E2 F2 G2 H2
A3 B3 C3 D3 E3 F3 G3 H3
A4 B4 C4 D4 E4 F4 G4 H4
la transformation attendue est-elle celle exposée ci-dessous ?
A2 B1 B2
A2 C1 C2
A2 D1 D2
A2 F1 F2
A2 G1 G2
A2 H1 H2
A3 B1 B3
A3 C1 C3
A3 D1 D3
A3 F1 F3
A3 G1 G3
A3 H1 H3
A4 B1 B4
A4 C1 C4
A4 D1 D4
A4 F1 F4
A4 G1 G4
A4 H1 H4
Cordialement
Claude

[Feupy]

Bonjour Claude,

Merci pour votre réponse.

Oui, c'est exactement le résultat attendu.

[papouclo]

Re,
Dans cette proposition, je suppose a priori que le tableau de départ nommé source commence en A1 (Feuil1) et que le tableau résultat à obtenir commencera (sur la même feuille ou sur une autre) en ligne 1 aussi.
La détermination des lignes et colonnes des cellules à lire dans le tableau source fait appel aux fonctions QUOTIENT (ou à la fonction ENT) et MOD pour tenir compte d'une certaine "périodicité" dans la lecture des cellules.
Pour ne pas avoir des formules trop longues, j'ai défini plusieurs noms :
source ici pour la plage A1:F4
période défini par:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=COLONNES(source)-2

test défini par:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=LIGNE()<=période*(LIGNES(source)-1)

calcligne défini par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ENT((LIGNE()-1)/période)+2

calccol défin par:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=(MOD(LIGNE()-1;période)+2)+((MOD(LIGNE()-1;période)+2)>=période)

Dans la première colonne (ligne 1) du tableau résultat, écrire la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(test;INDIRECT(ADRESSE(calcligne;1;1;;"Feuil1"));"")

et recopier dans la colonne vers le bas.
Dans la colonne suivante (ligne 1), écrire la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(test;INDIRECT(ADRESSE(1;calccol;1;;"Feuil1"));"")

et recopier dans la colonne vers le bas.
Dans la dernière colonne (ligne 1), écrire la formule:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(test;INDIRECT(ADRESSE(calcligne;calccol;1;;"Feuil1"));"")

et recopier dans la colonne vers le bas.
Cordialement
Claude

[Feupy]

Bonjour Claude,

C'est super !!! cela fonctionne. Merci, merci, merci mille fois !!!!

Petite précision, si je ne veux pas sauter la colonne 'E', quel code je dois changer ?

[papouclo]

Bonjour,
Il suffit de modifier les formules définissant les noms période et calccol.
période doit être défini par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=COLONNES(source)-1

calccol doit être défini par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOD(LIGNE()-1;période)+2

Les formules dans les trois colonnes restent les mêmes.
Cordialement
Claude