Discussion :

[Kikki1970]

Bonjour à toutes et à tous,

Je suis nouveau sur ce forum et j'espère ne pas trop vous ennuyer avec mes demandes.

Voilà, je dois créer dans un formulaire un champs numérique(N_PANIER) incrémentale avec un format "000".
Jusque là, je ne pense pas avoir de pb (NuméroAuto).
Cependant, ce champs avec cette valeur numérique doit avoir une remise à zéro à chaque changement de date.
Et là, je bloque.
N'étant pas fort en VBA, j'espère trouver de l'aide parmi vous .

Bien à vous et merci d'avance

Kikki1970

[PipoWIL]

Oui, lorsque tu crées une table avec au champ autonumber la séquence est crée un fois pour toute. Même si tu détruis tous les records, l'ajout d'un nouveau record n'aura pas le numero 1.

Plusieurs solutions sont possibles.

Soit tu détruis ta table et tu la recrées à chaque fois.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Function testDemo()
Dim strSQL As String
 
strSQL = "DROP TABLE Table1"
On Error Resume Next     'Je sais que ce DROP TABLE peut générer une erreur si la table a déjà été détruite
DoCmd.RunSQL strSQL
On Error GoTo 0          'Si une autre erreur devait survenir, je veux la voir pour débugger.  Après on fera mieux....
 
strSQL = "CREATE TABLE [Table1] (ID Counter constraint ID PRIMARY KEY, Champ1 char (50), Champ2 single null, Champ3 date null)"
DoCmd.RunSQL strSQL
 
End Function

Soit tu gères toi-même le numéro de l'increment en choisissant une simple champ Integer (ou Long si ta table est très grande) que tu remets à zéro en début de processus.

[Rolmaire]

Pour plus de précision, va voir http://support.microsoft.com/kb/812718/fr

[Kikki1970]

Oui, lorsque tu crées une table avec au champ autonumber la séquence est crée un fois pour toute. Même si tu détruis tous les records, l'ajout d'un nouveau record n'aura pas le numero 1.

Plusieurs solutions sont possibles.

Soit tu détruis ta table et tu la recrées à chaque fois.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Function testDemo()
Dim strSQL As String
 
strSQL = "DROP TABLE Table1"
On Error Resume Next     'Je sais que ce DROP TABLE peut générer une erreur si la table a déjà été détruite
DoCmd.RunSQL strSQL
On Error GoTo 0          'Si une autre erreur devait survenir, je veux la voir pour débugger.  Après on fera mieux....
 
strSQL = "CREATE TABLE [Table1] (ID Counter constraint ID PRIMARY KEY, Champ1 char (50), Champ2 single null, Champ3 date null)"
DoCmd.RunSQL strSQL
 
End Function

Soit tu gères toi-même le numéro de l'increment en choisissant une simple champ Integer (ou Long si ta table est très grande) que tu remets à zéro en début de processus.

Bonjour PipoWIL,
Merci pour les infos, mais as tu un exemple.
Etant un novice en VBA, j'ai un peu de mal avec les +1 -1 et Integer je ne connais pas.
Merci d'avance.

Kikki1970

[PipoWIL]

As-tu regardé la solution proposée par Rolmaire ?
Cela devrait te permettre de remettre facilement à zéro un increment dans une table.

En relisant ta question, je vois que tu veux remettre à zéro un increment à chaque fois que la date change et que ton champ doit avoir 3 chiffres.

Voici un exemple que tu peux analyser :

Au départ j'ai une table, Table1, qui a deux champs : un champ "Jour" qui est de format DATE et un champ "MonChamp"avec mes données.
Voici le contenu de ma table :
Jour / MonChamp
-------- -----------
15/02/2011 / pierre
15/03/2012 / Marbre
14/02/2013 / bois
14/02/2013 / platique
14/02/2013 / metal
15/03/2012 / verre
15/12/2013 / cristal
Ce que je te propose, pour que tu voies bien des étapes distinctes, c'est de créer une nouvelle table avec les dates bien classées dans l'ordre puis de créer ton incrément. Tu remqrqueras que la Table2 est crée avec un champ texte 'Compteur' qui est vide.

Voici un code VBA :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
Option Compare Database
Option Explicit
Function increment_avec_date()
'cette fonction crée la table Table2 qui n'est rien d'autre qu'une copie de la Table1 ordonnée
'par Jour Ascendant
'Je parcours la table Table2 du début à la fin et je mets à jour le champ Compteur : pour
'chaque changement de jour, je remets mon compteur à zéro
 
Dim db As DAO.Database
Dim rst As DAO.Recordset
Dim strSQL As String
Dim i As Integer
Dim dtJourPrec As Date
Dim strCompteur As String
 
'Je ne peux pas créer une table qui existe déjà.  Donc pour éviter une erreur, je supprime
'la Table2.
'Si j'essaye de supprimer une table qui n'existe pas, MS Access me donnera une erreur.
'Alors, ici je dis à MS Access, "si tu vois une erreur, reprends à la ligne suivante"
strSQL = "DROP TABLE Table2"
On Error Resume Next     'Je sais que ce DROP TABLE peut générer une erreur si la table a déjà été détruite
DoCmd.RunSQL strSQL
On Error GoTo 0          'Si une autre erreur devait survenir, je veux la voir pour débugger.  Après on fera mieux....
 
 
'Ceci est une "make table query" qui va te créer une table
strSQL = "SELECT Table1.Jour, Table1.MonChamp, '' AS Compteur INTO Table2 FROM Table1 ORDER BY Table1.Jour"
Application.CurrentDb.Execute strSQL        'une autre manière, plus élégante,  d'exécuter le statement SQL
 
 
 
'si tu interromps le code ici, tu peux voir la table2
 
 
Set db = Application.CurrentDb
Set rst = db.OpenRecordset("Table2")
 
dtJourPrec = #1/1/1900#
i = 1
rst.MoveFirst
Do Until rst.EOF
    If rst!jour = dtJourPrec Then
        'si le Jour = jour precedent, alors on continue avec le meme compteur sinon on remet le compteur à zéro
        i = i + 1
    Else
        i = 1
    End If
    dtJourPrec = rst!jour
    strCompteur = Right("000" & i, 3)
    rst.Edit
    rst!Compteur = strCompteur
    rst.Update
 
    rst.MoveNext
Loop
 
Set rst = Nothing
Set db = Nothing
 
'regarde maintenant ta Table2.  Tu peux la mettre facilement dans ton formulaire
 
End Function

[Kikki1970]

Bonjour,
Merci à tout le monde et à PipoWIL pour son code.
Cela fonctionne super.


Bien à vous.

Kikki1970