Discussion :

[Babzoo]

Bonjour,

Je débute en programation SAS et je me heurte déjà à un soucis. Je cherches à determiner le nombre de d'appel reçu en parallèle sur une minute.
Pour cela je me suis créé un table Nb_Ap_Int avec les creneaux de 1 minutes sur une journée et nb_appel initialisé à 0.

Hi.........................Hs......................Nb_appel
16MAR12:00:00:00 16MAR12:00:00:59 0
16MAR12:00:01:00 16MAR12:00:01:59 0
16MAR12:00:02:00 16MAR12:00:02:59 0
16MAR12:00:03:00 16MAR12:00:03:59 0
16MAR12:00:04:00 16MAR12:00:04:59 0
16MAR12:00:05:00 16MAR12:00:05:59 0
16MAR12:00:06:00 16MAR12:00:06:59 0
(...)

la table donnant les détail des appel est APPEL_T avec entre autre une Hdebut et Hfin des appel :

Hdebut.................Hfin
16MAR12:07:39:02 16MAR12:07:42:20
16MAR12:07:38:31 16MAR12:07:38:36
16MAR12:07:38:42 16MAR12:07:38:49
16MAR12:07:30:33 16MAR12:07:37:51
16MAR12:07:37:51 16MAR12:07:37:52
16MAR12:07:37:52 16MAR12:07:37:53
16MAR12:07:37:53 16MAR12:07:38:06
16MAR12:07:38:06 16MAR12:07:38:26
(...)


Je veux remplir Nb_Ap_Int avec le nombre de traitement qui tournent pendant la minute testée. En SQL ça donne ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
proc sql;
UPDATE Nb_Ap_Int 
SET Nb_appel = (SELECT count(*) 
FROM APPEL_T 
WHERE APPEL_T.Hdebut < Nb_Ap_Int.Hs and APPEL_T.Hfin> Nb_Ap_Int.Hi);
quit;

Sauf qu'il faut que je l'écrive en Etape data et je sais pas du tout comment modifier une table en lisant une autre ...
L'idée c'est de lire chaque ligne de APPEL_T et de mettre nb_appel = nb_appel +1 à tous les intervals pendant lequel l'appel dure.

Merci de votre aide ! Et bonne journée

[sasadm]

Voilà comment j'envisagerais de résoudre le problème: Plutôt que de partir de la minute et de compter les appels, on part de l'appel et on en extrait les minutes occupées par la durée de l'appel. Ensuite, il n'y a plus qu'à compter chaque minute par une procédure SQL ou une étape data. Et enfin boucher les trous par les minutes vides (facile).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
data appels;
informat Hdebut Hfin datetime16.;
format Hdebut Hfin  datetime16.   ;
input Hdebut $ Hfin $;
cards;
16MAR12:07:39:02 16MAR12:07:42:20
16MAR12:07:38:31 16MAR12:07:38:36
16MAR12:07:38:42 16MAR12:07:38:49
16MAR12:07:30:33 16MAR12:07:37:51
16MAR12:07:37:51 16MAR12:07:37:52
16MAR12:07:37:52 16MAR12:07:37:53
16MAR12:07:37:53 16MAR12:07:38:06
16MAR12:07:38:06 16MAR12:07:38:26
;
run;
 
data comptage;
format minutes datetime16.;
set appels;
/* determination de la minute du début de l'appel  */
minutes= input(cats(put(Hdebut ,  datetime13.), ':00'), datetime16.) ;
 
/* on compte 1 appel pour cette minute (facultatif)  */
n=1;
 
 
/* incrementation du temps minute par minute jusqu'à la fin de l'appel */
do while (minutes <= Hfin);
	output; /* on extrait chaque minute de la duree de l'appel */
	minutes=minutes+60; /* incrementation */
end;
 
run;
 
 
/* on somme les appels (les 1) par minute */
proc sql;
	select minutes, sum(n) as nb_appel from comptage
	group by minutes;
run;

[Babzoo]

Merci de la réponse je vais tester ça ce soir. Je n'avais pas du tout songé à cette solution

[hossward]

il faut que je l'écrive en Etape data et je sais pas du tout comment modifier une table en lisant une autre .

Voici une solution pour ta requête en étape data :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
data compar (keep=Hi Hs Nb_appel) ;
set Nb_Ap_Int  ;
j=0 ;
do i=1 to nbs;
j+1 ;
set APPEL_T nobs=nbs point=i ;	
if Hdebut < Hs AND Hfin> Hi then Nb_appel=Nb_appel+1 ;
if j=nbs then output ;
end;
run;

Bon courage
Ward

[Babzoo]

Vos deux solutions fonctionnent parfaitement, donc merci beaucoup !
Bonne journée