Discussion :

[Tigris]

Bonjour à toutes et à tous,

Mon problème est simple à décrire mais me bloque depuis ce midi.

J'ai créé une macro qui doit :

* Ouvrir un fichier "1" ;
* Copier certaines lignes du fichier "1" dans mon fichier "Cible" ;
* Fermer le fichier "1".

Pas de problème de ce côté.

Ma problématique est :

Je dois effectuer cette action "d'ouverture/copier/coller/fermeture" sur un nombre indéterminé de fichiers Excel, placés dans un nombre indéterminés de dossiers, tous placés dans un même dossier mère.

Comment puis-je faire ?

Merci d'avance pour votre aide.

[parmi]

Bonjour,

Ça te prendrait une function récursive (qui se rappelle elle-même) pour pouvoir lire tous les sous-répertoires.
En cherchant sur ce site, tu devrais pouvoir trouver ton bonheur.

Personnellement, j'utiliserais Dir() pour rechercher les répertoires et les fichiers.
D'autres vont te suggérer le FileSystemObject...
À toi de voir

[parmi]

Voici un exemple que j'avais déjà fait pour quelqu'un.
Tu vas devoir apporter les modifications nécessaires (ton chemin principal, le type de fichier que tu veux ouvrir, une vérification du nom ou du contenu si nécessaire,...)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Sub SearchFiles()
    ImportFiles "C:"   'Change for the main folder
End Sub
 
Sub ImportFiles(varPath As Variant)
    Dim varFile As Variant
    Dim objColl As Collection
 
    On Error GoTo ErrTrap
 
    Set objColl = New Collection
 
    If Right(varPath, 1) <> "\" Then varPath = varPath & "\"
 
    varFile = Dir(varPath, vbDirectory + vbArchive)
    Do While varFile <> ""
        'Stock Folders
        If GetAttr(varPath & varFile) = vbDirectory Then
            If Left(varFile, 1) <> "." Then
                objColl.Add varPath & varFile
            End If
 
        'Dealing with the files
        ElseIf LCase(Right(varFile, 3)) = "jpg" Or LCase(Right(varFile, 4)) = "jpeg" Then
            'Do what you want with the image
            MsgBox varPath & varFile
'            Stop
        End If
        varFile = Dir
    Loop
 
    For Each varFile In objColl
        ImportFiles varFile
    Next
 
    Set objColl = Nothing
 
    Exit Sub
 
ErrTrap:
    MsgBox Err.Number & vbCrLf & Err.Description
End Sub

[kiki29]

Salut, va regarder ici : Liste des fichiers d'un dossier avec recherche récursive ou non via les APIs

[Tigris]

Bonjour,

Tout d'abord, merci pour les réponses apportées.

Hélas, celles-ci ne sont guère satisfaisantes dans mon cas, aucune ne fonctionne malgré les modifications nécessaires apportées.

Je rencontre généralement l'erreur "1004 - Fichier.xls introuvable". Celle-ci s'affiche pour le 1er fichier xls de chaque dossier (et la macro ne semble même pas traiter le reste).

Ci-dessous, mon code actuel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
 
Sub ImportFiles(varPath As Variant)
    Dim varFile As Variant
    Dim objColl As Collection
 
    On Error GoTo ErrTrap
 
    Set objColl = New Collection
 
    If Right(varPath, 1) <> "\" Then varPath = varPath & "\"
 
    varFile = Dir(varPath, vbDirectory)
    Do While varFile <> ""
        'Stock Folders
        If GetAttr(varPath & varFile) = vbDirectory Then
            If Left(varFile, 1) <> "." Then
                objColl.Add varPath & varFile
            End If
 
        'Dealing with the files
        ElseIf LCase(Right(varFile, 3)) = "xls" Then
            'Do what you want with the image
            Set Wb = Workbooks.Open(varFile)
            Wb.Close False
            Set Wb = Nothing
'            Stop
        End If
        varFile = Dir
    Loop
 
    For Each varFile In objColl
        ImportFiles varFile
    Next
 
    Set objColl = Nothing
 
    Exit Sub
 
ErrTrap:
    MsgBox Err.Number & vbCrLf & Err.Description
End Sub
 
Sub Test()
    ImportFiles "\\Dossier Racine contenant deux autres dossiers qui, eux, contiennent les fichiers Excel ciblés\"   'Change for the main folder
End Sub

Merci d'avance pour vos prochaines réponses.

[parmi]

Peut-être en changeant cette ligne ?

Set Wb = Workbooks.Open(varFile)

pour

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Wb = Workbooks.Open(varPath & varFile)

[Tigris]

Peut-être en changeant cette ligne ?

Cher "Parmi",

Faisons court, faisons bref, faisons efficace : je vous aime !

Problème résolu, merci beaucoup !