Discussion :

[devilsnake88]

Bonjour,
J'ai créé un script basic qui lis un fichier texte dans lequel se trouve le nom d'ordinateurs et mon script me retourne l'adresse IP correspondante.

Malheureusement j'ai un soucis:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
@echo off
setlocal enabledelayedexpansion

for /f "tokens=* delims= " %%a in (test.txt) do (
	for /f "delims=[] tokens=2" %%b in ('ping %%a -n 1 -w 100 -4 -l 8 /a') do (
	echo %%a - %%b
	)
)
pause

Ceci me retourne bien: "%host% - %ip%".
Mais si je veux faire un SET ip=%%b puis echo %ip%, plus rien ne fonctionne...

J'ai tenté énormément de choses mais j'ne suis arrivé à un point ou j'ai besoin d'assistance ^^

Merci pour votre aide

[sachadee]

Salut,

Un exemple de ton fichier texte, serait utile.

[devilsnake88]

Ah désolé, euh rien de plus simple c'est:

nompc1
nompc2
nompc3
...

[sachadee]

Ceçi doit fonctionner sans problème :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
@echo off&cls

setlocal EnableDelayedExpansion

for /f "delims=" %%a in ('type test.txt') do (
	for /f "delims=[] tokens=2" %%b in ('ping %%a -n 1 -w 100 -4 -l 8 /a') do (
	set $Host=%%a
        set $IP=%%b
        echo !$Host! - !$IP!
	)
)

[devilsnake88]

En effet ça fonctionne très bien!

Merci à toi, ô grand maître du Batch xD

[devilsnake88]

Une dernière petite chose, dans ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off&cls
setlocal EnableDelayedExpansion

for /f "delims=" %%a in ('type test.txt') do (
	set /a N+=1
	set v!N!=%%a

	for /f "delims=[] tokens=2" %%b in ('ping %%a -n 1 -w 100 -4 -l 8 /a') do (
		set $Host=%%a
		set $IP=%%b
		if not errorlevel 1 (
			echo !N!: !$Host! - !$IP!
		)
		if errorlevel 1 (
			echo !N!: !$Host! - ETEIND
		)
	)
)
pause

Comment faire pour que "errorlevel" (ou une méthode pour vérifier que le ping de la machine répond bien) fonctionne?

J'ai modifié pour cet exemple "monpc2" en "monpc22" (qui n'existe pas) pour avoir un message du style "monPC22 est eteind".

Désolé pour le multi requests

[sachadee]

Essaye comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
@echo off&cls
setlocal EnableDelayedExpansion

for /f "delims=" %%a in ('type test.txt') do (
	set /a N+=1
	set v!N!=%%a

	for /f "delims=[] tokens=2" %%b in ('ping %%a -n 1 -w 100 -4 -l 8 /a') do (
		set $Host=%%a
		set $IP=%%b
		if %errorlevel% equ 0 (
			echo !N!: !$Host! - !$IP!
		) else (
			echo !N!: !$Host! - ETEIND
		)
	)
)
pause

[devilsnake88]

Ca me retourne juste:

monpc1
monpc3
...

Ce que je voudrais (je le redis pour éviter la confusion ^^):

monpc1
monpc2- ETEIND
monpc3
...

Je sais que si mon ping ne se trouve pas dans un for ... in(), errorlevel fonctionne mais si je fais ça, je ne peux pas faire mon ping pour chaques lignes de mon fichier .txt

[sachadee]

OK, j'ai compris ton problème en fait il n'entre pas dans la boucle, donc le test if n'est pas executé (il est donc inutil).

Tu peux setter $host à une valeur bidon (rien) et en sortie de boucle tu test cette valeur. Si elle est toujours à rien en sortie de boucle alors tu affiche éteind

EDIT :

Ou plus propre, on annule $host et on test si elle existe en sortie de boucle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
@echo off&cls
setlocal EnableDelayedExpansion

for /f "delims=" %%a in ('type sacha.txt') do (
	set /a N+=1
	set v!N!=%%a
        set $Host=
	for /f "delims=[] tokens=2" %%b in ('ping %%a -n 1 -w 100 -4 -l 8 /a') do (
		set $Host=%%a
		set $IP=%%b
		echo !N!: !$Host! - !$IP!)
if not defined $host echo %%a eteind)

Voilà l'idée

[devilsnake88]

Ah ouais c'est malin d'éditer la valeur ^^
Je testerais demain (au travail).
En tout cas merci à toi


EDIT:
@sachadee: Un très grand merci à toi!
Ça fonctionne super bien ^^