Discussion :

[FC9029]

Bonjour,

je cherche à utiliser un critère OU dans une formule =Somme.Si.Ens()
Du type :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SOMME.SI.ENS(C:C;D:D;"b";B:B; "1" OU "2" )

Après de nombreuses heures de recherche, d'essais (et un petit mal de crâne), j'ai fini par arriver à une formule du type :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=somme(SOMME.SI.ENS(C:C;D:D;"b";B:B;{1;2}))

qui fonctionne parfaitement en l'état.

Je souhaite désormais que ces critères ( "1" OU "2" ) puissent être variable.

Je joins un fichier d'exemple avec mes essais les plus "avancés".

Merci à ceux qui se pencherons sur le sujet!

François.

[gFZT82]

Bonjour,

As-tu essayé avec simplement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

{=SOMME(SOMME.SI.ENS(C2:C16;D2:D16;G3;B2:B16;G1:G2))}

Cordialement.

[FC9029]

Bonjour,

Merci beaucoup ! C'est parfait !
Ca Fonctionne parfaitement (et pas que dans le fichier d'exemple ^^) ! ! !

Merci,
François

[turbo_sophie]

bonsoir,


et si on veut garder les deux critères dans la même cellule,
comme ta cellule H1 {"1";2"}
peut on faire un somme.si.ens, sans mettre ces critères dans des cellules différentes ?


merci !!

[FC9029]

Bonjour,
je n'ai pas trouvé réponse à ta question, désolé.
Bonne recherche, et si tu trouves, je suis intéressé par la réponse.
A bientôt,
François

[turbo_sophie]

je n'ai pas réussi,
j'ai donc stocké {"1";2"} dans un nom de feuille

(dans mon cas c'est la traduction d'un multi select dans une listbox)

en espérant que cela puisse t'aider

[Taltosm]

Bonjour,

je rebondi sur la meme question mais avec NB.SI.ENS

est il possible de mettre un OU dans un NB.SI.ENS

j'ai

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS(Feuil1!E7:E800;"NONTIT";Feuil1!R7:R800;"1,42")

qui fonctionne tres bien et qui compte le nombre de cellule qui ont NONTIT dans la colonne E de la ligne 7 a 800 ET 1,42 dans la colonne R de la ligne 7 a 800

mais ce que je voudrais c'est

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB(NB.SI.ENS(Feuil1!C7:C800;{"NTCONT";"NTOCCA";"NICUI";"AUXHO";"NICAE";"APPR"};Feuil1!R7:R800;"1,42"))

qui me donne un résultat FAUX :! alors que je souhaite qu'il compte les cellules qui ont NTCONT ou NTOCCA dans la colonne C... ET 1, 42 dans la colonne R

Merci pour vos réponses, avis etc...

[papouclo]

Bonjour,
Si on ne veut compter que les lignes avec la cellule de la colonne C contenant NTCONT ou NTOCCA et la cellule de la colonne R contenant 1,42, essayer la formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

{ =SOMME ( NB.SI.ENS ( Feuil1!C7:C800 ; {"NTCONT";"NTOCCA"} ; Feuil1!R7:R800 ; 1,42) ) }

Cordialement
Claude

[Taltosm]

cela ne marche pas, mais je crois avoir compris...

OU ne fonctionnerai t'il pas que pour 2 choix ?


{"NTCONT" OU "NTOCCA"}

alors que moi je souhaite

{"NTCONT" OU "NTOCCA" OU "NICUI" OU "AUXHO" OU "NICAE" OU "APPR"}

[Minh67]

Bonjour,

As-tu essayé avec simplement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

{=SOMME(SOMME.SI.ENS(C2:C16;D2:D16;G3;B2:B16;G1:G2))}

Cordialement.

Bonjour,


Je me permets de revenir sur ce sujet, mais en téléchargeant le fichier excel avec le problème et en copiant la formule, mon résultat obtenu est de "0" et non "38".
J'avoue ne pas comprendre et me dire que je suis aveugle sur un détail.

Quelqu'un pourrait-il m'éclairer ?

En vous remerciant par avance.


Cordialement


Edit : réponse trouvée : il faut valider la formule avec CTRL + MAJ + ENTREE

[faustina]

Bonjour à tous,

Je rebondit sur cette discussion car moi aussi je me casse la tête sur le sujet!

Grossomodo j'ai une grosse formule qui additionne plusieurs SOMME.SI.ENS

1er PB:Je souhaite alléger cette formule avec un OU pour permettre à une même plage de correspondre aux résultats d'une cellule ou d'une autre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS(BN8:BN386;BL8:BL386;"x";$AC$8:$AC$386;$G$387)+SOMME.SI.ENS(BN8:BN386;BL8:BL386;"x";$AC$8:$AC$386;$G$390)

J'ai essayé la formule cité par gFZT82 type SOMME(SOMME.SI.ENS(C2:C16;D216;G3;B2:B16;G1:G2) et elle ne marche pas avec les cellules, triste!

le 2nd PB est que je souhaite additionner plusieurs ensemble de SOMME.SI, ici ce sont les plages qui varient et non plus la cellule "critère", Mon problème est que si une cellule répond aux critères de 2 plages je ne veux pas que ce soit cumulable! le OU me parait jouable mais comment l'utilisé dans ce cas?
J'ai simplifié ma formule pour que ce soit plus compréhensible:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS(BN8:BN386;BL8:BL386;"x";$AC$8:$AC$386;$G$387)+SOMME.SI.ENS(BN8:BN386;BL8:BL386;"x";$AE$8:$AE$386;$G$387)+SOMME.SI.ENS(BN8:BN386;BL8:BL386;"x";$DE$8:$DE$386;$G$387)

J'ai essayé cette formule, elle ne fonctionne pas mais peut être qu'elle vous aidera à comprendre mon mystère!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS(BN8:BN386;BL8:BL386;"x";OU($AC$8:$AC$386;$AE$8:$AE$386;$DE$8:$DE$386);$G$387)

Autrement, dit, et j'espère être compréhensible, Je veux que mon critère de la cellule $G$387 soit présent dans au moins une des 3 plages $AC$8:$AC$386;$AE$8:$AE$386;$DE$8:$DE$386 mais que si elle se trouve dans 2 voir 3 plages, je ne veux pas que cette valeur soit comptabilisé 2 fois!

Hummm si vous avez une astuce, je prend! MERCI!!!

[LeBo74]

Bonjour Faustina

Je me permets une réponse mais je crois que tu aurais du ouvrir un nouveau post étant donée que c'est une nouvelle question.

On peut réaliser ce que tu souhaites faire mais tu devras décomposer ton somme.si.ens en la somme d'une matrice conditionnelle
J'imagine que je ne suis pas clair donc voici à quoi cela ressemble avec ton exemple (formule matricielle à valider par ctrl-shift-entré)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(SI((BL8:BL386="x")*((AC8:AC386=G387)+(AE8:AE386=G387)+(DE8:DE386=G387));BN8:BN386))

Dans la conditionnelle, j'utilise le * pour les ET et les + pour les OU. Ensuite on addtionne la matrice obtenue.
Avec cette logique, tu peux solutionner pas mal de problème semblabe,

Bonne suite