Discussion :

[ric009]

Bonjour à tous,

J'espère que des pro du VBA m'aideront à résoudre mon problème ...

Mon soucis est que j'ai récupéré un code de recherche de nom (très efficace) mais je l'ai modifié plusieurs fois pour qu'il prenne en compte les prénoms et les noms, mais aucun résultat...

Mon objectif : est que lorsque je tape un nom qui possède plusieurs occurrences, il m'affiche le nom et prénom de chaque occurrence... Je vous laisse voir le fichier peut-être que vous comprendrez mieux comme ça ...

Merci par avance pour votre aide !

[mercatog]

J'ai un tout petit modifié ton code et ajouté la possibilité de récupérer aussi les prénoms

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Private Sub TextBox1_Change()
Dim Recherche As String, Adresse As String, Res As String
Dim MaRech As Object
Dim Plage As Range, c As Range
Dim Ligne As Long
 
ListBox1.Clear
Recherche = TextBox1.Value
If Recherche = "" Then Recherche = "*"
With Worksheets("BASE")
    Ligne = .Cells(.Rows.Count, "B").End(xlUp).Row
    Set Plage = .Range("B1:B" & Ligne)
End With
 
Set MaRech = CreateObject("Scripting.Dictionary")
With Plage
    Set c = .Find(Recherche, , xlValues)
    If Not c Is Nothing Then
        Adresse = c.Address
        Do
            If UCase(c.Value) Like UCase(Recherche) & "*" Then
                Res = c.Value & "    " & c.Offset(0, 1).Value
                MaRech(Res) = Res
            End If
            Set c = .FindNext(c)
        Loop While Not c Is Nothing And c.Address <> Adresse
        Me.ListBox1.List = MaRech.Items
        MaRech.RemoveAll
        Set MaRech = Nothing
    End If
End With
Set Plage = Nothing
End Sub

[ric009]

merci pour ta réponse ça fonctionne très bien !!!

cordialement.

[mercatog]

Le code est adapté de celui que tu as proposé initialement. Donc c'est ton code, adapté.
Ci-après, le code légèrement commenté pour ta compréhension

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Private Sub TextBox1_Change()
Dim Recherche As String, Adresse As String, Res As String
Dim MaRech As Object
Dim Plage As Range, c As Range
Dim Ligne As Long
 
'On vide ListBox1
ListBox1.Clear
 
'Dans la variable recherche on récupère le texte siaisi dans TextBox1
Recherche = TextBox1.Value
 
'Cette ligne est ajouté au cas où si on efface TextBox1, on récupère dans la variable Recherche le joker * (qui signifie n'importe quel texte
If Recherche = "" Then Recherche = "*"
 
'Ici c'est pour instancier la variable objet Plage à notre plage de recherche
With Worksheets("BASE")
    Ligne = .Cells(.Rows.Count, "B").End(xlUp).Row
    Set Plage = .Range("B1:B" & Ligne)
End With
 
'on crée un dictionaire (pour éviter les doublons)
Set MaRech = CreateObject("Scripting.Dictionary")
 
With Plage
    'on fait une boucle à l'aide de Find pour récupérer toutes les cellules de la colonne B contenant le mot contenu dans TextBox1 (variable Recherche)
    Set c = .Find(Recherche, , xlValues)
    If Not c Is Nothing Then
        Adresse = c.Address
        Do
            'Si la cellule c commence par la valeur contenue dans la vriable Recherche
            If UCase(c.Value) Like UCase(Recherche) & "*" Then
                'Dans Res, on concatène la valeur de la colonne B et celle de la colonne C
                Res = c.Value & "    " & c.Offset(0, 1).Value
                'on l'ajoute au dictionnaire (en évitant les doublons)
                MaRech(Res) = Res
            End If
            'on cherche la valeur suivante
            Set c = .FindNext(c)
        Loop While Not c Is Nothing And c.Address <> Adresse
        'on récupère le résultat du dictionnaire
        Me.ListBox1.List = MaRech.Items
        MaRech.RemoveAll
        Set MaRech = Nothing
    End If
End With
Set Plage = Nothing
End Sub