Discussion :

[krof77]

Bonjour
je cherche a retrouver le nbr de jours ouvrés entre 2 dates (jusque là tt va bein), seulement je voudrais la valeur mois apres mois
voir piece jointe
par exemple entre le 15 janvier et le 10 mars, je dois retrouver ~11 jours ouvrés en janvier, puis 20 en fev, et enfin ~7 en mars
qq un peut il m'aider svp ?

par avance merci

[papouclo]

Bonjour,
En remplaçant en ligne 1 les mois : janvier, février ... par les dates du premier jour du mois 1/1/2013 , 1/2/2013, ... quitte à retrouver le nom des mois avec le format personnalisé mmmm ,
écrire en C2 la formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
=NB.JOURS.OUVRES(C$1;$B2)*($A2<=C$1)*(C$1<=$B2)*($B2<=FIN.MOIS(C$1;0)) + NB.JOURS.OUVRES(C$1;FIN.MOIS(C$1;0))*($A2<C$1)*(FIN.MOIS(C$1;0)<$B2)
+ NB.JOURS.OUVRES($A2;$B2)*(C$1<$A2)*($B2<=FIN.MOIS(C$1;0)) + NB.JOURS.OUVRES($A2;FIN.MOIS(C$1;0)) * (C$1<$A2)*($A2<=FIN.MOIS(C$1;0)) * (FIN.MOIS(C$1;0)<$B2)

Recopier la formule vers le bas et la droite.
Les résultats obtenus peuvent se lire sur le classeur joint.
Remarque : J'ai rajouté la période du 15 janvier au 10 mars 2013 mais la formule donne d'autres résultats que les nombres donnés dans le message de krof77
La fonction NB.JOURS.OUVRES est utilisée ici sans tenir compte d'une liste de jours fériés qu'il faudrait préciser sur une plage du classeur.

Cordialement
Claude

[krof77]

Bonjour
ça fonctionne !! merci beaucoup, celle là je l'aurais pas trouvé
bonne soirée
Christophe

[Philippe Tulliez]

Bonjour,
Une autre solution.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=($B2>=C$1)*($A2<=FIN.MOIS(C$1;0)) * NB.JOURS.OUVRES(MAX($A2;C$1);MIN($B2;FIN.MOIS(C$1;0)))

[EDIT]
S'il faut tenir compte des jours fériés, il y a lieu d'ajouter la référence à une plage, au 3ème argument de la formule NB.JOURS.OUVRES

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=($B2>=C$1)*($A2<=FIN.MOIS(C$1;0)) * NB.JOURS.OUVRES(MAX($A2;C$1);MIN($B2;FIN.MOIS(C$1;0));jFerie )

[Phanloga]

Bonjour.
Et si tu es sous 2007/2010, regarde ce sujet.
On m'y a bien aidé !!

Attention au paramètre [week-end] qu'il faut adapter.

[tototiti2008]

Bonjour à tous,

S'il n'y a pas de jours fériés à gérer, une autre possibilité, en C2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((JOURSEM(LIGNE(INDIRECT($A2&":"&$B2));2)<6)*(MOIS(LIGNE(INDIRECT($A2&":"&$B2)))=COLONNE(A1)))

puis à recopier partout

[kiki29]

Salut, pour info voir également ici