Discussion :

[BAHIRI]

Bonjour à Forum,

Est il possible d'éviter le message : Le Presse-papier contient......
Merci par avance.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
   Sheets("Sheet1").Select
    Range("A1").Select
    Selection.CurrentRegion.Select
    Selection.Copy
    ActiveWindow.Close
    Range("A1").Select
    ActiveSheet.Paste
    Range("A1").Select

[Daniel.C]

Bonjour,

Après la ligne 7, mets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.CutCopyMode = False

[mercatog]

Au lieu des Select et Activemachin, travailles avec des variables Workbook.
Si tu mettais ton code en entier, tu auras une méthode fiable.

Exemple à adapter (on ouvre la fichier source, et on copie les données de la feuille FeuilleSource vers la feuille FeuilleDestination du fichier contenant la macro et on ferme sans enregistrer le fichier Source)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Transferer()
Dim Fichier As String
Dim Wbk As Workbook
 
Application.ScreenUpdating = False
Fichier = "C:\Documents and Settings\Administrateur\Bureau\FichierSource.xls"
If Dir(Fichier) <> "" Then
    Set Wbk = Workbooks.Open(Fichier)
    Wbk.Worksheets("FeuilleSource").Range("A1").CurrentRegion.Copy ThisWorkbook.Worksheets("FeuilleDestionation").Range("A1")
    Wbk.Close False
    Set Wbk = Nothing
End If
End Sub

[BAHIRI]

Bonjour,

Je vous prie de trouver ci-dessous la procédure complète. Si vous pouvez m'aider à l'adapter avec mes remerciement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub Rapport_V2()
 
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
 
    Sheets("Sheet1").Select
    Range("A1").Select
    Selection.CurrentRegion.Select
    Selection.ClearContents
    Range("A1").Select
 
    Workbooks.Open Filename:= _
        "C:\Users\KBI\Documents\Bureau tmp\Agenda.xls"    
 
    Call Sauvegarder_Agenda
 
    Sheets("Sheet1").Select
    Range("A1").Select
    Selection.CurrentRegion.Select
    Selection.Copy
    ActiveWindow.Close
    Range("A1").Select
    ActiveSheet.Paste
    Range("A1").Select
 
    Call Sauvegarder_Agenda
 
    Call MEF_Date 'conversion de date en numérique
 
    Call TCDAGENDA_1
    Call TCDAGENDA_2
 
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
 
End Sub

[mercatog]

Quel est le nom de la feuille de destination?

Qu'est ce que tu ne peux adapter du code donnée en réponse #2?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Transferer()
Dim Fichier As String
Dim Wbk As Workbook
 
Application.ScreenUpdating = False
Fichier = "C:\Users\KBI\Documents\Bureau tmp\Agenda.xls"
If Dir(Fichier) <> "" Then
    Set Wbk = Workbooks.Open(Fichier)
    Wbk.Worksheets("Sheet1").Range("A1").CurrentRegion.Copy ThisWorkbook.Worksheets("FeuilleDestionation").Range("A1")
    Wbk.Close False
    Set Wbk = Nothing
    Call Sauvegarder_Agenda
    Call MEF_Date
    Call TCDAGENDA_1
    Call TCDAGENDA_2
End If
End Sub

[BAHIRI]

Bonjour,

Il n'y a rien à adapter sauf mes lunettes, le code est opèrationnel.

Merci pour ton aide

Cordialement