Retrouver numero de serie et nom du pc

**salvien** · 25/11/2014, 13h13

Bonjour à tous ,
Apres recherche et plusieurs test , je me permet d'ouvrir ce sujet car je ne trouve pas de réponse à ma question .
Je suis dans une société de 500+ employés , et sur ces 500 employés , une centaine ont des lenovo M83 sous windows 7 .
Lorsqu'on déploie des pc , un soft nous permet de définir le nom du pc en rapport avec le numéro de série , ce qui permet de les retrouver simplement.
Problème : les numéros de pc noté dans mon soft ne correspondent pas au numéro de série . C-à-d , pour un s/n: "A" , le nom dans le soft est bien "A" , mais sur le pc déployé , c'est "X"
Ma requêtes est donc : y a t'il un moyen de récupérer à l'aide d'un soft plusieurs données :
-Adresse IP
-Nom complet sur le domaine
-Numero de serie

Vous remerciant par avance pour vos conseils !
Cordialement
Salvien

Invité · 26/11/2014, 12h39

Hello

Après pour avoir le nom du pc >> dans démarer >> ordinateur >> clic droit >> propriété >> les informations de la machine

**salvien** · 26/11/2014, 13h22

merci pour la reponse =)
cependant , je souhaite pouvoir le faire en réseau , pour éviter d'aller sur tout les ordinateurs un par un =)

**hackoofr** · 26/11/2014, 13h49

Avec ce Vbscript vous pouvez faire peut-être ce que vous avez demandé

Il s’agit d’un VBScript permettant de récupérer sur une machine les informations suivantes :

== GENERAL ==
Nom du poste :
Workgroup ou domaine :
Marque :
Modele :
Serial :

== SYSTEME EXPLOITATION ==
OS :
Version:
Service Pack :
Numero Serie :
Type Version :
Date d’Installation :
== PROCESSEUR & RAM ==
Processeur :
Type Processeur :
RAM Total :
+Bank 0 :
+Bank 1 :
== DISQUE DUR & PARTITIONS ==
Disques Physiques :
Nom :
Taille :
Modèle :
Nbr de partition(s) :
Espace Total :
Partitions
C: Occupé à XX% – Taille Totale : YYY Go (ZZ Go utilisés)
== RESEAU ==
Carte Réseau –
Adresse MAC :
Adresse IP :
Sous Réseau:
Passerelle :
DNS :
Domaine DNS :

Par défaut, le script va vous générer un fichier texte à l’emplacement où a été lancé ce script. Il est possible de paramétrer le script afin que les données soient envoyées vers un partage réseau.
Script_Audit_PC.vbs

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
'==========================================================================
' NAME: Script Audit PC
' DATE  : 090505
' COMMENT: V1.0
'==========================================================================

On Error Resume Next

Dim objNetwork, objDrive, intDrive, intNetLetter 
Dim FSO, ObjFile, WshNetwork, SrtNewText, strText
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set WshNetwork = WScript.CreateObject("WScript.Network")
Set objShell = CreateObject("WScript.Shell")

hostname = WshNetwork.computername
username = WshNetwork.username
domainname = WshNetwork.UserDomain


'==========================================================================
'mettez ici l'emplacement du dossier dans lequel sera enregistrer le rapport
'si ce dossier n'existe pas, il sera crée
path = ""

'sharename = "logs_"&username&""

If  objFSO.FolderExists (""&path&"") Then
  Else
Set objFolder = objFSO.CreateFolder (""&path&"")
End If

'save softwares configuration In a txt file
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.CreateTextFile(""&path&""& hostname & " - "&username&".txt", True)
filepath = ""&path&""& hostname & " - "&username&".txt"

'==========================================================================
'INFOS GENERALES (Nom du poste, nom de l'utilisateur actuel)
'==========================================================================
objTextFile.WriteLine "== GENERAL =========================================================="&VbCrLf&""
objTextFile.WriteLine "Nom du poste : "& hostname &""
Set objWMISvc = GetObject( "winmgmts:\\.\root\cimv2" )
Set colItems = objWMISvc.ExecQuery( "Select * from Win32_ComputerSystem", , 48 )
For Each objItem in colItems
    strComputerDomain = objItem.Domain
    If objItem.PartOfDomain Then
        objTextFile.WriteLine "Domaine : " & strComputerDomain
    Else
        objTextFile.WriteLine "Workgroup : " & strComputerDomain
    End If
objTextFile.WriteLine "Marque : " & objItem.Manufacturer
objTextFile.WriteLine "Modele : " & objItem.Model
Next
Set SNSet = GetObject("winmgmts:").InstancesOf ("Win32_BIOS")
for each SN in SNSet
objTextFile.WriteLine "Serial : " & SN.SerialNumber
Next
objTextFile.WriteLine

'==========================================================================
'INFOS SYSTEME 
'==========================================================================
objTextFile.WriteLine "== SYSTEME EXPLOITATION ============================================="&VbCrLf&""

Set dtmConvertedDate = CreateObject("WbemScripting.SWbemDateTime")

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colOperatingSystems = objWMIService.ExecQuery _
    ("Select * from Win32_OperatingSystem")

For Each objOperatingSystem in colOperatingSystems

    objTextFile.WriteLine "OS : " & objOperatingSystem.Caption
    objTextFile.WriteLine "Version: " & objOperatingSystem.Version 
    objTextFile.WriteLine "Service Pack : " & objOperatingSystem.ServicePackMajorVersion
    objTextFile.WriteLine "Numero Serie : " & objOperatingSystem.SerialNumber
    objTextFile.WriteLine "Type Version : " & objOperatingSystem.BuildType
    dtmConvertedDate.Value = objOperatingSystem.InstallDate
    dtmInstallDate = dtmConvertedDate.GetVarDate
    objTextFile.WriteLine "Date d'Installation : " & dtmInstallDate 
    objTextFile.WriteLine
Next

'==========================================================================
'INFORMATIONS MATERIEL
'==========================================================================


objTextFile.WriteLine "== PROCESSEUR & RAM ================================================="&VbCrLf&""

'-- Processeur : nom
    Set colComputer = objWMIService.ExecQuery("Select * from Win32_Processor")
    For Each objComputer In colComputer
        objTextFile.WriteLine "Processeur :"& vbTab &"" & objComputer.Name
    Next

'-- Processeur : type
Set colSettings = objWMIService.ExecQuery _
 ("SELECT * FROM Win32_Processor")
For Each objProcessor In colSettings
    objTextFile.WriteLine "Type Processeur : "& vbTab &"" & objProcessor.Description
Next
objTextFile.WriteLine
'-- RAM
Set colComputer = objWMIService.ExecQuery _
("Select * from Win32_ComputerSystem")
For Each objComputer In colComputer
    objTextFile.WriteLine "RAM Total : "&FormatNumber (objComputer.TotalPhysicalMemory /1048576+1, 0) & "Mo"
    objTextFile.WriteLine
Next
    
For Each objMem In GetObject("winmgmts:{impersonationLevel=impersonate}\\" & strComputer & "\root\cimv2").InstancesOf("Win32_PhysicalMemory")
    objTextFile.WriteLine ""& vbTab &"+"&  objMem.BankLabel &" : "& objMem.Capacity/1024/1024 & " Mo"
Next

' Disques et partition
objTextFile.WriteLine ""&VbCrLf&"== DISQUE DUR & PARTITIONS =========================================="&VbCrLf&""

objTextFile.WriteLine "Disques Physiques :"
Set colItems = objWMIService.ExecQuery(_
"Select * from Win32_DiskDrive")

            maxsize = 0
            drive = 0

            For Each objItem in colItems
If objItem.Partitions > 0 Then
objTextFile.WriteLine ""&vbTab &"Nom : "& vbTab &"" & objItem.Name 
objTextFile.WriteLine ""&vbTab &"Taille : " & Int(objItem.Size /(1073741824)) & " GB" 
objTextFile.WriteLine ""&vbTab &"Modèle : " & objItem.Model 
objTextFile.WriteLine ""&vbTab &"Nbr de partition(s) : "& vbTab &"" & objItem.Partitions &VbCrLf&"" 

maxsize = maxsize + Int(objItem.Size /(1073741824))
drive = drive + 1
Else
End If
Next

objTextFile.WriteLine"Espace Total : "&maxsize&" Go dans "&drive&" disques durs"

objTextFile.WriteLine ""&VbCrLf&"Partitions"

    '-- Partitions et Tx Occupation
        Set colDisks = objWMIService.ExecQuery _
        ("Select * from Win32_LogicalDisk Where DriveType = 3")
        For Each objDisk In colDisks
            intFreeSpace = objDisk.FreeSpace /1000000000             'espace disque libre
            intTotalSpace = objDisk.Size /1000000000
            pctFreeSpace = intFreeSpace / intTotalSpace
            intOccupedSpace = intTotalSpace - intFreeSpace
            pctOccupedSpace = intOccupedSpace / intTotalSpace
            Disk = objDisk.DeviceID
    objTextFile.WriteLine ""& vbTab &" "&Disk&" Occupé à "&FormatPercent(pctOccupedSpace,0)&" - Taille Totale : " &FormatNumber (intTotalSpace,0)&" Go ("&FormatNumber(intFreeSpace,0)&" Go utilisés)"
Next

'==========================================================================
'RESEAU
'==========================================================================
objTextFile.WriteLine ""&VbCrLf&"== RESEAU ==========================================================="&VbCrLf&""
Set colNicConfigs = objWMIService.ExecQuery _
 ("Select * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")
 
 
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colAdapters = objWMIService.ExecQuery _
    ("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")
 
n = 1
objTextFile.WriteLine
 
For Each objAdapter in colAdapters
   objTextFile.WriteLine "Carte Réseau - " & objAdapter.Description
  objTextFile.WriteLine "  Adresse MAC : " & vbTab & objAdapter.MACAddress
 
   If Not IsNull(objAdapter.IPAddress) Then
      For i = 0 To UBound(objAdapter.IPAddress)
         objTextFile.WriteLine "  Adresse IP : " &vbTab & vbTab & objAdapter.IPAddress(i)
      Next
   End If
 
   If Not IsNull(objAdapter.IPSubnet) Then
      For i = 0 To UBound(objAdapter.IPSubnet)
         objTextFile.WriteLine "  Sous Réseau: " &vbTab & vbTab & objAdapter.IPSubnet(i)
      Next
   End If
 
   If Not IsNull(objAdapter.DefaultIPGateway) Then
      For i = 0 To UBound(objAdapter.DefaultIPGateway)
         objTextFile.WriteLine "  Passerelle : " &vbTab & vbTab & objAdapter.DefaultIPGateway(i)
      Next
   End If
 
    If IsNull(objAdapter.DefaultIPGateway) Then
    objTextFile.WriteLine
            objTextFile.WriteLine "  Pas de DNS Specifié"
 Else
 
   If Not IsNull(objAdapter.DNSServerSearchOrder) Then
      For i = 0 To UBound(objAdapter.DNSServerSearchOrder)
         objTextFile.WriteLine "  DNS :" & objAdapter.DNSServerSearchOrder(i)
      Next
   End If
 
   objTextFile.WriteLine "  Domaine DNS : " & objAdapter.DNSDomain
 
   If Not IsNull(objAdapter.DNSDomainSuffixSearchOrder) Then
      For i = 0 To UBound(objAdapter.DNSDomainSuffixSearchOrder)
         objTextFile.WriteLine "    Liste de recherche suffixe DNS : " & _
             objAdapter.DNSDomainSuffixSearchOrder(i)
      Next
   End If
End If

' Configuration WINS
 If IsNull(objAdapter.WINSPrimaryServer) And IsNull(objAdapter.WINSSecondaryServer) Then
  objTextFile.WriteLine
   objTextFile.WriteLine "Pas de WINS specifié"
    objTextFile.WriteLine
   Else
   objTextFile.WriteLine "  WINS"
   objTextFile.WriteLine "  ----"
   objTextFile.WriteLine "    Serveur WINS Primaire :   " & objAdapter.WINSPrimaryServer
   objTextFile.WriteLine "    Serveur WINS Secondaire : " & objAdapter.WINSSecondaryServer
 End If
  n = n + 1 
Next

Function WMIDateStringToDate(utcDate)
   WMIDateStringToDate = CDate(Mid(utcDate, 5, 2)  & "/" & _
       Mid(utcDate, 7, 2)  & "/" & _
           Left(utcDate, 4)    & " " & _
               Mid (utcDate, 9, 2) & ":" & _
                   Mid(utcDate, 11, 2) & ":" & _
                      Mid(utcDate, 13, 2))
End Function

objTextFile.WriteLine ""&VbCrLf&"=========================================================================="
objTextFile.WriteLine "==                       File saved @ "&Now&"               =="
objTextFile.WriteLine "=========================================================================="&VbCrLf&""
 
objTextFile.close
WScript.Quit(1)

**pradeaulasede** · 01/12/2014, 09h31

...tu utilisais un scan d'adresse ip sur ton réseau, tu aurais les adresses Ip en activité et en fonction des logiciels tu auras plusieurs informations sur tes machines (nom, adresse MAC etc...). Advanced Ip Scanner (gratuit) fait tout ça.
Si jamais ton logiciel te donne pas d'autre information que l'IP, tu peux faire ping -a adresse_IP et tu auras le nom entier du PC... pour le N° de série par contre.... j'ai pas d'idée...
Bonne journée !

Retrouver numero de serie et nom du pc

Windows 7

Discussions similaires

Partager

Partager