Discussion :

[sterf]

bonjour messieurs,

Je bute bètement sur un code CDO. l'idée de départ était l'éxécution d' un code qui par appuis sur un bouton envoyait un mail automatique à un groupe de personnes. ça fonctionnait plutot bien jusqu'a ce que j'essaie de complèter le code avec une "msgbox" (censé éviter les erreurs d'envoie). Cette "msgbox" demande simplement une confirmation avant envoie(deux bouton->"oui & cancel).
Mon pb ç'est que je n'arrive pas "imbriquer" les deux codes de façon à ce que lorsque j'appuis sur "oui" la macro soit exécuté et quand je clic sur "cancel", que l'action soit annulée.Soit ça envoie quelque soit le bouton cliqué...
Soit ça envoie sans cliquer; soit ça ne fonctionne carrément plus.

voici mes codes:

Sub Mail_workbook_Outlook_1()
'Working in 2000-2010
'This example send the last saved version of the Activeworkbook
Dim OutApp As Object
Dim OutMail As Object

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)

On Error Resume Next
With OutMail
.To = "monculsurtonnez.com"
.CC = ""
.BCC = ""
.Subject = "Alerte défaut projet MDE détecté FO"
.Body = "bonjour," & vbCrLf _
& vbCrLf _
& "Ceci est un message automatique d'alerte vous prévenant d'un nouveau défaut MDEP détecté par un Front Office. Cliquer sur le lien hypertexte ci dessous pour le visualiser" & vbCrLf _
& vbCrLf _
& "<liens>" _
& vbCrLf _
& "l'équipe front office"

'You can add other files also like this
'.Attachments.Add ("C:\test.txt")
.Send 'or use .Display
End With
On Error GoTo 0

Set OutMail = Nothing
Set OutApp = Nothing
End Sub

ça c'est le code d'origine qui fonctonne par clic sur bouton...

la "msgbox"

Dim monResult as vbMsgBoxResult
monResult = MsgBox("voulez vous difuser l'alerte ?", vbOKCancel, "confir")
if monResult = vbok then

else

end if

Ce qui serait sympa, ç'est que la personne souhaitant m'aider, m'insert la msgbox dans ma macro afin que je puisse comprendre comment ça fonctionne et etre autonome quand le cas ce représentera.

Merci par avance.

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub Mail_workbook_Outlook_1()
'Working in 2000-2010
'This example send the last saved version of the Activeworkbook
Dim OutApp As Object
Dim OutMail As Object
 
If MsgBox("voulez vous difuser l'alerte ?", vbOKCancel, "confir") = vbOK Then
    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
 
    On Error Resume Next
    With OutMail
        .To = "monculsurtonnez.com"
        .CC = ""
        .BCC = ""
        .Subject = "Alerte défaut projet MDE détecté FO"
        .Body = "bonjour," & vbCrLf _
                & vbCrLf _
                & "Ceci est un message automatique d'alerte vous prévenant d'un nouveau défaut MDEP détecté par un Front Office. Cliquer sur le lien hypertexte ci dessous pour le visualiser" & vbCrLf _
                & vbCrLf _
                & "<liens>" _
                & vbCrLf _
                & "l'équipe front office"
 
        'You can add other files also like this
        '.Attachments.Add ("C:\test.txt")
        .Send                                      'or use .Display
    End With
    On Error GoTo 0
    Set OutMail = Nothing
    Set OutApp = Nothing
Else
    MsgBox "Envoi annulé par l'utilisateur"
End If
End Sub