Discussion :

[arsene38]

Bonjour à vous !!
J'aimerais créer une macro SAS qui me permettrais d'extraire à partir d'une table, une table des "n" valeurs les plus grandes et les "n" valeurs les plus petites pour une variable donnée.

Je débute sous SAS donc j'ai d'abords eu le réflexe de créer un prog SAS et après de faire ma macro mais je n'y arrive pas.
Mon raisonnement est que je commence par faire un tri "descending" de ma variable et de prendre les "n" premières valeurs et les "n" dernières à partir d'un tableIN vers un tableOUT afin d'avoir une macro du style:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
%macro extract (tableIN, n, tableOUT);
DATA &tableOUT;
SET &tableIN;
...

Pouvez-vous m'aider ?
Cordialement

[josef1980]

Bonsoir,
Essayer ce programme si cela répond à votre problématique.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
data test(drop=i);
do i=1 to 100;
x=i; 
output; 
end;
run;  /*Moi j'ai crée une table déja triée, mais vous il suffit de faire un proc sort sur la variable en question*/                                                                                                                                                                                                                                             
 
%macro exemple (tabin=,n=,tabout=); 
        data &tabout.;                                                                                                                  
                do i=1 to &n.,nb_obs-&n.+1 to nb_obs ;
        set &tabin. point=i nobs=nb_obs;                                                                                                
        output;                                                                                                                         
        end;                                                                                                                            
        stop;                                                                                                                           
        run;                                                                                                                            
%mend;                                                                                                                                  
 
%exemple (tabin=test,n=5,tabout=test2);                                                                                                 
 
proc print data=test2;                                                                                                                  
run;

Cordialement

[arsene38]

Bonjour, je vous remercie! au vu de la macro j'ai quelques doutes mais je vais essayer de la faire tourner.
J'ai également trié ma variable et je suis parti sur sur une boucle où si _N_ >=n alors je la supprime, je vais creuser ça.
En tous cas merci

[hossward]

Bonjour,
Ce code, sans tri, peut également répondre à ta requête :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
/* Jeux de donneés */
data normal;
do n=1 to 20;
Val=10*rannor(53124)+50;
output;
end;
run;  
 
ODS select extremeobs;
proc Univariate data=normal nextrobs=5 ;
id n ;
var val;
run;

Cdt Ward

[Haache]

JE PROPOSE CECI

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
data test;do x=1 to 100; 
output; 
end;
run;
 
 
%macro Extraire(table=,n=5,var=);
	proc sql noprint;
	SELECT COUNT(*) into: N1 FROM &table;
	quit;
	%let N2=%sysevalf(&N1-&n+1);
	proc sort data=&table  out=__test;
	by &var;
	run;
	data resultat;
	set __test;
	if _n_ le &n or _n_ ge &N2;
	run;
	proc sql noprint;
	drop table __test;
	quit;
%mend;
 
 
%Extraire(table=test,var=x); /*Ici par défaut n=5*/
%Extraire(table=test,n=20,var=x); /*Ici n=20*/