Discussion :

[antonysansh]

Bonjour le forum,

Je fais de nouveau appel à vous car j'aimerais savoir s'il existe une façon en VB, de déterminer sur quelle page va se trouver une ligne de ma feuille lors de l'impression.

En fait pour un souci de mise en forme je souhaiterais que certaine ligne ne soit pas séparer par un saut de page donc si je pouvais savoir sur quelles pages ces lignes vont être imprimées je pourrais changer le saut de page pour gérer le problème.

Merci d'avance à tous ceux qui prendront le temps de me répondre.

[parmi]

Bonjour,

Il te faudrait déterminer sur quelle ligne se situe les sauts de page versus celles que tu veux grouper.
Le code qui suit te permettrait de savoir où sont les sauts de page actuels

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
    Dim PageBr As Object
 
    For Each PageBr In ActiveSheet.HPageBreaks
        'MsgBox PageBr.Location.Row
        Debug.Print PageBr.Location.Row
   Next

Tu peux alors forcer les sauts de pages aux endroits que tu préfères

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.HPageBreaks.Add before:=Range("A" & LigneChoisie)

Par contre, dès que tu forceras un saut de pages, les autres seront décalés.
Tu pourrais lire les nouveaux sauts de pages en utilisant leur index

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.HPageBreaks.Item(Numéro de l'index).Location.Row

[antonysansh]

Merci beaucoup parmi,

J'avais fini par m'orienter vers les HPageBreaksmais ces derniers étaient un peu flous pour moi.
C'est maintenant plus clair, je vais pouvoir gérer mes sauts de pages avec les différents éléments que tu m'as apportés.

Je t'en remercie

[antonysansh]

Voilà ce que j'ai pu sortir grâce à toi parmi

Je récupère les premières lignes des pages :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Function Lignes_Pages(sh As Worksheet) As Variant
    '-------------------------------------------------------------------------------+
    '   Construit un tableau qui contient le numéro des premières lignes des pages  |
    '-------------------------------------------------------------------------------+
        Dim resultat(), i&, nb_pages&
        nb_pages = sh.PageSetup.Pages.Count                 'nombre de pages de la feuille
        ReDim resultat(nb_pages)
        resultat(0) = 1                                     'page 1 commence toujours ligne 1
        For i = 1 To nb_pages - 1
            resultat(i) = sh.HPageBreaks(i).Location.Row
        Next i
        Lignes_Pages = resultat()
End Function

Je test si une ligne est la première d'une page :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Function Premiere_Ligne_Page(Ligne As Long) As Boolean
    '-----------------------------------------------------------------------+
    '   Renvoie Vrai si la ligne en paramètre est la première d'une page    |
    '-----------------------------------------------------------------------+
    Dim i&, t(): t() = Lignes_Pages(ActiveSheet)
    For i = 0 To UBound(t)
        If Ligne = t(i) Then
            Premiere_Ligne_Page = True
            Exit For
        End If
    Next i
End Function

Ensuite comme je veux mettre mes lignes par deux, si la deuxième est en début de page, j'ajoute un saut de page avant la précédente :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Placer_HPB()
    '---------------------------------------------------+
    '   Place l'en-tête et son champ sur la même page   |
    '---------------------------------------------------+
    ActiveSheet.ResetAllPageBreaks
    Dim i&
    For i = 12 To 30 Step 3
        If Premiere_Ligne_Page(i) Then
            ActiveSheet.HPageBreaks.Add before:=Range("A" & i - 1)
        End If
    Next i
End Sub

Avec ça et en descendant le long des lignes je ne suis pas embêté avec les sauts de pages qui se décalent.

Encore merci à toi et bonne journée
Je passe en