Discussion :

[torjancss]

Bonjour,


je suis un étudiant , j'ai un problème dans le quel je cherche énormément une solution , j'ai beaucoup essayé mais j'ai pas pu le résoudre et je souhaite que vous m'aidiez a le résoudre
alors je veux un programme XL qui permet de faire tout les possibilités (combinaisons ) possibles avec les lettres a,b,c dans des chaines de caractère composé par 13 éléments (les éléments sont a, b et c , c tt )
le résultat alors 2197 chaines de caractères de 13 lettres composé par ces 3 lettres seulement par exemple :
aaaaaaaaaaaaa
aaabbbcccabcb
.
.
.
.
.
.
ainsi de suite .
NB : on aura 2197 chaines de caractères
Merci d'avance

[papouclo]

Bonjour,
Avant de penser à écrire toutes les chaines de 13 caractères composées des 3 caractères a, b et c, il faut peut être recalculer correctement le nombre de chaines possibles.
J'ai bien peur qu'il ne soit pas égal à 13³ comme vous le croyez mais à 3¹³ c'est à dire 1 594 323 au lieu de 2 197.
Ce qui peut faire hésiter avant de se lancer dans l'écriture de ces chaines, d'autant plus que le nombre de réponses dépasse la capacité en lignes d'une feuille
donc que l'on ne peut pas chercher une méthode les écrivant une sous l'autre.

Si vraiment on veut se lancer dans l'aventure , une méthode possible :
d'abord écrire les chaines cherchées sur 3 colonnes : dans une colonne toutes les chaines commençant par "a", dans la suivante toutes les chaines commençant par "b",
dans la dernière toutes les chaines commençant par "c".
Ce qui revient à chercher toutes les chaines de 12 caractères choisis parmi les trois caractères a, b, c soit 3¹² ou 531 441 chaines.
On a le choix entre 3 caractères (je désignerai le nombre 3 par choix pour généraliser la formule) à répartir sur 12 emplacements (je désignerai le nombre 12 par emplacements ).
Ecrire en A1 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= QUOTIENT ( MOD(LIGNE()-1 ; choix ^ (emplacements - COLONNE() + 1) ) ; choix ^ (emplacements-COLONNE() ) ) + 1

Recopier cette formule vers la droite jusqu'à la 12 ème colonne donc la cellule L1.
En N1, écrire la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="a" & SUBSTITUE(SUBSTITUE(SUBSTITUE($A1&$B1&$C1&$D1&$E1&$F1&$G1&$H1&$I1&$J1&$K1&$L1;"1";"a");"2";"b");"3";"c")

en P1, la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="b" & SUBSTITUE(SUBSTITUE(SUBSTITUE($A1&$B1&$C1&$D1&$E1&$F1&$G1&$H1&$I1&$J1&$K1&$L1;"1";"a");"2";"b");"3";"c")

en R1, la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="c" & SUBSTITUE(SUBSTITUE(SUBSTITUE($A1&$B1&$C1&$D1&$E1&$F1&$G1&$H1&$I1&$J1&$K1&$L1;"1";"a");"2";"b");"3";"c")

Il ne reste plus qu' à sélectionner la plage A1 : R1 et à recopier vers le bas jusqu'à la ligne 531 441.
A moins d'écrire une procédure recopiant les formules jusqu'à la dernier ligne, il faut certainement beaucoup de patience.
En extrapolant ce que j'ai obtenu avec un certain nombre de lignes, cela doit donner un dossier d'une soixantaine de MO.
Bon courage!
Cordialement
Claude