Ma listbox ne se refresh pas

**Merellys** · 02/06/2014, 11h16

Oui, j'ai reflechi après coup...

J'ai fait ce que tu m'a dit et le problème est presque réglé:

Maintenant, machine, secteur et commande s'affichent, cependant, une erreur demeure toujours lorsque je veux selectionner une machine ou un secteur, pour les deux, l'erreur n° 3464 (Type de données incompatible dans l'expression du critère) s'affiche et la ligne n° 36 est surlignée...

Sinon tout le reste fonctionne bien.

Par contre pour les dates je vais rajouter une colonne "Année" pour que mon chef puisse faire le compte en fin d'année. Je vais donc rajouter une colonne dans ma table "composants" en mettant en numérique avec un critère de 4 chiffres. Ensuite je rajoute ma colonne nommée "Année" dans les lignes 10 à 12 c'est bien ça?

Tu as rajouté une checkbox pour les quantités, tu as fait ça pour un soucis de codage? (j'essaye de comprendre).

Et pour finir, ce code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Private Sub RefreshQuery()
  Dim sSQL As String    'évite de nommer avec des mots-clés !  SQL => sSQL
  Dim sSQLWhere As String
  Dim ctl As Control
  Dim q As QueryDef
  'Constructionde la partie SELECT
  sSQL = "SELECT CodComposants, Composant, Reference, Marque, " _
               & "Fournisseur, Qte, PUHT, PTOTAL, Secteur, Machine, OI, " _
               & "Date, Commande, Devis FROM Composants"
  'Construction de la clause Where
  For Each ctl In Me.Controls
    If Left(ctl.Name, 7) = "cmbRech" And Not IsNull(ctl) = True Then
        If IsDate(ctl) Then
            sSQLWhere = sSQLWhere & Mid(ctl.Name, 8) & "=#" & Format(ctl, "mm/dd/yy") & "# and "
          Else
            If IsNumeric(ctl) Then
                sSQLWhere = sSQLWhere & Mid(ctl.Name, 8) & "=" & ctl & " and "
              Else
                sSQLWhere = sSQLWhere & Mid(ctl.Name, 8) & "=""" & ctl & """ and "
            End If
        End If
    End If
  Next ctl
  'Entête de la clause Where et suppression du dernier " and "
  If Len(sSQLWhere) <> 0 Then sSQLWhere = " Where " & Left(sSQLWhere, Len(sSQLWhere) - 5)
  'Ajouter la clause Where et poser le point-virgule final
  sSQL = sSQL & sSQLWhere & ";"
  'Mise à jour de rRowSource
  Set q = CurrentDb.QueryDefs("rRowSource")
  q.SQL = sSQL
  Set q = Nothing
  Me.lstResults.RowSource = "rRowSource"
  Me.lblStats.Caption = DCount("*", "rRowSource") & " / " & DCount("*", "Composants")
End Sub

C'est celui qui correspond à celui là?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub Form_Load()
Dim ctl As Control
 
For Each ctl In Me.Controls
    Select Case Left(ctl.Name, 3)
        Case "chk"
            ctl.Value = -1
        Case "lbl"
            ctl.Caption = "- * - * -"
          Case "txt"
            ctl.Visible = False
            ctl.Value = ""
        Case "cmb"
            ctl.Visible = False
    End Select
Next ctl
 
Me.lstResults.RowSource = "SELECT CodComposants, Composant, Reference, Marque, Fournisseur, Qte, PUHT, PTOTAL, Sec, UT, OI, Sec, Date, Ncommande, Devis FROM Composants;"
Me.lstResults.Requery
 
End Sub

**ClaudeLELOUP** · 02/06/2014, 13h56

Tu as rajouté une checkbox pour les quantités, tu as fait ça pour un souci de codage? (j'essaye de comprendre).

Je l’ai fait pour des raisons didactiques, pour que mon exemple contienne les trois cas de figure.
Selon que le critère est une date, du numérique ou du texte, la syntaxe est différente, revois les lignes 16 à 24 du code de mon billet 33.

je veux sélectionner une machine ou un secteur, pour les deux, l'erreur n° 3464 (Type de données incompatible dans l'expression du critère)

Tu n’as probablement pas modifié la propriété « Contenu » de la zone de liste comme je te le proposais :

- pour tes listes, vois comment j’ai procédé pour le contenu de cmbRechQte. Cette manière de faire te permet de proposer à l’utilisateur uniquement les items de choix qui existent vraiment dans la source de données.

Tu as probablement laissé comme dans ta version originale, la colonne liée n’est pas du même type que celui de la colonne de ta table => le message.
N.B. Dans l'exemple que j'ai posté, j'avais modifié la colonne liée, tu ne l'as peu-être pas remarqué.

Et pour finir, ce code: ...
C'est celui qui correspond à celui là?

Non, l’un n’est pas l’équivalent de l’autre ! D’ailleurs le code que tu avais dans l’événement sur « Chargement » est parfaitement inutile : il suffit de définir correctement les propriétés des contrôles du formulaire.

**Merellys** · 03/06/2014, 07h55

Envoyé par ClaudeLELOUP

Tu n’as probablement pas modifié la propriété « Contenu » de la zone de liste comme je te le proposais :

Tu as probablement laissé comme dans ta version originale, la colonne liée n’est pas du même type que celui de la colonne de ta table => le message.
N.B. Dans l'exemple que j'ai posté, j'avais modifié la colonne liée, tu ne l'as peu-être pas remarqué.,

Bonjour,

je pense avoir fait comme toi (sachant que les cmbRechMachine et cmbRechSecteur y étaient déjà):

Cependant, ça ne fonctionne toujours pas...:

http://www.hostingpics.net/viewer.ph...erreur3464.png

**ClaudeLELOUP** · 03/06/2014, 10h59

Bonjour,

Je vois que dans ta cmbRechMachine tu affiches « Référence » (qui semble être du numérique) et non pas « Machine » qui lui est du texte => le message d’erreur.
Conclusion
Ou bien, tu veux rechercher sur « Machine » et tu modifies le contenu de ta zone de liste.
Ou bien tu veux rechercher sur « Référence », mais alors, tu dois modifier le nom de tes contrôles pour respecter les conventions de nommage utilisées dans le code.

**Merellys** · 06/06/2014, 10h48

Bonjour,

j'ai réglé le soucis pour ce qui est des secteurs.

Par contre machine ne fonctionne toujours pas, et de base je l'avais mis en texte puisque certaines machines commencent par "0" et j'ai besoin de mes 6 chiffres en permanence.

**ClaudeLELOUP** · 06/06/2014, 11h30

Bonjour,

Par contre machine ne fonctionne toujours pas, et de base je l'avais mis en texte puisque certaines machines commencent par "0" et j'ai besoin de mes 6 chiffres en permanence.

Hum, ça se complique : d'après le type du contrôle de recherche (123456 => Numérique apparent) on doit pouvoir trouver une donnée qui, bien qu’en chiffres, a été définie en tant que texte.

Je cherche une astuce...

**ClaudeLELOUP** · 07/06/2014, 05h25

Bonjour,

Une piste :

• À l’ouverture du formulaire :
- rechercher le nom de la table source de la zone de liste ( = ce qui suit « From » dans la requête « rRowSource » ;
- rechercher pour chaque « cmbRechxxx » le type de la colonne cible et le mémoriser dans la propriété « Remarque » (Tag).
• Dans Private Sub RefreshQuery, aux lignes 16 à 24, se référer à la propriété Tag pour aiguiller le choix du délimiteur.

Je ne suis pas actuellement disponible pour te proposer un code que j’aurai testé : probablement pas avant une huitaine de jours. Désolé.

**Merellys** · 11/06/2014, 16h01

Bonjour!

Pour le code ce n'est pas grave car je dois utiliser une autre table pour les machines, qui n'est pas du tout à jour...

Si je fini avant je vais essayer de regarder le code.

**ClaudeLELOUP** · 12/06/2014, 15h05

Bonjour,

Pour éviter du code supplémentaire, procède comme ceci :
- dans la propriété « Remarque » de tes contrôles « cmbRechxxxxxx » inscris le type de données que tu as choisi pour xxxxxx dans la table (Texte, Date, Numérique) comme ceci :

- le code devient :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
Option Compare Database
Option Explicit
 
Private Sub RefreshQuery()
  Dim sSQL As String    'évite de nommer avec des mots-clés !  SQL => sSQL
  Dim sSQLWhere As String
  Dim ctl As Control
  Dim q As QueryDef
  'Constructionde la partie SELECT
  sSQL = "SELECT CodComposants, Composant, Reference, Marque, " _
               & "Fournisseur, Qte, PUHT, PTOTAL, Secteur, Machine, OI, " _
               & "Date, Commande, Devis FROM Composants"
  'Construction de la clause Where
  For Each ctl In Me.Controls
    If Left(ctl.Name, 7) = "cmbRech" And Not IsNull(ctl) = True Then
         Select Case ctl.Tag  'choisir le délimiteur en fonction du type inscrit dans la propriété Remarque
           Case "Texte"
             sSQLWhere = sSQLWhere & Mid(ctl.Name, 8) & "=""" & ctl & """ and "
           Case "Date"
             sSQLWhere = sSQLWhere & Mid(ctl.Name, 8) & "=#" & Format(ctl, "mm/dd/yy") & "# and "
           Case "Numérique"
             sSQLWhere = sSQLWhere & Mid(ctl.Name, 8) & "=" & ctl & " and "
         End Select
    End If
  Next ctl
  'Entête de la clause Where et suppression du dernier " and "
  If Len(sSQLWhere) <> 0 Then sSQLWhere = " Where " & Left(sSQLWhere, Len(sSQLWhere) - 5)
  'Ajouter la clause Where et poser le point-virgule final
  sSQL = sSQL & sSQLWhere & ";"
  'Mise à jour de rRowSource
  Set q = CurrentDb.QueryDefs("rRowSource")
  q.SQL = sSQL
  Set q = Nothing
  Me.lstResults.RowSource = "rRowSource"
  Me.lblStats.Caption = DCount("*", "rRowSource") & " / " & DCount("*", "Composants")
End Sub
Public Sub ModifCHK()
  Me("cmbRech" & Mid(Me.ActiveControl.Name, 4)).Visible = Not Me("cmbRech" & Mid(Me.ActiveControl.Name, 4)).Visible
  If Me("cmbRech" & Mid(Me.ActiveControl.Name, 4)).Visible = False Then
      Me("cmbRech" & Mid(Me.ActiveControl.Name, 4)) = Null
      Call RefreshQuery
    Else
      DoCmd.GoToControl Me("cmbRech" & Mid(Me.ActiveControl.Name, 4)).Name
      Me.ActiveControl.Dropdown
  End If
End Sub
Private Sub chkMachine_Click()
  Call ModifCHK
End Sub
 
Private Sub chkMarque_Click()
  Call ModifCHK
End Sub
 
Private Sub chkQte_AfterUpdate()
  Call ModifCHK
End Sub
 
Private Sub chkSect_Click()
  Call ModifCHK
End Sub
 
Private Sub chkSecteur_Click()
  Call ModifCHK
End Sub
Private Sub chkDate_Click()
  Call ModifCHK
End Sub
Private Sub chkCommande_click()
  Call ModifCHK
End Sub
Private Sub chkFournisseur_click()
  Call ModifCHK
End Sub
Private Sub chkReference_click()
  Call ModifCHK
End Sub
Private Sub chkComposant_click()
  Call ModifCHK
End Sub
Private Sub cmbRechCommande_AfterUpdate()
  Call RefreshQuery
End Sub
 
Private Sub cmbRechComposant_AfterUpdate()
  Call RefreshQuery
End Sub
 
Private Sub cmbRechDate_AfterUpdate()
  Call RefreshQuery
End Sub
 
Private Sub cmbRechFournisseur_AfterUpdate()
  Call RefreshQuery
End Sub
 
Private Sub cmbRechMachine_AfterUpdate()
  Call RefreshQuery
End Sub
 
Private Sub cmbRechMarque_AfterUpdate()
  Call RefreshQuery
End Sub
 
Private Sub cmbRechQte_AfterUpdate()
  Call RefreshQuery
End Sub
Private Sub cmbRechReference_AfterUpdate()
  Call RefreshQuery
End Sub
 
Private Sub cmbRechSect_AfterUpdate()
  Call RefreshQuery
End Sub
 
Private Sub cmbRechSecteur_AfterUpdate()
  Call RefreshQuery
End Sub
 
Private Sub Form_Open(Cancel As Integer)
  Call RefreshQuery
End Sub
 
Private Sub lstResults_DblClick(Cancel As Integer)
   DoCmd.OpenForm "frmAutoComposants", acNormal, , "[CodComposants] = " & Me.lstResults
End Sub

L’exemple corrigé est ici : http://claudeleloup.developpez.com/&...12Merellys.mdb

**Merellys** · 14/06/2014, 06h55

Bonjour!

J'ai remplacé à la main les morceaux de codes "faux" dans celui que tu m'avais donné avec le nouveau, car j'y ai rajouté deux trois petites choses. Et ça fonctionne! Merci!

Par contre, est-ce qu'on peut mettre le numéro des lignes dans le code?

**ClaudeLELOUP** · 14/06/2014, 11h32

Bonjour,

Par contre, est-ce qu'on peut mettre le numéro des lignes dans le code?

Je ne le pense pas.

Mais pour quoi faire ?

**Merellys** · 14/06/2014, 11h48

Pour s'y retrouver parce que j'imagine que lorsqu'il y a des longs codes, c'est plus pratique de les avoir plutôt que de compter, enfin j'imagine... enfin c'était juste une questioncomme ça car mon code n'est pas assez conséquent pour avoir besoin de la numérotation des lignes.

Mon chef m'a demandé de modifier les listes de manière à ce que quand je choisi un critère, dans les autres ça me mette automatiquement les critères qui sont liés au premier critère.

Je peux utiliser ce tutoriel sans soucis avec le code que tu m'a donné ça ne va pas poser de problèmes?

**ClaudeLELOUP** · 14/06/2014, 11h59

Je peux utiliser ce tutoriel sans soucis avec le code que tu m'a donné ça ne va pas poser de problèmes?

Pas de souci !

**Merellys** · 02/07/2014, 17h21

Bonjour!

Pardonnez moi pour ces 2 semaines d'absence mais on avait besoin de moi ailleurs...

J'ai utilisé le tutoriel (en lien dans mon message précédent). D'abord en faisant exactement comme dans celui ci (j'ai fait une DB à part) etensuite je l'ai refaite avec mes valeursn et là, c'est le drâme, ça ne fonctionne plus!

Voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Option Compare Database
 
Private Sub cmbSecteur_AfterUpdate()
 
End Sub
 
Private Sub cmbSecteur_AfterUpdate()
Dim lngcodSe As Long
Dim SQL As String
 
If Not IsNumeric(Me!cmbSecteur) Then Exit Sub
lngcodSe = Me!cmbSecteur
SQL = "SELECT codMachine, Reference,codSecteur FROM TBLMachine WHERE codSecteur =" & lngcodSe & "ORDER BY Reference"
cmbMachine.RowSource = SQL
cmbMachine.Enabled = True
cmbMachine.SetFocus
cmbMachine.Dropdown
 
End Sub

La mise en page du formulaire est la même que dans le tuto. Cependant la première ligne se nomme "Secteur" et la seconde "Machine".

**Merellys** · 02/07/2014, 18h48

J'ai oublié de préciser: j'avais un blocage dès que je choisissais un secteur (le petit chat me disait qu'il y avait un probleme avec "cmbSecteur_AfterUpdate") et la seconde zone restait grisée.

J'ai changé la désignation de certaines appelations pour faire exactement comme dans le tuto. A present la seconde zone se dégrise et je peux "choisir" mais la liste est vide.

**ClaudeLELOUP** · 03/07/2014, 08h13

Bonjour,

J’ai perdu le fil !
Si j’ai bien suivi :
- ton formulaire de recherche fonctionne ;
- ce que tu essaies maintenant, c’est rendre tes zones de listes interdépendantes, de sorte que le choix opéré dans l’une d’elles restreigne les choix offerts par les autres.

En conséquence, je te suggère de placer cette discussion-ci en « Résolu » et à ouvrir une autre discussion dans laquelle tu exposes ton nouveau problème.

Cordialement.

**Merellys** · 03/07/2014, 14h01

Bonjour Claude,

d'ac, encore merci pour ton aide et je vais en faire un autre

**Merellys** · 03/07/2014, 14h15

Je rajoute juste une dernière chose: j'essaye de travailler dessus en essayant de faire le code toute seule, et je reviens faire le nouveau sujet si ça ne fonctionne et vous faire part de mon code.

Bonne journée

Ma listbox ne se refresh pas [AC-2000]

Access

Discussions similaires

Partager

Partager