Discussion :

[Fredche]

Bonjour,

je reviens vers vous aujourd'hui car j'ai un petit soucis avec un SOMMEPROD utilisant une fonction perso.

J'ai récupéré sur le web, merci les contributeurs, une fonction pour trouver le numéro de semaine ISO :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Public Function NumSemISO(ByVal d As Date)
Dim wd As Long
wd = Weekday(d, vbMonday)
NumSemISO = Int((d - DateSerial(Year(d - wd + 4), 1, 1) - wd + 11) / 7)
End Function

Cela fonctionne très bien. Mais je devais utiliser cela sur toute une plage de dates pour intégrer dans le SOMMEPROD. J'ai donc adapté le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Public Function NumSemISOm(ByVal RnDates As Range)
Dim wd As Long
Dim dat As Date
Dim TabDates() As Integer
Dim i As Integer
 
ReDim TabDates(RnDates.Rows.Count)
For i = 0 To UBound(TabDates)
    d = RnDates(i + 1)
    wd = Weekday(d, vbMonday)
    TabDates(i) = Int((d - DateSerial(Year(d - wd + 4), 1, 1) - wd + 11) / 7)
Next i
NumSemISOm = TabDates
 
End Function

Si j'utilise une formule du type MAX(NumSemISOm(ListeDates)), aucun soucis, j'obtiens 52, et MIN, j'obtiens 1.
Je travaille sur deux années, c'est donc d'une logique implacable

Mais si j'essaie de l'utiliser dans un SOMMEPROD avec par exemple *NumSemISOm(ListeDates)=3*, c'est comme si je n'avais rien mis ...

Donc ma question, ce code vous paraît-il correct pour ce que je veux en faire ?

Merci d'avance.

Edit : En fait la fonction marche parfaitement bien. J'ai essayé avec un SOMMEPROD plus basique, tous les résultats sont logiques. Le problème est que j'essaie d'appliquer un critère année et ensuite un critère numéro de semaine sur la même plage de cellules ... ce qui ne fonctionne pas.

J'ai modifié le titre de la discussion, si quelqu'un cherche une fonction telle que celle-ci, il trouvera plus facilement.
Et un si un modo passe par là pour déplacer dans la partie VBA

Par contre, je sens que je vais ouvrir un nouveau sujet avec mon problème de sommeprod avec critère sur une même colonne avant la fin de la journée

Fred

[eriiic]

Bonjour,

j'ai un peu modifié ta fonction :
- il y a plus simple pour le calcul du n° de semaine.
- pour être matricielle une fonction personnalisée doit être As Variant
- comme tu veux une colonne en retour il faut transposer ta matrice

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Public Function NumSemISOm(RnDates As Range) As Variant
    Dim TabDates() As Integer, i As Integer
    ReDim TabDates(1 To RnDates.Rows.Count)
    For i = 1 To UBound(TabDates)
        TabDates(i) = DatePart("ww", RnDates(i), vbMonday, vbFirstFourDays)
    Next i
    NumSemISOm = Application.Transpose(TabDates)
End Function

Teste si c'est mieux...

eric

edit :
Le problème est que j'essaie d'appliquer un critère année...
Tu pourrais faire une autre fonction qui te retourne 201326 pour la 26ème semaine de 2013, d'une pierre 2 coups.

[Fredche]

Bonjour Eric,

merci de t'intéresser à mon cas
Apparemment, cela fonctionne du coup beaucoup mieux dans mon SOMMEPROD. Je pensais que c'était parce que je travaillais sur la même plage de cellules que j'avais des soucis. En fait, je travaille bien sur la même plage, mais sur des matrices différentes, l'une pour les années, l'autre pour les semaines. Donc je ne devrais pas avoir de soucis de ce côté là. Enfin ... si j'ai bien tout compris

Je retiens donc deux choses, Variant pour retourner une matrice, comme c'est d'ailleurs expliqué chez crosoft :http://support.microsoft.com/kb/463444/fr
Et ne pas oublier le transpose pour remettre à la verticale. Un jour je percuterai dès que je créerai ma variable tableau

Par contre, pour le datepart, après avoir lu :
http://support.microsoft.com/?kbid=200299
et
http://blog.developpez.com/philben/p...o_des_semaines
Je vais garder la solution de philben (finalement je n'avais pas cherché la solution si loin que cela).
En effet, comme expliqué sur le site de microsoft et testé à l'instant dans Excel, avec datepart :
28/12/2003 semaine 52
29/12/2003 semaine 53
30/12/2003 semaine 1


Apparemment, ce problème de semaine ISO fait couler beaucoup d'encre (ou de pixels) sur le net ...

Je me rends compte également que je déclarais dans mon code une variable "dat" qui ne me sert pas, et que j'utilisais "d" (déclarée en début de module comme publique). Pas très propre tout ça.

Donc au final, j'ai :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Public Function NumSemISOm(RnDates As Range) As Variant
    Dim TabDates() As Integer, i As Integer, wd As Long
    ReDim TabDates(1 To RnDates.Rows.Count)
    For i = 1 To UBound(TabDates)
        wd = Weekday(RnDates(i), vbMonday)
        TabDates(i) = Int((RnDates(i) - DateSerial(Year(RnDates(i) - wd + 4), 1, 1) - wd + 11) / 7)
    Next i
    NumSemISOm = Application.Transpose(TabDates)
End Function

A première vue, cela fonctionne.

Merci Eric.

Fred

[eriiic]

Je vais garder la solution de philben (finalement je n'avais pas cherché la solution si loin que cela).
En effet, comme expliqué sur le site de microsoft et testé à l'instant dans Excel, avec datepart :
28/12/2003 semaine 52
29/12/2003 semaine 53
30/12/2003 semaine 1

Effectivement, j'avais noté des erreurs sur ces dates :
29/12/1947
31/12/1951
30/12/1963
29/12/1975
31/12/1979
30/12/1991
29/12/2003
31/12/2007
30/12/2019
29/12/2031
31/12/2035
30/12/2047
29/12/2059.
Je modifie mes notes et adpote aussi la solution de Philben... ;-)

eric