Discussion :

[masomo]

Bonjour,

Je dois trouver le code qui traite dans une liste ayant des sous listes, le nombre de celles commençant par un chiffre. en cherchant j ai pu trouver que numberp peut m'aider. Mais j arrive pas à trouver le code.

pourriez vous m aider à voir ou je me plante, merci d'avance.


mon code est:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
(defun nombres (liste) 
  (cond 
   ((not liste) 0) 
   ((listp (car liste)) (and (numberp (car (car liste)))) 
     (1+ (nombres (cdr liste))))  
     (t (nombres (cdr liste))) ) )

Resultat

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
(nombres '((5 a 1 2) (a b) b (2 a b d)))
3

alors que j attendais avoir 2.

merci de l aide

[byjav]

Salut !

J'espère que tu te sers d'un editeur capable de l'indentation (Emacs...). Voici ton code proprement indenté:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
(defun nombres (liste)
  (cond ((not liste) 0)
        ((listp (car liste))
         (and (numberp (car (car liste))))
         (1+ (nombres (cdr liste))))
        (t (nombres (cdr liste)))))

La deuxième clause de cond est incorrecte.

Une clause de cond a la forme (<condition> <forme_1> ... <forme_n>). Ayant rencontré une clause dont la <condition> est vraie, cond évalue les formes <forme_1>, ..., <forme_n> dans cette clause en renvoie la valeur de la dernière.

Ici dans la deuxième clause on a trois S-expressions: la condition (listp (car liste)) suivie des formes (and (numberp (car (car liste)))) et (1+ (nombres (cdr liste)))) Alors, la condition est vraie si et seulement si l'element la tête de la liste originale est une liste. C'est plus ou moins évident que la fonction renvoie le nombre total des soulistes.

Toi, tu avais besoin d'une condition composée: (and (listp (car liste)) (numberp (car (car liste))))

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
(defun nombres (liste)
  (cond ((not liste) 0)
        ((and (listp (car liste)) (numberp (car (car liste))))
         (1+ (nombres (cdr liste))))
             (t (nombres (cdr liste)))))

est correcte.

Du point de vue du style, on peut remarquer le suivant. Les fonctions null et not sont synonymes, mais la première s'applique pour déterminer si un objet est nil ou pas et la seconde est utilisée dans des contextes logiques. Comme liste n'est pas une variable « logique », il vaut mieux remplacer not pour null.

A la place de (car (car liste)) on peut écrire (caar liste).

Mais ce qui est le pire, c'est l'algorithme récursif. La pile d'appel est proportionnelle à la longeur de la liste sans aucune justification. Une solution efficace « à la fonctionnelle » utiliserait des fonctions d'ordre supérieur : par exemple, la fonction count-if qui renvoie le nombre des elements d'une liste (ou un vecteur) qui satisfont une condition:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
(defun nombres-2 (list)
  (count-if (lambda (x)
              (and (listp x)
                   (numberp (first x))))
            list))

Une boucle serait encore plus efficace. Voici un exemple un peu avancé de loop :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
(defun nombres-3 (list)
  (loop for x in list
       counting (and (listp x)
                     (numberp (first x)))))

[masomo]

Je vous remercie,
c'est la meilleure des réponses et tout ce qui est expliqué dedans.