Discussion :

[Tchebichef]

Bonjour à tous,
Je viens vers vous car j'ai un problème que je ne comprends pas et par conséquent que je n'arrive pas à résoudre.
Je souhaite supprimer des lignes d'une feuille excel en fonction d'un critère.
J'utilise le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
For i = 1 To nbrelignes
If Range("J" & i) < DateValue(Now) Then
Rows(i & ":" & i).Delete Shift:=xlUp
i = i - 1
End If
Next i

Tout fonctionne bien jusqu'à la ligne 545 où là excel tourne sans jamais s'arrêter.
J'ai fait le test en virant la variable nbrelignes (qui est en fait le nombre de lignes de ma feuille récupéré par nbrelignes = ActiveSheet.UsedRange.Rows.Count) et en la remplaçant par une constante. Tout fonctionne sauf si je mets une constante supérieure à 545...
Et là je ne pige plus du tout.
Quelqu'un aurait une idée ?
D'avance merci pour vos aides.
Tchebi

[Jean-Philippe André]

Salut,
par habitude, il faudrait plutôt faire une boucle qui décrémente, ca évite les aberrations

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
For i = nbrelignes to 1 step -1
If Range("J" & i) < DateValue(Now) Then
Rows(i & ":" & i).Delete
End If
Next i

[Tchebichef]

Bonjour jpcheck,
Je ne comprends pas pourquoi, mais ça marche parfaitement !
Pouvez vous m'expliquer le pourquoi du comment ?
Merci

[Jean-Philippe André]

Ta borne supérieure de boucle ne changeant pas, il te faut t'assurer qu'une fois arrivé au dernier élément de ta liste d'origine (donc sans les suppressions), tu arrêtes ta boucle.

Alors autant partir "d'en bas" et "remonter", tu ne repasses jamais sur la même ligne

[el_slapper]

Pour dire la même chose autrement, avoir un numéro de ligne qui monte et qui descend, ça rend l'algorithme complexe. Le "i = i-1" dans une boucle qui incrémente i est une mauvaise idée, car on ne sait plus très bien ou on en est.

Je pense que dans le code initial, l'erreur est de ne pas modifier la variable nbrelignes. Parceque quand on supprime une ligne, logiquement, il reste une ligne de moins à traiter. Alors que quand on va de la dernière à la première, eh bien la première reste toujours la première.

La conséquence est qu'on continue à appliquer le traitement au delà de la limite. Donc, sur une ligne blanche, par exemple, et la condition est probablement vraie sur une ligne blanche. Donc on boucle infiniment : on incrémente i, on tombe sur une ligne blanche, on la supprime, on décrémente i, et on recommence infiniment puisque seules des lignes blanches remontent.

Si on veut absolument partir du haut, il vaut mieux faire un while, avec gestion dynamique du compteur ET de la limite. du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
i = 1
While i <= nbrelignes
    If Range("J" & i) < DateValue(Now) Then
        Rows(i & ":" & i).Delete Shift:=xlUp
        nbrelignes = nbrelignes - 1
    Else
        i = i + 1
    End If
Wend

ça ne bouclera pas, parceque dans tous les cas i se rapproche de nbrlignes.

Mais le code de JPCheck est quand même supérieur à ça, parcequ'il ne gère qu'un seul compteur au lieu de deux.

[Tchebichef]

En effet, je m'étais douté que le problème venait de nbrelignes qui est fixe alors qu'il diminue à chaque suppression de ligne.
J'avais donc essayé de rajouter nbrelignes=nbrelignes-1 dans la boucle mais sans succès (même phénomène de bouclage "en boucle").
Je comprends maintenant pourquoi ce bouclage : ma condition étant une condition de date, elle est toujours vraie pour une ligne vide.
Merci en tout cas pour la solution et les explications.
Cordialement,