Discussion :

[krol55]

Bonjour,

J'ai une table avec trois colonnes :
-le nom d'une personne
- date de début d'absence
- date de fin d'absence

Je voudrais connaitre pour chaque mois sur une période de deux ans
- le nombre d'agents absents
- le nombre de jours d'absence par mois ...

Est-ce que c'est possible ? Pour le moment je galére avec excel, sur une table de plus de 200000 lignes c'est chaud !

Merci d'avance de votre aide,

K

[JeromeMATHIAS]

Bonjour,

oui bien sûr c'est tout à fait possible.

Tu y a déjà réfléchi ? As tu commencer à rédiger un bout de code ?

[krol55]

Bonjour et merci pour cette première réponse,

Alors, en fait pour l'instant prise par la vitesse, je le fais sous excel !!!
Mais je pense qu'il y a plus rapide, surtout qu'avec prés de 300000 lignes et une couverture de 4 années ca commence à ramer sec.

Pour le nombre de jours, la logique est la suivante :
On prend en entrée une table avec une ligne par contrats :
- Identifiant
- DOTC
- N° contrat
- Date début contrat = D
- Date Fin Contrat = F

Règle logique pour calculer la durée par mois avec
- DM = 1er jour du mois
- FM = dernier jour du mois
Les cas possibles sont :
Nb jours dans le mois D < DM DM <= D <= FM D > FM
F < DM 0 Impossible Impossible
DM <= F <= FM F-DM+1 F-D+1 Impossible
F > FM FM-DM+1 FM-D+1 0
Nous avons donc 4 cas possibles
Si D < DM et
Si DM <= F <= FM alors F-DM+1
Sinon si F > FM alors FM-DM+1
Sinon si DM <= D <= FM et
Si DM <= F <= FM alors F-D+1
Sinon si F > FM alors FM-D+1
...

[sasadm]

Bonjour krol55,

Cela devrait t'aider. L'idée est d'incrementer les mois depuis la date de debut jusqu'a ce que la date de fin soit depassee.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
 
data absence;
 
input 
Identifiant $6.
Date_deb date9.
+1 Date_fin date9.
;
format Date: yymmdd10. ;
 
cards ;
pers1 02jan2012 15feb2013
pers2 03jul2013 05jul2013
;
run; 
 
 
data mois_absence;
/* calcul des mois d'absence: mois_a */
/* calcul du nombre de jour d'absence dans le mois : nb_j_m_a */
 
set absence;
format mois_a yymmn6.;
 
/* variable tecnhnique d'iteration pour recueil des mois d'absence */
iter=0;
 
 
/* mois_a represente le mois d'absence = 1er jour du mois d'absence */
mois_a=intnx('month', Date_deb, 0, 'beginning'); /* initialisation au 1er mois */
 
 
/* recuperation des mois d'absence par bouclage */
do while(  mois_a <= Date_fin  ); /* tant que le mois est inferieur a la date de fin... */
 
	/* calcul du nombre de jours d'absence a l'interieur du mois :
		min et max pour controler les debut et finde la periode 	
	*/
	nb_j_m_a=min(Date_fin, intnx('month', mois_a, 0, 'end'))-max(mois_a, Date_deb)+1; 
 
	output; /* recuperation du mois */
 
	/* incrementation du mois */
	iter=iter+1;
	mois_a=intnx('month', Date_deb, iter,  'beginning');
 
end;
run;

[krol55]

Excellent, merci beaucoup, m'en suis sortie finalement