Discussion :

[wacker26]

Bonsoir à tous,

Je débute en SAS, et j'aimerais solliciter votre aide concernant un petit problème que je rencontre. Je dispose d'une table comme suit:


Et j'aimerais faire une sorte de tableau croisé, de la sorte sous sas:


où, par exemple, l'entrée (ligne=valeur2,colonne=valeur3) m'indique combien de fois dans mon tableau initial je passe de valeur2 à valeur3 (et non l'inverse, il y a une notion de temps (04,05,06,etc.), donc de sens, passer de valeur1 à valeur 2 est différent du passage réciproque. Le tableau n'est donc pas symétrique) au cours du temps (VAR_04, VAR_05, etc.). Par exemple, à ligne 3 du tableau on compterait 1 passage de valeur2 à valeur3 et un passage de valeur3 à valeur2.

Je ne sais pas trop comment faire ça, c'est une sorte de tableau résumant l'état du réseau (le nombre de passage d'un état à l'autre).

Je précise que le nombre de valeurs possibles est grand, et que j'ai déjà, si cela peut aider, fait un tableau sous excel que j'ai importé dans SAS où les observations et les variables sont comme dans le tableau que je souhaite obtenir.


Je vous remercie pour votre aide, et vous souhaite une bonne soirée

Wacker.

[JeromeMATHIAS]

Bonjour, il manque quelques éléments.
Quel est le nom (et le nombre) de tes variables, et quel est leur type (numérique ou longueur de caractère)

[wacker26]

Bonsoir !

J'ai codé une première macro qui devrait me permettre d'effectuer ce que je désirais. Cela dit, les compteurs restent à 0.
Je vous copie tout le code (quelques lignes), il tourne bien, mais les compteurs ne fonctionnent pas :/

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
DATA table1 ;
input nom $  var2004  var2005  var2006   var2007 ;
cards ;
etu1 1 2 2 2
etu2 1 2 3 4
etu3 1 3 1 2
run ;
 
%MACRO test;
DATA results;
SET table1;
%DO i=1 %TO 4 %BY 1;
%DO j=1 %TO 4 %BY 1;
RETAIN cpt&i.&j. 0;
%if var2004=i and   var2005=j %then cpt&i.&j.=%EVAL(cpt&i.&j.+1);
%if var2005=i and	var2006=j %then cpt&i.&j.=%EVAL(cpt&i.&j.+1);
%if var2006=i and	var2007=j %then cpt&i.&j.=%EVAL(cpt&i.&j.+1);
%if var2007=i and	var2008=j %then cpt&i.&j.=%EVAL(cpt&i.&j.+1);
%if var2008=i and	var2009=j %then cpt&i.&j.=%EVAL(cpt&i.&j.+1);
%if var2009=i and	var2010=j %then cpt&i.&j.=%EVAL(cpt&i.&j.+1);	
%END;
%END;
RUN;
%MEND test;
%test;

Merci pour votre aide,

Wacker.

[olivier.decourt]

Bonjour.
Ce sont des IF et pas des %IF. Et les %EVAL ne sont pas nécessaires.
Pour faire court (il y a pas mal de posts sur le sujet), un %IF c'est quand la condition porte sur la valeur d'une macro-variable, et qu'on ne veut l'évaluer qu'une fois. Si la condition doit être évaluée à chaque observation, c'est un IF normal.
J'écrirais donc IF var2004=&i AND var2005=&j then cpt&i.&j.=cpt&i.&j.+1 ;

[hossward]

Bonjour Wacker,
Je crois qu’un array à deux dimensions peut faire l’affaire et remplacer ta macro qui m’a au moins aidé à concevoir le problème et à réaliser le code que je te propose ici :
Tu peux changer le nombre des éléments des deux arrays selon le nombre des variables et les valeurs souhaitées pour la comparaison.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
DATA table1 ;
input nom $ var2004 var2005 var2006 var2007 ;
cards ;
etu1 1 2 2 2
etu2 1 2 3 4
etu3 1 3 1 2
run ;
 
data table2 (keep=cpt:) ;
set table1 end=fin ;
array etu(*) var2004-var2007 ; 
array cpt(4,4) (16*0); /* initialisation à zéro la matrice compteur */
 
do i=1 to 3 ;    /* Nombre des variables moins 1  */ 
	do m=1 to 4 ;
	   do n=1 to 4 ;
		if etu(i)=m and etu(i+1)=n then cpt(m,n)=cpt(m,n)+1 ; 	
		end ;
	end ;
end ;  
if fin then output ;
run ;	  
 
/* Construction du tableau croisé */
data table3	(keep=val: nobs) ;
retain nobs val: ;
set table2 ;
array cpt(4,4) ;
array val(4) ;
  do m=1 to 4;
    do n=1 to 4;
		nobs=m ; 
        val(n)=cpt(m,n) ;	 
	end ;  
	output ;
  end ;
run ;

Cordialement
Ward

[wacker26]

Merci énormément hossward, ça marche parfaitement et ça va au-delà de ce que j'espérais faire.
Cela dit, j'avoue ne pas comprendre toutes les subtilités des array et matrices sur SAS, aurais-tu un cours (*.pdf) expliquant bien tout cela? Parce que l'étape suivante est de calculer la norme (à définir, par exemple la somme des cases de la matrice) de ce tableau.

Merci encore !

Bonne journée à toi,

Wacker.