Discussion :

[win_ubuntu]

Bonsoir,
soit le doc votes.xml :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
<?xml version="1.0"?>
<Votes>											
<Ville nom="Cachan" dept="94">
<Bureau num="1">
<Candidat nom="Toto" voix="3398"/><Candidat nom="Dupont" voix="6589"/>
</Bureau>
<Bureau num="2">
<Candidat nom="Toto" voix="5645"/><Candidat nom="Dupont" voix="4090"/>
</Bureau>
</Ville>
<Ville nom="L’Hay" dept="94">
<Bureau num="1">
<Candidat nom="Toto" voix="2067"/><Candidat nom="Dupont" voix="4089"/>
</Bureau>
</Ville>
<Ville nom="Bagneux" dept="92">
<Bureau num="1">
<Candidat nom="Toto" voix="4723"/><Candidat nom="Dupont" voix="5167"/>
</Bureau>
</Ville>
</Votes>

Question:
Écrivez un programme XSLT qui calcule la somme des voix pour chacun des candidats. Le résultat de la transformation donnera le document :
<Votes>
<Candidat nom="Toto">15833</Candidat>
<Candidat nom="Dupont">19935</Candidat>
</Votes>

Mon essai:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
...
xsl:template match="Votes">
<votes>
	<xsl:for-each select="Ville/Bureau/Candidat">
	<xsl:if test="not(@nom=following::Candidat/@nom)">
	<xsl:variable name="nom" select="@nom"/>
	<candidat nom="{@nom}"><xsl:value-of select="sum(//Candidat[@nom=$nom]/@voix)"/> </candidat>
	</xsl:if>
	</xsl:for-each>
	</votes>
	</xsl:template>
...

çà marche tés bien. je veux une autre solution utilisant la fonction:
distinct-values ()
merci d'avance

[thelvin]

distinct-values() c'est une fonction pour XSLT 2.0, pas 1.0
Mais ok, très bien, il suffit d'utiliser du 2.0.

Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
<root>
  <a>Hello</a>
  <a>Bonjour</a>
  <a>Hello</a>
</root>

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
<xsl:template match="/">
  <root>
    <xsl:for-each select="distinct-values(//a)">
      <a>
        <xsl:value-of select="."/>
      </a>
    </xsl:for-each>
  </root>
</xsl:template>

[win_ubuntu]

voici un code utilisant la fonction: distinct-values:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="2.0">
    <xsl:template match="Votes">
        <votes>
        <xsl:for-each select="distinct-values(//Candidat/@nom)">
            <candidat nom= "{.}">
               <xsl:value-of select="sum(//Candidat[@nom=.]/@voix)" />
            </candidat>
        </xsl:for-each>
        </votes>
    </xsl:template>
</xsl:stylesheet>

érreur:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 ...
Description: Leading '/' cannot select the root node of the tree containing the context item: the context item is an atomic value
Emplacement de début: 8:0
URL: http://www.w3.org/TR/xpath20/#ERRXPTY0020

[thelvin]

Marrant. C'est vrai que moi j'aurais utilisé xsl:for-each-group au lieu de distinct-values(), et donc le problème se poserait pas. Je m'attendais pas à ce que XPath 2.0 nous fasse un coup pareil.

Il existe peut-être une solution triviale, mais si ce n'est pas le cas, il suffit de mettre l'ensemble des candidats dans une variable, avant de commencer le for-each. Comme ça on peut y accéder avec cette variable au lieu de //

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<xsl:variable name="candidats" select="//Candidat"/>

Reste à régler le problème qui apparaît ensuite. La solution est la même.

[Loceka]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<xsl:value-of select="sum(//Candidat[@nom=.]/@voix)" />

Je doute que cette partie-là fasse ce que tu souhaites :
Là tu testes que l'attribut nom de l'élément Candidat a la même valeur que le contenu texte de ce même élément Candidat.

Toi ce que tu veux c'est le comparer à l'attribut nom actuellement sélectionné. Pour ça, il faut que tu passes soit par une variable, soit par la fonction XSL current():

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<xsl:value-of select="sum(//Candidat[@nom=current()]/@voix)" />

[win_ubuntu]

merci infiniment les gars; voila la solution, çà marche trés bien:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="2.0">
    <xsl:template match="Votes">
        <votes>
            <xsl:variable name="candidats" select="//Candidat"/>
            <xsl:for-each select="distinct-values(//Candidat/@nom)">
                <candidat nom= "{.}">
                    <xsl:value-of select="sum($candidats[@nom=current()]/@voix)" />
                </candidat>
            </xsl:for-each>
        </votes>
    </xsl:template>
</xsl:stylesheet>

mais remarquez vous que le parser a accepté cette ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sum(//Candidat...)

dans la première solution, et l'a refusé dans la deuxième!.

[thelvin]

mais remarquez vous que le parser a accepté cette ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sum(//Candidat...)

dans la première solution, et l'a refusé dans la deuxième!.

Ben oui, pour la raison indiquée.
Un XPath s'évalue toujours à partir du contexte en cours.
Lorsqu'on fait un for-each, à l'intérieur de la boucle, le contexte en cours est l'élément pour lequel on fait la boucle. C'est pour ça qu'on peut utiliser le . dans <candidat nom= "{.}">.

Or un XPath qui commence par / signifie "commence déjà par remonter au document," et par "le document" on veut dire "le document qui contient le contexte en cours."
Si le for-each se fait sur un ensemble d'éléments du document,comme par exemple //machin , ça marche très bien.
Mais dans le cas de distinct-values(), on ne sélectionne pas des éléments. On extrait la valeur des éléments, sous forme de strings, et on en renvoie la liste d'occurrences uniques. Une string n'appartient à aucun document, comme il le dit c'est un atome. Et donc commencer par / n'a pas de sens si le contexte est une simple string, obtenue avec distinct-values().


La solution correcte à ce besoin est <xsl:for-each-group>, et non pas distinct-values(). Ainsi le problème ne se poserait pas.

[Loceka]

dans le cas de distinct-values(), on ne sélectionne pas des éléments. On extrait la valeur des éléments, sous forme de strings, et on en renvoie la liste d'occurrences uniques. Une string n'appartient à aucun document, comme il le dit c'est un atome. Et donc commencer par / n'a pas de sens si le contexte est une simple string, obtenue avec distinct-values().

J'aurais jamais pensé à ça.
C'est d'autant plus bizarre qu'en sortie (du distinct-values) on a quand même des noeuds (attributs dans le cas actuel), qui eux sont bien rattaché à un document.

Note que je ne doûte pas de ton explication mais ce comportement de XSL me semble pour le moins étrange.

[thelvin]

J'aurais jamais pensé à ça.
C'est d'autant plus bizarre qu'en sortie (du distinct-values) on a quand même des noeuds (attributs dans le cas actuel), qui eux sont bien rattaché à un document.

Non, ce sont probablement des xs:string. En tout cas ce sont des xs:anyAtomicType, toujours le cas avec distinct-values(). Les nœuds sont convertis en xs:anyAtomicType en fonction de leur type XML Schema, ou xs:string s'ils n'en ont pas.

Note que je ne doûte pas de ton explication mais ce comportement de XSL me semble pour le moins étrange.

Il est fort dommage que des valeurs XPath atomiques ne soient pas considérées comme faisant partie du document sur lequel s'exécute la transformation, c'est sûr -_-°. Déjà que pour les éléments faisant partie d'un autre document, je trouve le comportement de // douteux...