Discussion :

[papilou86]

Bonjours,
je crée une table en VBA de la façon ci dessous :
Mais a l'affichage la table s'affiche avec des largeurs de colonne standards de access. J'aimerai pouvoir donner une largeur différentes à la création de la table, pour avoir un affichage à l'ouverture que je n'ai pas a modifier.
est-ce possible?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Set tbl = Db.CreateTableDef("tempo") 'Création d'une table
Set fld = tbl.CreateField("Champ1", dbText)   'création du champ désignation
    fld.OrdinalPosition = 1                         'champ position 1
    fld.Size = 20                                   'taille 10 caractères
    tbl.Fields.Append fld                           'ajout du champ dans la table
 
Set fld = tbl.CreateField("Champ2", dbText)   'création du champ Item
    fld.OrdinalPosition = 2                         'champ position 2
    fld.Size = 50                                   'taille 10 caractères
    tbl.Fields.Append fld                           'ajout du champ dans la table

etc. etc.
Merci

[LedZeppII]

Bonsoir,

Après quelques essais je suis arrivé à le faire.
Il faut ajouter des propriétés aux champs de la table.
Pour je ne sais quelle raison, ces propriétés ne peuvent être ajoutées qu'une fois la table ajoutée à la collection TableDefs.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Dim db As DAO.Database
Dim tdef As DAO.TableDef, fld As DAO.Field, p As DAO.Property

Set db = CurrentDb

Set tdef = db.CreateTableDef("Table1")
' Crée 1er champ
Set fld = tdef.CreateField("Champ1", dbText, 50)
tdef.Fields.Append fld
' Crée 2e champ
Set fld = tdef.CreateField("Champ2", dbText, 50)
tdef.Fields.Append fld
 ' Ajoute la table à la collection
db.TableDefs.Append tdef

Set tdef = db.TableDefs("Table1")
' Crée propriété largeur colonne à 2000 twips (2000/567 cm)
Set p = db.CreateProperty("ColumnWidth", dbInteger, 2000)
' L'ajoute au champ champ1
tdef.Fields("Champ1").Properties.Append p
' Propriété pour définir l'ordre d'affichage des colonnes
Set p = db.CreateProperty("ColumnOrder", dbInteger, 2)
tdef.Fields("Champ1").Properties.Append p
' Proriété pour masquer les colonnes
Set p = db.CreateProperty("ColumnHidden", dbBoolean, False)
tdef.Fields("Champ1").Properties.Append p

Set p = db.CreateProperty("ColumnWidth", dbInteger, 4000)
tdef.Fields("Champ2").Properties.Append p
Set p = db.CreateProperty("ColumnOrder", dbInteger, 1)
tdef.Fields("Champ2").Properties.Append p
Set p = db.CreateProperty("ColumnHidden", dbBoolean, False)
tdef.Fields("Champ2").Properties.Append p

En espèrant que ça fonctionne pour toi aussi.
A+

[papilou86]

Merci de cette réponse, ca marche
merci encore