Discussion :

[aude_alti]

Bonjour,

A partir d’une liste excel dans un onglet Sheet n°1, comme ci-dessous :
276001001
276001002
276001003
276001004

Je souhaiterais obtenir une autre liste excel comme ci-dessous dans un onglet Sheet n°2 :

276001001.pdf
276001001_commentary.pdf
276001001_query.pdf
276001001_audit_trail.pdf
276001002.pdf
276001002_commentary.pdf
276001002_query.pdf
276001002_audit_trail.pdf
276001003.pdf
276001003_commentary.pdf
276001003_query.pdf
276001003_audit_trail.pdf
276001004.pdf
276001004_commentary.pdf
276001004_query.pdf
276001004_audit_trail.pdf


Voici le code que j’ai pour le moment :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Option Explicit
Sub Etape_4_Creation_Liste()
Dim Ws As Worksheet
Dim lig, derlig As Integer
Dim I As Long
With Sheets("Sheet n°1") 'feuille ou sont les données
derlig = .Range("A65536").End(xlUp).Row 'A = colonne contenant le séparateur d'onglet
For lig = 1 To derlig
 
For I = 0 To 3
Sheets("Sheet n°1").Range("A" & lig & ":B" & lig).Copy Sheets("Sheet n°2").Range("A" & lig + I & ":B" & lig + I)
Next I
 
Next lig
 
End With
End Sub

Le problème est la 2ème cellule de Sheet n°1 écrase la 2ème cellule de Sheet n°2. Je pense que je dois refaire une boucle mais je ne sais pas comment faire et je ne parviens pas à renommer les cellules destinations en ‘.pdf’, ‘_commentary.pdf’…etc.

Merci encore pour votre aide

aude_alti

[mercatog]

Une petit code utilisant les variables tableaux pour la rapidité

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub Former()
Dim i As Long, n As Long, p As Long
Dim k As Byte, m As Byte
Dim Res() As String
Dim Suff, Tb
 
Suff = Array("", "_commentary", "_query", "_audit_trail")
 
With Worksheets("Sheet n°1")
    Tb = .Range("A1:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
End With
 
n = UBound(Tb, 1)
m = UBound(Suff) + 1
ReDim Res(1 To n * m, 1 To 1)
For i = 1 To n
    For k = 0 To m - 1
        p = p + 1
        Res(p, 1) = Tb(i, 1) & Suff(k) & ".pdf"
    Next k
Next i
 
Worksheets("Sheet n°2").Range("A1").Resize(n * m, 1) = Res
End Sub

Le même code utilisé directement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub Former()
Dim k As Byte, m As Byte
Dim Sh As Worksheet
Dim c As Range
Dim p As Long
Dim Suff
 
Application.ScreenUpdating = False
Suff = Array("", "_commentary", "_query", "_audit_trail")
m = UBound(Suff) + 1
 
Set Sh = Worksheets("Sheet n°2")
With Worksheets("Sheet n°1")
    For Each c In .Range("A1:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
        For k = 0 To m - 1
            p = p + 1
            Sh.Cells(p, 1) = c.Value & Suff(k) & ".pdf"
        Next k
    Next c
End With
Set Sh = Nothing
End Sub

[aude_alti]

Merci mercatog, ça marche, impec!