Discussion :

[Cha_rline]

Hello tout le monde,

J'ai un problème avec une boucle For. Cette dernière ne s'arrête pas quand l'indice (i) a atteint le nombre maximal (v_derniere) et continue, ce qui me fait donc une boucle infinie.
Et je ne comprend pas pourquoi.

Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
Sub supprimer()
 
Dim i As Integer
Dim v_derniere As Integer
 
 
 
'Calcul du nombre d'OF dans la liste
v_derniere = Cells(65535, 6).End(xlUp).Row
 
 
For i = 3 To v_derniere
 
    If Cells(i, 6).Value = "" Then
 
     Cells(i, 1).Delete Shift:=xlUp
     Cells(i, 2).Delete Shift:=xlUp
     Cells(i, 3).Delete Shift:=xlUp
     Cells(i, 4).Delete Shift:=xlUp
     Cells(i, 5).Delete Shift:=xlUp
     Cells(i, 6).Delete Shift:=xlUp
     Cells(i, 7).Delete Shift:=xlUp
 
     i = i - 1
     v_derniere = Cells(65535, 6).End(xlUp).Row
 
    End If
 
Next i
 
End Sub

Est-ce que quelqu'un peut m'aider ?

Merci d'avance
Charline

[Philippe Tulliez]

Bonjour,
A la première lecture rapide de ta procédure, il suffit de supprimer la ligne 25 qui ne sert strictement à rien mis à part perturber la boucle. La variable I est incrémentée par la boucle (For To Next)

[Cha_rline]

Hello Philippe,

La ligne 25 sert à dire : je veux recommencer le contrôle (if...) au numéro de ligne où ma ligne a été supprimée.

Si je ne mets pas cette partie du code, toutes les lignes ne seront pas vérifiées...

Alors peut-être que ça fonctionnera si j'enlève cette ligne, mais ça ne fera pas ce que je veux.

[illight]

Salut,


En lisant rapidement, dans un premier temps, il faut que tu fasses ta boucle dans l'autre sens :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Sub supprimer()
 
Dim i As Integer
Dim v_derniere As Integer
 
 
 
'Calcul du nombre d'OF dans la liste
v_derniere = Cells(65535, 6).End(xlUp).Row
 
 
For i = v_derniere To 3 step -1 
 
    If Cells(i, 6).Value = "" Then
 
     Cells(i, 1).Delete Shift:=xlUp
     Cells(i, 2).Delete Shift:=xlUp
     Cells(i, 3).Delete Shift:=xlUp
     Cells(i, 4).Delete Shift:=xlUp
     Cells(i, 5).Delete Shift:=xlUp
     Cells(i, 6).Delete Shift:=xlUp
     Cells(i, 7).Delete Shift:=xlUp
     v_derniere = Cells(65535, 6).End(xlUp).Row
 
    End If
 
Next i
 
End Sub

Tu n'auras alors plus de souci de boucle infinies, et les lignes voulues seront supprimées.

[Menhir]

En lisant rapidement, dans un premier temps, il faut que tu fasses ta boucle dans l'autre sens :

+1
Quand on fait des suppressions, toujours aller de bas en haut.

Pour simplifier ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub supprimer()
 
Dim i As Long
 
For i = Cells(Rows.Count, 6).End(xlUp).Row To 3 step -1 
    If Cells(i, 6).Value = "" Then Range(Cells(i, 1),Cells(i, 7)).Delete Shift:=xlUp
Next i
 
End Sub

[Cha_rline]

Salut,


En lisant rapidement, dans un premier temps, il faut que tu fasses ta boucle dans l'autre sens :

Tu n'auras alors plus de souci de boucle infinies, et les lignes voulues seront supprimées.

+1
Quand on fait des suppressions, toujours aller de bas en haut.

Pour simplifier ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub supprimer()
 
Dim i As Long
 
For i = Cells(Rows.Count, 6).End(xlUp).Row To 3 step -1 
    If Cells(i, 6).Value = "" Then Range(Cells(i, 1),Cells(i, 7)).Delete Shift:=xlUp
Next i
 
End Sub

Merci à vous deux ! Ca fonctionne très bien !

Je ne savais pas qu'il fallait faire dans le sens inverse en cas de suppression ! Vous m'avez appris quelque chose ! Je vais pouvoir changer quelques autres lignes de code

Merci beaucoup !
Charline

[Invité]

Salut,

Dans une boucle For,
For Index = IndexStart To IndexEnd Step IndexStep,
seul Index est potentiellement variable, les 3 autres parties sont stocké en tant que constantes.
Elles sont évalués une seule fois lors de l'initialisation de la boucle.
Donc, quand tu écris dans une boucle (Entre le For et le Next) IndexEnd = xxx, ce n'est pas pris en compte.
Il faut réinitialiser la boucle pour que le nouveau IndexEnd soit pris en compte.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Sub BoucleTest()
    Dim Index As Long
    Dim IndexStart As Long, IndexEnd As Long, IndexStep As Long
 
    Index = 1
    IndexStart = 1
    IndexEnd = 10
    IndexStep = 1
 
    For Index = IndexStart To IndexEnd Step IndexStep
        Debug.Print Index
        IndexStart = IndexStart + 1
        IndexEnd = IndexEnd - 1
        IndexStep = IndexStep + 1
    Next
End Sub

Comme tu le vois, le fait de modifier les 3 variables (IndexStart, IndexEnd et IndexStep) ne change pas le déroulement de la boucle (il y a bien 10 itération) car elles sont toutes les 3 stockés en tant que constante. Seul Index est modifiable.

[Cha_rline]

Merci pour l'explication

[Invité]

De rien

@+

[Menhir]

Je ne savais pas qu'il fallait faire dans le sens inverse en cas de suppression !

Ca n'a rien d'obligatoire mais, comme le prouve la simplification sur ton code, c'est beaucoup plus pratique.