Discussion :

[jerodino]

Bonjour à tous,

Je suis à la recherche d'une solution concernant un de mes projets. J'ai cherché sur la toile une éventuelle solution, sans réels succès...

J'ai défini une plage excel C4 : DD129 comme étant une "zone géographique", chaque cellule étant l'équivalent d'une surface (cad une cellule égale 20mx20m). Je rempli manuellement chaque cellule suivant des codes bien définis : exemple "Y1" ou "Y2" etc...

Ce que j'essaye de faire c'est d'extraire automatiquement dans la colonne DI a partir de la cellule DI4 la liste des cellules contenant la valeur "Y1" (l'adresse). En DJ, la liste des cellules contenant "Y2" etc ...

Ces adresses me permettront après coup de faire le lien avec une autre feuille contenant les codes identifiants de chaque cellule. (structuré similairement C4 : DD129)

Mon niveau en VBA est proche du néant et je n'ai pas trouvé de solutions avec les formules excel

Merci d'avance

jerodino

[PMO2017]

Bonjour,

Une piste avec une fonction personnalisée.
Copiez le code suivant dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
'ADRESSE_VALEUR
'Crée une adresse de(s) cellule(s) sous forme de texte, à partir de
'la valeur de la cellule de recherche spécifiée.
'
'### Syntaxe ###
'ADRESSE(Plage;Recherche;[Num_Absolu])
'
'Plage      est la plage de cellule(s) dont on recherche l'adresse.
'
'Recherche  est la cellule contenant le mot recherché.
'
'Num_Absolu spécifie le type de référence à renvoyer.
'
'--------------------------------------------------
'L 'argument Num_Absolu renvoie ce type de référence
'1 Absolue
'2 Ligne absolue, colonne relative
'3 Ligne relative, colonne absolue
'4 ou omis Relative
 
Function ADRESSE_VALEUR(Plage As Range, Recherche As Range, Optional Num_Absolu As Integer = 4) As String
Dim C As Range
Dim R As Range
For Each C In Plage
  If C = Recherche Then
    If R Is Nothing Then
      Set R = C
    Else
      Set R = Application.Union(R, C)
    End If
  End If
Next C
If Not R Is Nothing Then
  Select Case Num_Absolu
    Case 1
      ADRESSE_VALEUR = R.Address
    Case 2
      ADRESSE_VALEUR = R.Address(True, False)
    Case 3
      ADRESSE_VALEUR = R.Address(False, True)
    Case 4
      ADRESSE_VALEUR = R.Address(False, False)
  End Select
End If
Set R = Nothing
End Function

Les 3 arguments de la fonction sont expliqués au début du code.

Exemple d'utilisation :
1) dans une nouvelle feuille, renseignez la colonne A (à partir de A1) des valeurs recherchées (Y1, Y2, etc)
2) dans la cellule B1 tapez la formule

=ADRESSE_VALEUR('Ma feuille data'!C4:DD129;$A1;4)

Il faudra adapter 'Ma feuille data' du nom de votre feuille contenant les données
3) la formule a le même comportement qu'une formule Excel intégrée, on peut donc la reproduire vers le bas en tirant le coin inférieur gauche avec la souris

En faisant un copier/coller par valeurs, on récupère le texte résultant de la formule.

[jerodino]

Bonjour PMO2017,

Premièrement un grand merci pour la réponse !
J'aime beaucoup le principe de la formule personnalisée, vraiment très intéressant. Tout a bien marché, cela me donne une liste de références et de plages de référence mais par contre dans une seule cellule.
Est-il possible d'obtenir le même résultat mais avec une référence par cellule ? Si 100 cellules rencontrent le critère, j'ai besoin d'avoir 100 cellules résultats.

En tout cas je commence à pleinement réaliser le pouvoir de VBA !

Merci d'avance

jerodino

[PMO2017]

Bonjour,

J'avais cru comprendre que vous vouliez l'intégralité des adresses des cellules afin de pouvoir faire, en VBA, une affectation dans une variable Range de toute la plage concernée.
J'ai mal compris.
*******
On peut contourner avec la démarche manuelle suivante :
1) faire un copier/coller Spécial valeurs et sélectionner la plage obtenue (qui doit être sur une seule colonne)
2) faire menu Données/Convertir
3) dans la boîte de dialogue qui apparaît
- cocher Délimité
- cliquer sur Suivant
- cocher Virgule
- cliquer sur Terminer

Obtenez-vous le résultat désiré ?
Sinon, il faudra oublier la fonction personnalisée et faire un traitement par procédure Sub.
A plus.

[jerodino]

En fait j'avais pensé à ça mais j'ai vraiment besoin d'avoir l'adresse de chacune des cellules, j'ai essayé de bidouiller quelque chose ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Selection()
Dim FL1 As Worksheet, Cell As Range, Plage As Range
Dim R As Range
Dim i As Integer
 
    Set FL1 = Worksheets("235")
    Set R = Range("DG3")
    Set i = 5
    With FL1
        Set Plage = Range("C4 : DD129")
        For Each Cell In Plage
            If Cell = R Then
            Cells(140, i) = Cell.Address(False, False)
            i = i + 1
            End If
        Next
    End With
    Set FL1 = Nothing
    Set Plage = Nothing
End Sub

mais il me met une erreur de définition d'objet

Jerodino

[PMO2017]

Bonjour,

Voici votre code avec quelques remarques

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
'### Sub Selection() 'mieux vaut éviter d'utiliser des mots réservés du VBA
Sub MaSelection()
Dim FL1 As Worksheet, Cell As Range, Plage As Range
Dim R As Range
Dim i As Integer
'---
Set FL1 = Worksheets("235")
Set R = Range("DG3")
'### Set i = 5   'pas bon : Set est utilisé pour l'affection d'un Objet (on le référence dans la variable Objet)
'### i a été déclaré comme Integer (ce n'est donc pas une variable Objet)
i = 5
With FL1
'###  Set Plage = Range("C4D129") 'pas bon : ce n'est pas forcément la plage de FL1 mais celle de la feuille active
  Set Plage = .Range("C4:D129")
  For Each Cell In Plage
    If Cell = R Then
      '### là j'ai un doute, s'il s'agit d'inscrire dans la colonne 140 avec la ligne
      '### qui s'incrémente de 1 à chaque passage et qui commence en ligne 5, il faut écrire
      '### Cells(140, i) = Cell.Address(False, False)
      .Cells(i, 140) = Cell.Address(False, False)
      i = i + 1
    End If
  Next
End With
Set FL1 = Nothing
Set Plage = Nothing
End Sub

Fonctionne-t-il ?

[jerodino]

Merci pour les commentaires ! Je commence à comprendre un peu mieux.
Alors le code est le suivant maintenant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub MaSelection()
Dim FL1 As Worksheet, Cell As Range, Plage As Range
Dim R As Range
Dim i As Integer
'---
Set FL1 = Worksheets("235")
Set R = Range("DG3")
i = 5
With FL1
  Set Plage = .Range("C4 : DD129")
  For Each Cell In Plage
    If Cell = R Then
      .Cells(i, 140) = Cell.Address(False, False)
      i = i + 1
    End If
  Next
End With
Set FL1 = Nothing
Set Plage = Nothing
End Sub

La macro se déroule sans accrocs mais rien ne se passe, Cela vient peut être de la valeur Y1 en DG3 qui est du texte ?

[jerodino]

Mea Culpa ...

Je viens de regarder à la droite de ma feuille ... et les résultats étaient là !

Merci beaucoup pour votre aide

Jerodino