Discussion :

[Occato]

Bonjour tous le monde,

Je suis bloqué dans le développement de mon fichier access.

J'ai une table ( Scéances) qui contient l'ensemble des scéances réalisée cette table contient entre autre les champ :
- ID_seances ( numéros unique de la scéances)
- ID_coordonnees ( numéros unique du patient )
- Tierpayant ( valeur binaire )

Dans mon formulaire je rentre tout d'abors le nom du patient ( liste déroulante) ensuite le reste des autres informations.

Je souhaiterai que sur mon formulaire d'entrée des valeurs ( lié à "Séances" : Nouvelle Scéance) mon checkbox prenne la dernière valeur de Tierpayant pour le patient concerné ( ID_coordonnees). Lorsque je modifie le patient dans le formulaire , la valeur de la checkbox doit donc changer.

J'ai essayé de travailler sur la valeur par défaut de Tierpayant dans mon formulaire et de faire un update avant MAJ de ID_coordonnees. Mais sans succès...

Valeur rentré dans " valeur par défaut" :
SELECT Last(Séances.Tierpayant) AS DernierDeTierpayant, Séances.ID_coordonnees
FROM Séances
GROUP BY Séances.ID_coordonnees
HAVING (((Séances.ID_coordonnees)=[Formulaires]![Nouvelle Scéance]![ID_coordonnees]));

Update VBA
Private Sub ID_coordonnees_BeforeUpdate(Cancel As Integer)
Me![Tierpayant].Requery
End Sub

Quelqu'un aurait il une piste?

Merci d'avance!!

[3ug3n]

Bonjour,

A l'aveugle (car manquant d'infos sur votre modèle, et la construction de votre form), je suis assez sceptique quant à l'utilisation de SQL directement en source d'un champ.

Je vous inviterais à vous orienter vers une solution du type :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private Sub ID_coordonnees_AfterUpdate()
Dim db As Database
Dim rst As Recordset
Dim strSQL As String
Dim lngIdCoord As Long
Dim blnTP As Boolean
 
lngIdCoord = Me.[ID_Coordonnees]
' + gestion d'erreur sur Me.[ID_Coordonnees]
 
Set db = CurrentDb
 
strSQL = "SELECT Seances.Tierpayant " _
             & " FROM Seances " _
             & " WHERE Seances.ID_Coordonnees = " & lngIdCoord & " AND Seances.ID_Seances =(SELECT Max(S1.ID_Seances) " _
             & " FROM Seances AS S1 Where S1.ID_Coordonnees = Seances.ID_Coordonnees) "
 
Set rst = db.OpenRecordset(strSQL)
 
    If Not (rst.EOF And rst.BOF) Then
      rst.MoveFirst
      blnTP = rst.Fields("TierPayant")
    Else
      'gestion d'erreur
    End If
 
Me.Tierpayant = blnTP
 
'Clean-up
rst.Close
Set rst = Nothing
db.Close
Set db = Nothing
 
End Sub

... et :
- à enlever la valeur par défaut et le code que vous avez postés.
- à bannir l'emploi des fonctions "premier"/"dernier"

[Occato]

Ça fonctionne parfaitement !! Simple et efficace.
Je passerai plus souvent par la case VBA+SQL dans mes prochains projets.


Un tout grand merci 3ug3n !