Discussion :

[Bklein51]

Bonjour,

Je cherche à nommer une plage de cellule à partir d'une valeur d'une autre cellule.

Je m'explique plus clairement :

Sous VBA, j'utilise le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim MaPlage as Range
Set MaPlage =  Range("A2":"A40")
Names.Add Name:=Range("A1").value, RefersTo := MaPlage

Cela ne marche pas, visiblement le "Range("A1") ne passe pas bien comme nom de plage...

Auriez vous une idée, solution ?

Merci d'avance !

[vinc_bilb]

Bonjour

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim MaPlage As Range
Set MaPlage = Range("A2:A40") ' Corrigé
Names.Add Name:=CStr(Range("A1").Value), RefersTo:=MaPlage 'J'ai rajouté la conversion en string forcée

Bonne journée

Attention: vous ajoutez le range nommé au workbook actif .... si vous pointez sur un autre classeur, ça va s'enregistrer ailleurs

[Bklein51]

Salut Vinc,

Merci pour ta réponse rapide. J'ai adapté ta réponse à mon code mais j'ai une erreur d'exécution 1004 : Erreur définie par l'application ou l'objet,

Je post mon code exact, peut être que tu verras ce qui cloche car je tourne en rond là :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Dim N As Integer
N = Sheets("Listes sociétés").Range("ZZ4").End(xlToLeft).Column + 0
Dim MaPlage As Range
Set MaPlage = Sheets("Listes sociétés").Range("A4:A40").Offset(0, N)
Names.Add Name:=CStr(Range("K7").Value), RefersTo:=MaPlage

Tout ceci est sous un bouton activX de la feuille principale où se trouve la range("K7").

[vinc_bilb]

Rebonjour;

Non, sans un exemple des feuilles associées, c'est moi qui tourne en rond .... en particulier entre le range K7 et la colonne ZZ ....
Je pronostiquerai bien un erreur récurrent, quand les gens n'utilisent pas le .currentRegion pour un range

Je ne sais pas si le code a été adapté d'un enregistrement macro, mais il est assez .... original

[Bklein51]

Voici mon fichier

Cela va sans doute t'éclairer !

Permis feu.xlsm

[vinc_bilb]

A la louche, quelquechose comme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
Sub Assign_Rng_Name()
 
Dim Wsh As Worksheet
Dim SrcRng As Range, ColRng As Range
Dim RngN As String
Dim ColN As Single, RowOffs As Single
 
' Init
    Set Wsh = ThisWorkbook.Worksheets("Listes sociétés")
    Set SrcRng = Wsh.Range("A2").CurrentRegion
    Debug.Print SrcRng.Address
 
    If SrcRng.Cells.Count = 0 Then Exit Sub
 
    For ColN = 1 To SrcRng.Columns.Count
 
        Set ColRng = SrcRng.Columns(ColN)
        Debug.Print ColRng.Address
 
        If ColN = 1 Then
 
            RngN = CStr(SrcRng(1, ColN).Value)
 
            Set ColRng = ColRng.Offset(1, 0).Resize(ColRng.Rows.Count - 1, 1)   ' Toutes les lignes non vides sauf la 1ere
            Debug.Print ColRng.Address
 
            ThisWorkbook.Names.Add Name:=RngN, RefersTo:=ColRng
            Debug.Print ColRng(1, 1).V
 
            Else:
 
                RngN = Replace(CStr(SrcRng(2, ColN).Value), " ", "_")
 
                If (RngN <> vbNullString) And (Not (IsEmpty(SrcRng(3, ColN)))) Then
 
                    Set ColRng = ColRng.Offset(2, 0).Resize(ColRng.Cells.Count - 2, 1)  ' Toutes les lignes non vides sauf les 2 premières
                    Debug.Print ColRng.Address, ColRng.SpecialCells(xlCellTypeConstants).Address
                    Set ColRng = ColRng.SpecialCells(xlCellTypeConstants)
 
                    ThisWorkbook.Names.Add Name:=RngN, RefersTo:=ColRng
 
                End If
 
        End If
 
    Next ColN
 
End Sub

[Bklein51]

Avec du retard, je viens d'adapter un peu tout ce que tu avais posté et ça fonctionne !
Merci beaucoup !