Discussion :

[pomolo11]

Bonjour,

J'ai une table SAS avec des noms de variables non significatives, comme par exemple l_2011, l_2012...
Et j'ai une autre table SAS qui fait correspondre à chacune de ces variables un label.

Première table : donnees
l_2011 l_2012 l_2013

15 25 10
33 20 14

Deuxième table : metadonnees
Nom_colonne label
l_2011 nombre_licences_2011
l_2012 nombre_licences_2012
l_2013 nombre_licences_2013

Donc je veux avoir dans la première table quelque chose comme :
nombre_licences_2011 nombre_licences_2012 nombre_licences_2013
15 25 10
33 20 14

Comment je peux procéder s'il vous plait ? Je suis coincé car je débute en SAS, merci

[lelensois16]

Bjr,

Possible via un proc transpose double et un proc sql

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
data donnees ; 
input  l_2011 l_2012 l_2013 ; 
cards ; 
15 25 10
33 20 14
;
run ; 
 
data metadonnees ; 
input Nom_colonne $ label $20. ; 
cards ; 
l_2011 nombre_licences_2011
l_2012 nombre_licences_2012
l_2013 nombre_licences_2013
;
run ; 
 
proc transpose data = donnees out = donnees_tr ; run ; 
 
proc sql ; 
create table fusion as 
select label , col1 , col2
from donnees_tr left join metadonnees on donnees_tr._NAME_ = metadonnees.Nom_Colonne ; 
run ; 
 
proc transpose data = fusion out = table_finale (drop=_NAME_); 
id label ; 
run ;

Cdt et bon courage

[pomolo11]

Mercii je ne vais plus être perdu dans mes tables

[olivier.decourt]

Bonjour.
J'essaye de devancer Géraldine avant qu'elle ne fasse la promo du CALL EXECUTE. C'est exactement ce dont tu as besoin, surtout si la table de données est grosse, car la solution du Lensois nécessite de la travailler pas mal.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
DATA _NULL_ ;
  SET work.metadonnees END=fin ;
  IF _N_=1 THEN DO ;
    CALL EXECUTE ("PROC DATASETS LIB=work NOLIST ;")
    CALL EXECUTE ("MODIFY donnees ;")
    CALL EXECUTE ("LABEL ") ;
  END ;
  CALL EXECUTE(nomColonne !! "=" !! QUOTE(STRIP(label)) ) ;
  IF fin THEN CALL EXECUTE(" ; RUN ; QUIT ;") ;
RUN ;

Bon courage.
Olivier

[JeromeMATHIAS]

Bonsoir,

Il y a quelques semaines ont avait eu un participant qui s'interrogeait sur quand on devait utiliser le macro langage et quand on devait l'éviter.

Je ne suis pas fan de macro langage, et si j'avais participé à la discussion je lui aurais simplement répondu que le macro langage doit rester cantonné autant que possible à la génération de code (implicitement piloté par des méta données).

C'est exactement le cas ici (c'est même le cas type de ce pour quoi à mon sens le macro langage est fait), c'est pourquoi, une fois n'est pas coutume, je propose une solution version "macro" dérivée de la solution d'Olivier (avec quelques bouts de code de lelensois...).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
DATA donnees ; 
input  l_2011 l_2012 l_2013 ; 
cards ; 
15 25 10
33 20 14
;
run ; 
 
DATA metadonnees ; 
input Nom_colonne $ label $20. ; 
cards ; 
l_2011 nombre_licences_2011
l_2012 nombre_licences_2012
l_2013 nombre_licences_2013
;
run ; 
 
PROC SQL;
SELECT Nom_colonne,Label  
INTO :MV_COL SEPARATED BY "," , :MV_LABEL SEPARATED BY ","
FROM metadonnees;
QUIT;
 
%MACRO m;
PROC DATASETS LIB=work NOLIST ;
MODIFY donnees ;
LABEL /**RENAME**/
%DO I=1 %TO %SYSFUNC(COUNTW("&MV_COL",","));
%SYSFUNC(SCAN("&MV_COL",&I,",")) =%SYSFUNC(SCAN("&MV_Label",&I,","))
%END;
;
RUN;
%MEND m;
 
%m;

Edit : Selon ce que tu veux faire tu peux remplacer LABEL par RENAME.

[pomolo11]

Bonsoir,

Vous avez raison, j'ai testé la première procédure sur une grande table, et SAS plantait, j'ai testé par la suite la marco et ça marche bien, merci bien pour votre aide précieuse

[Géraldine_Cade_SAS]

Oui je l'avoue dès que j'ai vu la question j'ai pensé CALL EXECUTE, merci pour la dédicace