Discussion :

[lolo1960]

Bonsoir,
Avant de poser mon problème j'aimerais dire bravo pour ce site. Je ne suis pas une pro de l'informatique mais on y trouve des choses incroyables,
Alors voici, avec des copines on a commencé une activité qui au départ était un simple jeu mais à présent on veut en faire quelque chose de plus équitable. Je m'explique:
Dans un fichier Access, j'ai trois tables: Membre, coupures et À payer.
La table membre contient les infos de chacune d'entre-nous (mon, date d'adhésion au groupe, nombre de coupure en euros versés, et un champ vide pour les coupures à payer).
La table coupures contient les coupures d'euros ainsi que le nombre dont nous avons besoin pour notre petite caisse.
La table À payer doit contenir le nombre de coupures à payer par les celles d'entre-nous qui auront été choisies au hasard


Ma question est la suivante: existe-t-il un moyen de répartir de façon aléatoire le nombre de coupure du champ "Nombre à répartir" de la table "Coupures" en fonction du type de coupure du champ "Coupure" à nos membres et d'afficher le résultat au champ "Coupures à payer" de la table à payer?
Par exemple, il faut répartir 8 coupures de 5 euros entre les membres qui ont des coupures de 5 (Nadia possède 6 et Jasmine 9) de façon aléatoire.

Je mets un fichier en attaché

Merci de votre aide.

[ClaudeLELOUP]

Bonjour et bienvenues aux copines,


Ce que je comprends :
- il y a des participantes : Nadia, Suzi… ;
- qui ont proposé : Nadia 6 coupures de 5 €, Suzy 8 coupures de 10 € ;
- à un moment donné on décide que les participantes doivent ensemble fournir : 8 coupures de 5 €, 10 coupures de 10 €, 12 coupures de 20 €… ;
- le défi : comment choisir au hasard, qui va payer.
Est-ce correct ?

[lolo1960]

Salut Claude,
Tu as bien résumé mon problème à une exception:

- il y a des participantes : Nadia, Suzi… (dont le nombre varie en cas de nouvelles ou de départ)
- Nous avons besoin de: 8 coupures de 5; 10 de 10; 12 de 20; 6 de 50 .... et seules les coupures qui sont disponibles au comptes de chaque membre peuvent être demandées.
- Ainsi : Nadia possède 6 coupures de 5 €, Suzy 8 coupures de 10 € , Hilda 32 de 20; Jasmine 9 de 5; Lolita 14 de 10
- à un moment donné on décide que les participantes doivent ensemble fournir : 8 coupures de 5 €, 10 coupures de 10 €, 12 coupures de 20 €… ;
- le défi : comment choisir au hasard, qui va payer de sorte que si par exemple c'est en cliquant sur un bouton: chaque clic produit une répartition différente pour que nul ne se sente choisie volontairement.

Merci.

[ClaudeLELOUP]

Bonjour,

Voici une proposition. Jette un œil sur les tables : j’ai un peu modifié pas de caractères spéciaux.

Explication du processus

L’algorithme consiste à considérer les demandes de coupures une à une.
Pour chacune d’elles, on crée une table provisoire (tInterne) contenant
- l’identification du participant ;
- ce qu’il propose pour cette coupure (« Offre ») ;
- le champ destiné à enregistrer ce que le sort lui demandera de livrer (« Doit »).

De deux choses l’une :
• si l’offre est trop faible pour la demande, chaque participant livre son offre et on édite un message d’avertissement : le champ « Doit » = le champ « Offre » ;
• si l’offre excède la demande, on déclenche alors un processus itératif qui va déterminer de manière aléatoire une ligne de la table. Dans la ligne tirée au sort on ajoute 1 à « Doit » pour autant que « Doit » ne dépasse pas « Offre ».
Le processus itératif s’arrête lorsque la somme des « Doit » a atteint le nombre de coupures demandées.
Les « Doit » de cette table provisoire sont alors reportés dans la colonne « APayer » de la table Membres et on traite la demande suivante.

Le code à déclencher

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
 Option Compare Database
Option Explicit
 
 
Public Sub Repartition()
Dim rsDemande As Recordset
Dim sSql As String
  DoCmd.SetWarnings False
  'Réinitialiser de la colonne APayer
  DoCmd.RunSQL "UPDATE Membres SET Membres.APayer = 0;"
  'lire les demandes une à une
  Set rsDemande = CurrentDb.OpenRecordset("SELECT Coupures.* FROM Coupures WHERE (((Coupures.NombreArepartir)>0));")
  Do Until rsDemande.EOF
    'créer la structure tInterne
    sSql = "SELECT Coupures.Coupures AS coupure, Coupures.NombreArepartir AS Demande, " _
           & "Membres.MembresPK AS Membres, Membres.NombreParCoupure AS Offre, 0 AS Doit " _
           & "INTO tInterne " _
           & "FROM Coupures INNER JOIN Membres ON Coupures.Coupures = Membres.Coupures " _
           & "WHERE (((Coupures.Coupures)=""" & rsDemande("coupures") & """));"
    DoCmd.RunSQL sSql
    'Y a-t-il trop peu (ou juste assez) d'offres pour cette coupure ? => pas de tirage au sort
    If Nz(DSum("Offre", "tInterne"), 0) <= Nz(rsDemande("NombreArepartir"), 0) Then
         MsgBox "Pas de tirage au sort pour les coupures de " & rsDemande("coupures") & " € !" & vbLf & vbLf _
           & "Demande : " & Nz(rsDemande("NombreArepartir"), 0) _
           & " ; Offre : " & Nz(DSum("Offre", "tInterne"), 0) & "."
         DoCmd.RunSQL "UPDATE tInterne SET tInterne.Doit = [Offre];"
         GoTo MajApayer
    End If
    'Tirage au sort
    Call TirageAuSort
MajApayer:
    DoCmd.RunSQL "UPDATE tInterne INNER JOIN Membres " _
                  & "ON (tInterne.Membres = Membres.MembresPK) AND (tInterne.coupure = Membres.Coupures) " _
                  & "SET Membres.APayer = [Doit];"
    'CoupureSuivante
    rsDemande.MoveNext
  Loop
  DoCmd.SetWarnings True
  'libérer
  rsDemande.Close
  Set rsDemande = Nothing
DoCmd.DeleteObject acTable, "tInterne"
  'Montrer résultat
  DoCmd.OpenQuery "rResultats"
End Sub

Qui appelle à son tour :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Public Sub TirageAuSort()
  Dim rstInterne As Recordset
  Dim NbreCandidats As Integer
  Dim NumElu As Integer
  NbreCandidats = DCount("*", "tInterne")
 
  Set rstInterne = CurrentDb.OpenRecordset("tInterne")
  Do While DSum("Doit", "tInterne") < rstInterne("Demande")
    'Tirage
    Randomize
    NumElu = Int((NbreCandidats * Rnd) + 1)
    'Mise à jour de tInterne
    rstInterne.MoveFirst
    rstInterne.Move (NumElu - 1)
    If rstInterne("Doit") < rstInterne("Offre") Then
        rstInterne.Edit
        rstInterne("Doit") = rstInterne("Doit") + 1
        rstInterne.Update
    End If
   Loop
 
 
  rstInterne.Close
  Set rstInterne = Nothing
 
End Sub

Explication du code

Sub Repartition
Ligne 6
On met à zéro la colonne « APayer » de Membres. (Elle contient les résultats du précédent tirage.)
C’est l’équivalent de



Ligne 8
On crée un recordset de la table Coupures pour les demandes supérieures à zéro.
Que nous allons lire enregistrement par enregistrement lignes 9 à 33.

Lignes 11 à 16
On crée une table tInterne pour la 1re coupure, c’est l’équivalent de cette requête



À ce moment, le modèle contient cette table :




Lignes 17 à 23
S’il s’avère que l’offre est inférieure à la demande, on envoie un message :



Et on exécute cette requête :



Ligne 25 et 26
Si l’offre excède la demande, on tire au sort, voir commentaires de sub TirageAuSort.

Ligne 28 à 30
À l’issue des deux cas, on met la table Membres à jour :




Sub TirageAuSort
Ligne 5
On compte le nombre de lignes de tInterne nbre de candidats à tirer au sort.
Lignes 8 à 20
On lance une boucle qui sera interrompue lorsque la somme des « Doit » aura atteint le nombre de coupures demandé.
Lignes 10 et 11
On tire au sort un nombre entre 1 et le nombre de lignes de tInterne.
Pour vous documenter sur le fonctionnement de Rnd et Randomize, voyez :
http://office.microsoft.com/fr-be/ac...001228901.aspx
Lignes 13 à 19
On se positionne sur la ligne de tInterne qui a été tirée au sort et si « Doit » est encore inférieur à « Offre », on incrémente « Doit » d’une unité.


La base de données qui m’a servi à mettre au point est ici.
http://claudeleloup.developpez.com/F...140217Lolo.mdb

[lolo1960]

Merci Claude pour ce coup de maître.
Je dois t'avouer que je n'avais encore jamais rien vu d'aussi complexe. Alors depuis ton post, je fais l'effort d'analyser le processus pour voir si le résultat est celui attendu. J'en profite ainsi pour comprendre le mécanisme.
Je te reviens bientôt.

Merci encore.

[lolo1960]

Bonsoir Claude,
D'abord, je vais commencer par répondre à la question "est-ce que c'est ce que je souhaitais" par OUI.
Ensuite, pour être certaine de comprendre non pas tous ces codes (car je crois qu'il faut un certain temps pour arriver à ce niveau), mais la logique en arrière plan, j'aimerais te poser trois questions:
1- lorsque tu dans ton post "pas de caractères spéciaux" cela veut-il dire qu'en cas d'un caractère de ce type ça ne marchera pas?
2- Dans la requete "rResultats", que signifie "CEnt" dans "Coupure: CEnt([Coupures])"?
3- Lorsque le résultat de la répartition aléatoire s'affiche, est-il possible qu'un sous-total s'affiche par bloc de coupures comme sur la capture jointe? L'idée ici étant de faciliter les comptes.

D'avance merci pour tes explications.

[ClaudeLELOUP]

Bonjour,

1- lorsque tu dans ton post "pas de caractères spéciaux" cela veut-il dire qu'en cas d'un caractère de ce type ça ne marchera pas?

Ça pourrait certainement marcher, mais c’est une bonne habitude que de choisir de nommer les objets et contrôles avec des noms qui ne contiennent pas de caractères spéciaux.
Jette un œil sur cet avis d’un « pro » : Descriptif des conventions typographiques du code Visual Basic de Jean-Philippe AMBROSINO.

2- Dans la requete "rResultats", que signifie "CEnt" dans "Coupure: CEnt([Coupures])"?

CEnt() est la graphie française de la fonction CInt().
Elle convertit un nombre entier de type Texte en sa valeur numérique.
Je voulais trier les coupures par ordre croissant et je me suis rendu compte (trop tard) que tu avais le type « Texte » dans Coupure. Le tri donnait ceci :
10
100
20
200
5
50
500.
Il aurait été plus simple et plus sain de changer le type dans la table… mais cela impliquait des modifs dans le code et j’ai eu la flemme…

3- Lorsque le résultat de la répartition aléatoire s'affiche, est-il possible qu'un sous-total s'affiche par bloc de coupures comme sur la capture jointe? L'idée ici étant de faciliter les comptes.

Je te reviens :
- à la réflexion, on peut simplifier l’algorithme et se passer de tInterne ;
- je fignolerai un peu le formulaire pour y afficher le résultat : tu as oublié de joindre la capture, mais je crois comprendre.

[lolo1960]

Salut Claude,

Quand je pense avoir essayé deux fois de joindre cette capture, c'est à n'y rien comprendre. Mais bon, finalement je crois qu'il n'est pas toujours vrai de dire que les femmes peuvent faire plusieurs choses en même temps.
Merci pour tes explications qui me permette d'en apprendre un peu plus.
Je te mets donc la capture, à bientôt.

[ClaudeLELOUP]

Voici une nouvelle version sans recours à une table intermédiaire (tInterne) et totaux dans les résultats (un état au lieu d'une requête).

Le code est plus concis :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
Option Compare Database
Option Explicit
 
 
Public Sub Repartition()
  Dim rsDemande As Recordset, rsLaCoupure As Recordset
  Dim NbreCandidats As Integer
  Dim NumElu As Integer
  DoCmd.SetWarnings False
  'Réinitialiser de la colonne APayer
  DoCmd.RunSQL "UPDATE Membres SET Membres.APayer = 0;"
  'lire les demandes une à une
  Set rsDemande = CurrentDb.OpenRecordset("SELECT Coupures.* FROM Coupures WHERE (((Coupures.NombreArepartir)>0));")
  Do Until rsDemande.EOF
    'Créer un recordset avec cette coupure
    Set rsLaCoupure = CurrentDb.OpenRecordset("SELECT Nom_joueuse, Coupures, NombreParCoupure, APayer " _
                                                 & "FROM Membres " _
                                                 & "WHERE Coupures=" & rsDemande("coupures") & ";")
    'Y a-t-il trop peu (ou juste assez) d'offres pour cette coupure ? => pas de tirage au sort
    If DSum("NombreParCoupure", "Membres", "Coupures=" & rsDemande("coupures")) _
           <= rsDemande("NombreArepartir") Then
        Do While Not rsLaCoupure.EOF
          rsLaCoupure.Edit
          rsLaCoupure("APayer") = rsLaCoupure("NombreParCoupure")
          rsLaCoupure.Update
          rsLaCoupure.MoveNext
        Loop
        MsgBox "Pas de tirage au sort pour les coupures de " & rsDemande("coupures") & " € !" & vbLf _
                      & "Demande : " & rsDemande("NombreArepartir") & " ;" _
                      & " Offre   : " & DSum("NombreParCoupure", "Membres", "Coupures=" & rsDemande("coupures")) & "."
        GoTo CoupureSuivante
    End If
 
    'Tirage au sort
    NbreCandidats = DCount("*", "Membres", "Coupures=" & rsDemande("coupures"))
    Do While DSum("APayer", "Membres", "Coupures=" & rsDemande("coupures")) _
           < rsDemande("NombreArepartir")
      Randomize
      NumElu = Int((NbreCandidats * Rnd) + 1)
      'Mise à jour de tInterne
      rsLaCoupure.MoveFirst
      rsLaCoupure.Move (NumElu - 1)
      If rsLaCoupure("APayer") < rsLaCoupure("NombreParCoupure") Then
          rsLaCoupure.Edit
          rsLaCoupure("APayer") = rsLaCoupure("APayer") + 1
          rsLaCoupure.Update
      End If
    Loop
CoupureSuivante:
    rsDemande.MoveNext
  Loop
  DoCmd.SetWarnings True
  'libérer
  rsDemande.Close
  Set rsDemande = Nothing
  rsLaCoupure.Close
  Set rsLaCoupure = Nothing
End Sub

http://claudeleloup.developpez.com/F...140219Lolo.mdb

[lolo1960]

Salut Claude,

Ce modèle avec les totaux est parfait. Je sais qu'en principe je devrais cliquer sur RÉSOLU au bas de l'écran mais avant j'ai quelques questions pour en apprendre un peu plus:
- Était-il possible d'ajouter l'état "eResultats" à lapremière version? Si oui, dis-moi comment afin que je me pratique.
- Existe-t-il une liste des fonctions Access avec leurs graphie comme pour CEnt?
- Quel est le meilleurs point de départ pour apprendre Access, puis le VAB y associé (ce forum est déjà une première école je l'admet)

Merci encore.

[ClaudeLELOUP]

- Était-il possible d'ajouter l'état "eResultats" à la première version? Si oui, dis-moi comment afin que je me pratique.

Oui, bien sûr, il suffit d’utiliser un état (eResultats de la 2e version) au lieu d’une requête (rResultats).

Donc tu ajoutes l’état eResultats dans la 1re version et dans le code, tu remplaces la ligne 44 par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DoCmd.OpenReport "eResultats", acViewPreview

Note l’ordre des coupures perturbé ! (Coupures de type Texte.)

- Existe-t-il une liste des fonctions Access avec leur graphie comme pour CEnt ?

Ma référence, c’est le tutoriel de Philippe JOCHMANS Les fonctions de domaine.

Quel est le meilleur point de départ pour apprendre Access, puis le VAB y associé (ce forum est déjà une première école je l'admets)

En l'utilisant !
Mais d'abord avec des cas simples : il serait fortement exagéré de qualifier de « simple », ta question du tirage au sort !

Personnellement j’ai appris sur le tas par la méthode essais/erreurs, en posant des questions sur ce forum et en lisant la FAQ et des tutoriels.



D'une manière générale, pour se documenter sur les propriétés d'un formulaire ou d'un état, ou de leurs contrôles :
- afficher l'objet en mode construction ;
- cliquer sur la propriété => elle se met en surbrillance ;
- enfoncer la touche <F1>
=> l'aide Access s'ouvre à la bonne page.
De même dans le code, placer le curseur de la souris et enfoncer F1.
On peut aussi :
• ouvrir l'aide <F1>, choisir l'onglet « Aide intuitive » et suivre les instructions ;
• ouvrir la fenêtre d'exécution (<Ctrl> + G), saisir un mot-clé, y placer le curseur de la souris et enfoncer F1.


Sur ce, bonne journée : tu as de quoi meubler tes loisirs... si tu as la chance d'en avoir : moi, maintenant, c'est dimanche tous les jours.

Content de t'avoir croisée.

[lolo1960]

Bonjour Claude,

Rien à ajouter sinon que "la connaissance s'acquiert partout".
Alors je vais mettre toutes ces sources d'infos à profit.

MERCI!!!!!!!!!!