Discussion :

[azerty5]

Bonjour à tous,

je viens d'essayer de réaliser un algorithme afin de trouver les champs qui sont affectés à une valeur dans un tableau .

Pour illustre:
colA___col B_Col c_Col d_Col e__col f__col g
_____________________________________
AA_____123______________________________
BB______12______________________________
AA_____15_____________________________
CC_____125___________________________
CC_____4_____________________________
AA_____ 8______________________________
BB_____4______________________________
AA ____9______________________________


J'aimerai que ca me retourne
colA___col B_Col c_Col d_Col e__col f__col g
_____________________________________
AA___123_______________15____8____9
BB____12________________4___________
AA____15________________8____9 ______
CC____125_______________4____________
CC_____4_____________________________
AA____8_________________9____________
BB____4______________________________
AA ___9______________________________
Voici mon algroithme:
Qu'est ce qui cloche?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub test1()
 
Dim i As Integer
Dim j As Integer
Dim k As Integer
Dim nblig As Integer
 
Dim vara As String
Dim varb As String
Dim varc As String
 
nblig = Range(Selection, Selection.End(xlDown)).Rows.Count
 
Range("A1").Select
For i = 1 To nblig
vara = Cells("A" & i).Value
 
        Do While j < nblig
        varb = Cells("A" & j).Value
        varc = Cells("B" & j).Value
            If vara = varb Then
            Cells(i, k).Value = varc
            k = k + 1
            j = j + 1
            Else
            j = j + 1
            End If
            K + 5
        Loop
Next i
 
End Sub

Merci pour votre aide,

azerty5

[gFZT82]

Bonjour,

Avec le tableau en A1:G8

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub test1()
Dim i As Integer, j As Integer, k As Integer, nblig As Integer
Dim vara As String, varb As String, varc As String
    nblig = Range("A1").End(xlDown).Row
    For i = 1 To nblig - 1
        k = 5
        vara = Range("A" & i).Value
        For j = i + 1 To nblig
            varb = Range("A" & j).Value
            varc = Range("B" & j).Value
            If vara = varb Then
                Cells(i, k).Value = varc
                k = k + 1
            End If
        Next j
    Next i
End Sub

Cordialement.

[azerty5]

Ca marche parfaitement Merci beaucoup

Effectivement la boucle While était inefficace puisqueles valeurs n'étaient pas triées par ordre alphabétique.
Pour ma culture perso, Quelle est la différence entre Cells et Range?


Merci encore,
Cordialement

[gFZT82]

Si je te dis que Cells renvoie la collection des cellules de la feuille sous forme d’un objet Range et que l’objet Range représente une cellule, une ligne, une colonne ou une sélection de cellules, cela ne va pas t’avancer.

Aussi, pour faire simple, je vais te répondre dans quel cas utiliser l’un ou l’autre.
Si tu souhaites faire référence à une cellule, tu peux utiliser Cells ou Range.
Exemple :
Range("A1").Value = 15 est équivalent à Cells(1, 1).Value = 15

Par contre, si tu souhaites faire référence à un groupe de cellules, tu dois utiliser Range.
Exemple :
Range("A1 :B10").address ou
Range(Cells(1,1), Cells(10,2)).address ou
Range(Range("A1"), Range("B10")).address
représentent tous l’adresse $A$1:$B$10

Cordialement.