Discussion :

[Rinat]

Bonjour,
J'ai découvert grâce au tutoriel "Tableaux" les tableaux de type définis par l'utilisateur.
Je souhaite les utiliser pour regrouper des tableaux de une ou deux dimensions se référant à une même collection. Ici: clients. J'ai pris ici l'exemple de la durée des différents rendez vous avec un client appelé client n°3.
J'ai placé en fin de code une procédure avec deux fonctions que j' utilise dans la gestion d'un tableau par exemple de deux dimensions: moyenne des durées et recopie des durées grâce à la fonction index.
Je souhaite effectuer les mêmes opérations avec un tableau de type.
Mon code ne fonctionne pas. J'ai indiqué les messages erreur. Merci d'avance.
PS:désolé, je n'ai pas réussi à insérer une fenêtre pour le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Option Explicit
 
'Définition du type
Type InfoClients
    Durée_RDV(1 To 5) As Variant
End Type
 
Public Sub Moyenne_Tableau_Type_Données()  ' (Client,Durée RDV). 
Dim Tableau(1 To 10) As InfoClients
Dim i As Integer, Moyenne As Currency
 
' durée des 4 RDV du client n°3
For i = 1 To 4
    Tableau(3).Durée_RDV(i) = 4 * i
Next i
'moyenne de la durée des RDV du client n°3
Moyenne = Application.Average(Application.Index(Tableau.Durée_RDV, 3)) 'Renvoie: "Erreur de compilation. Tableau: qualificateur incorrect"
'Copie dans la feuille active  du tableau.
Range("A1").Resize(UBound(Tableau.Durée_RDV, 1), UBound(Tableau.Durée_RDV, 2)).Value = Application.Index(Tableau.Durée_RDV, 3) 'UBound(tableau,dimension souhaitée)'Renvoie: "Erreur de compilation. Tableau: qualificateur incorrect"
End Sub
 
Public Sub Moyenne_Tableau_deux_dimensions() 'Cette procédure fonctionne.
Dim Tableau(1 To 10, 1 To 5) As Variant ' (Client,Durée RDV)
Dim i As Integer, Moyenne As Currency
 
' durée des 4 RDV du client n°3
For i = 1 To 4
    Tableau(3, i) = 4 * i
Next i
'moyenne de la durée des RDV du client n°3
Moyenne = Application.Average(Application.Index(Tableau, 3))
 
'Copie du tableau dans la feuille active  .
Range("A1").Resize(UBound(Tableau, 1), UBound(Tableau, 2)).Value = Application.Index(Tableau, 3) 'UBound(tableau,dimension souhaitée)
 
End Sub

[Theze]

Bonjour,

Pour la moyenne du client n° 3 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Moyenne = Application.Average(Tableau(3).Durée_RDV)

Ceci renverra 5 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
UBound(Tableau(3).Durée_RDV())

car les tableaux du type sont dimensionnés en dur de 1 à 5 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Durée_RDV(1 To 5) As Variant

et ceci renverra 10 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
UBound(Tableau())

car le tableau est dimensionné en dur de 1 à 10 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Dim Tableau(1 To 10) As InfoClients

[Theze]

Bonjour,

Si tu veux quelque chose de plus dynamique, voici un petit exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
Type InfoClients
 
    Durée_RDV() As Double
    NomClient As String
    Adresse As String
    CP As String
    Ville As String
 
End Type
 
Public Sub Moyenne_Tbl_Type_Données()
 
    Dim Tbl() As InfoClients
    Dim I As Integer
    Dim J As Integer
    Dim Moyenne As Double
 
    For I = 1 To 3
 
        ReDim Preserve Tbl(1 To I)
 
        Tbl(I).NomClient = "Client n° " & I
        Tbl(I).Adresse = I & ", Rue des Fleurs"
        Tbl(I).CP = "0" & I & I * 100
        Tbl(I).Ville = "Ville " & I
 
        For J = 1 To 4
 
            ReDim Preserve Tbl(I).Durée_RDV(1 To J)
 
            Tbl(I).Durée_RDV(J) = (I + 4) * J
 
    Next J, I
 
    For I = 1 To UBound(Tbl)
 
        Moyenne = Application.Average(Tbl(I).Durée_RDV)
 
        Debug.Print "La moyenne du client " & Tbl(I).NomClient _
                    & " habitant '" & Tbl(I).Adresse & " " & Tbl(I).CP & " " & Tbl(I).Ville _
                    & "' est de " & Moyenne
 
    Next I
 
    Debug.Print "-------------"
 
    For I = 1 To UBound(Tbl())
 
        For J = 1 To UBound(Tbl(I).Durée_RDV)
 
            Debug.Print "Les valeurs entrées pour le client " & Tbl(I).NomClient & " sont : " & Tbl(I).Durée_RDV(J)
 
    Next J, I
 
End Sub

[Rinat]

Bonjour,
Merci Theze. Suite à ta réponse d'hier j'ai modifié mon code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Option Explicit
'Définition du type
Type InfoClients
    Durée_RDV(1 To 5) As Variant
End Type
 
Public Sub Moyenne_Tableau_Type_Données()  ' (Client,Durée RDV)
Dim Tableau(1 To 10) As InfoClients
Dim i As Integer, Moyenne As Currency
 
' durée des 4 RDV du client n°3
For i = 1 To 4
    Tableau(3).Durée_RDV(i) = 4 * i
Next i
'moyenne de la durée des RDV du client n°3
Moyenne = Application.Average(Tableau(3).Durée_RDV)
'Copie dans la feuille active  du tableau.
'Rappel:Tableau(3).Durée_RDV est un taleau de dimension 1, donc UBound(Tableau(3).Durée_RDV)est suffisant et resize sur une seule ligne
Range("A3").Resize(1, UBound(Tableau(3).Durée_RDV)).Value = Tableau(3).Durée_RDV 'UBound(tableau,dimension souhaitée).
End Sub

Je vais maintenant étudier ton deuxième message.

[Rinat]

J'ai étudié et testé ton nouveau code. Impeccable.
Je te remercie bien pour ton aide. Bon week end.